nixos/elastic-apm-server: init

nixos/modules/module-list.nix

@@ -340,6 +340,7 @@
   ./services/logging/rsyslogd.nix
   ./services/logging/syslog-ng.nix
   ./services/logging/syslogd.nix
+  ./services/logging/beats/apm-server.nix
   ./services/mail/clamsmtp.nix
   ./services/mail/davmail.nix
   ./services/mail/dkimproxy-out.nix

nixos/modules/services/logging/beats/apm-server.nix

@@ -0,0 +1,79 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  beatslib = import ./lib.nix { inherit lib pkgs; };
+
+  mkApmServerConfig = cfg: {
+
+    apm-server.host = "${cfg.listenAddress}:${toString cfg.port}";
+
+  };
+
+
+in
+
+{
+  ###### interface
+
+  options = {
+
+    services.beats.apm-server = recursiveUpdate
+      (beatslib.mkCommonOptions { name = "apm-server"; defaults = { package = pkgs.elastic-apm-server; }; })
+      {
+
+        listenAddress = mkOption {
+          description = "Address on which to listen.";
+          type = types.str;
+          default = "localhost";
+        };
+
+        port = mkOption {
+          description = "Port on which to listen.";
+          type = types.int;
+          default = 8200;
+        };
+
+        elasticsearch.indices = mkOption {
+          description = "Array of index selector rules";
+          type = with types; listOf attrs;
+          default = [
+            {
+              index = "apm-%{[beat.version]}-sourcemap";
+              when.contains.processor.event = "sourcemap";
+            }
+            {
+              index = "apm-%{[beat.version]}-error-%{+yyyy.MM.dd}";
+              when.contains.processor.event = "error";
+            }
+            {
+              index = "apm-%{[beat.version]}-transaction-%{+yyyy.MM.dd}";
+              when.contains.processor.event = "transaction";
+            }
+            {
+              index = "apm-%{[beat.version]}-span-%{+yyyy.MM.dd}";
+              when.contains.processor.event = "span";
+            }
+            {
+              index = "apm-%{[beat.version]}-metric-%{+yyyy.MM.dd}";
+              when.contains.processor.event = "metric";
+            }
+            {
+              index = "apm-%{[beat.version]}-onboarding-%{+yyyy.MM.dd}";
+              when.contains.processor.event = "onboarding";
+            }
+          ];
+        };
+
+      };
+
+  };
+
+  config = beatslib.mkNixosConfig {
+    mkBeatConfig = mkApmServerConfig;
+    cfg = config.services.beats.apm-server;
+  };
+
+}

nixos/modules/services/logging/beats/lib.nix

