feat(eventhub): Org case

modules/services/event-hub-data-source/organizational.tf

@@ -0,0 +1,43 @@
+data "azurerm_management_group" "onboarded_management_group" {
+  for_each = length(var.management_group_ids) > 0 ? toset(var.management_group_ids) : toset([var.tenant_id])
+  name     = each.value
+}
+
+locals {
+  all_mg_subscription_ids = flatten([
+    for mg in data.azurerm_management_group.onboarded_management_group : mg.all_subscription_ids
+  ])
+}
+
+data "azurerm_subscription" "onboarded_subscriptions" {
+  for_each = toset(local.all_mg_subscription_ids)
+  subscription_id = each.value
+}
+
+locals { 
+    enabled_subscriptions = var.is_organizational ? [for s in data.azurerm_subscription.onboarded_subscriptions : s if s.state == "Enabled"] : []
+}
+
+#---------------------------------------------------------------------------------------------
+# Create diagnostic settings for the tenant
+#---------------------------------------------------------------------------------------------
+resource "azurerm_monitor_diagnostic_setting" "sysdig_org_diagnostic_setting" {
+  count = var.is_organizational ? length(local.enabled_subscriptions) : 0
+
+  name               = "sysdig-diagnostic-setting"
+  target_resource_id = local.enabled_subscriptions[count.index].id
+  eventhub_authorization_rule_id = azurerm_eventhub_namespace_authorization_rule.sysdig_rule.id
+  eventhub_name                  = azurerm_eventhub.sysdig_event_hub.name
+
+  enabled_log {
+    category = "Administrative"
+  }
+
+  enabled_log {
+    category = "Security"
+  }
+
+  enabled_log {
+    category = "Policy"
+  }
+}

modules/services/event-hub-data-source/variables.tf

@@ -53,3 +53,15 @@ variable "namespace_sku" {
   description = "SKU (Plan) for the namespace that will be created"
   default     = "Standard"
 }
+
+variable "is_organizational" {
+  description = "(Optional) Set this field to 'true' to deploy secure-for-cloud to an Azure Tenant."
+  type        = bool
+  default     = false
+}
+
+variable "management_group_ids" {
+  description = "(Optional) List of Azure Management Group IDs. secure-for-cloud will be deployed to all the subscriptions under these management groups."
+  type        = set(string)
+  default     = []
+}