@@ -0,0 +1,145 @@
+{ lib, pkgs, ... }:
+
+with lib;
+
+{
+
+  mkCommonOptions = { name, defaults }: {
+
+    enable = mkEnableOption "Enable ${name}.";
+
+    package = mkOption {
+      description = "${name} package to use.";
+      type = types.package;
+      default = defaults.package;
+    };
+
+    executable = mkOption {
+      description = "Name of the executable within <option>package</option> to run.";
+      type = types.str;
+      default = defaults.executable or name;
+    };
+
+    name = mkOption {
+      description = "Name of the beat";
+      type = types.str;
+      default = defaults.name or name;
+    };
+
+    tags = mkOption {
+      description = "Tags to place on the shipped log messages";
+      type = types.listOf types.str;
+      default = [];
+    };
+
+    stateDir = mkOption {
+      description = "The state directory.";
+      type = types.str;
+      default = defaults.stateDir or "/var/lib/${name}";
+    };
+
+    loglevel = mkOption {
+      description = "Logging verbosity level.";
+      type = types.enum [ "debug" "info" "warning" "error" "fatal" ];
+      default = "warning";
+    };
+
+    extraConfig = mkOption {
+      description = "Additional config to be added to the beats config.json.";
+      type = types.attrs;
+      default = {};
+    };
+
+    elasticsearch = {
+      hosts = mkOption {
+        description = "Elasticsearch hosts";
+        type = with types; listOf str;
+        default = [ "localhost:9200" ];
+      };
+
+      username = mkOption {
+        description = "Username for elasticsearch basic auth.";
+        type = types.nullOr types.str;
+        default = null;
+      };
+
+      password = mkOption {
+        description = "Password for elasticsearch basic auth.";
+        type = types.nullOr types.str;
+        default = null;
+      };
+    };
+
+    kibana = {
+      host = mkOption {
+        description = "Host where kibana is reachable.";
+        type = types.str;
+        default = "localhost:5601";
+      };
+    };
+
+  };
+
+  mkNixosConfig = { cfg, mkBeatConfig }: let
+
+    mkCommonBeatConfig = cfg: {
+      inherit (cfg) tags;
+
+      path = {
+        data = "${cfg.stateDir}/data";
+        logs = "${cfg.stateDir}/logs";
+      };
+
+      logging.level = cfg.loglevel;
+
+      output = { inherit (cfg) elasticsearch; };
+
+      setup.template = {
+        fields = "${cfg.package}/share/fields.yml";
+        settings.index = {
+          number_of_shards = 1;
+          codec = "best_compression";
+        };
+      };
+
+      setup.kibana = {
+        inherit (cfg.kibana) host;
+      };
+
+      setup.dashboards = {
+        enabled = true;
+        directory ="${cfg.package}/share/kibana";
+      };
+    };
+
+    beatConfig = foldl' recursiveUpdate {} [
+      (mkCommonBeatConfig cfg)
+      (mkBeatConfig cfg)
+      cfg.extraConfig
+    ];
+    beatConfigJSON = pkgs.writeText "${cfg.name}.json" (builtins.toJSON beatConfig);
+
+  in mkIf cfg.enable {
+
+    systemd.services.${cfg.name} = {
+      wantedBy = [ "multi-user.target" ];
+
+      after = let
+        hasLocalKibana = lib.strings.hasInfix "localhost" cfg.kibana.host;
+        hasLocalElasticsearch = (findSingle (x: lib.strings.hasInfix "localhost" x) null "multiple" cfg.elasticsearch.hosts) != null;
+      in []
+        ++ optional hasLocalKibana "kibana.service"
+        ++ optional hasLocalElasticsearch "elasticsearch.service";
+
+      preStart = ''
+        mkdir -p ${beatConfig.path.data}
+        mkdir -p ${beatConfig.path.logs}
+      '';
+
+      serviceConfig = {
+        ExecStart = "${cfg.package}/bin/${cfg.executable} -c ${beatConfigJSON}";
+      };
+    };
+  };
+
+}

nixos/tests/elk.nix

@@ -96,6 +96,16 @@ let
                       unit_count: 1
                 '';
               };
+
+              beats.apm-server = {
+                enable = true;
+                extraConfig = {
+                  setup.dashboards = {
+                    always_kibana = true;
+                    retry.enabled = true;
+                  };
+                };
+              };
             };
           };
       };
@@ -125,6 +135,10 @@ let
       $one->waitUntilSucceeds("curl --silent --show-error '${esUrl}/_search' -H 'Content-Type: application/json' -d '{\"query\" : { \"match\" : { \"message\" : \"flowers\"}}}' | jq .hits.total | grep -v 0");
       $one->waitUntilSucceeds("curl --silent --show-error '${esUrl}/_search' -H 'Content-Type: application/json' -d '{\"query\" : { \"match\" : { \"message\" : \"dragons\"}}}' | jq .hits.total | grep 0");
 
+      # See if apm-server is healthy.
+      $one->waitForUnit("apm-server.service");
+      $one->waitUntilSucceeds("curl --silent --show-error 'http://localhost:8200/' | grep 'ok'");
+
       # Test elasticsearch-curator.
       $one->systemctl("stop logstash");
       $one->systemctl("start elasticsearch-curator");