pgsrip: init at 0.1.11

pkgs/by-name/pg/pgsrip/package.nix

@@ -0,0 +1,51 @@
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "pgsrip";
+  version = "0.1.11";
+  pyproject = true;
+
+  disabled = python3Packages.pythonOlder "3.9";
+
+  src = fetchFromGitHub {
+    owner = "ratoaq2";
+    repo = "pgsrip";
+    rev = version;
+    hash = "sha256-H9gZXge+m/bCq25Fv91oFZ8Cq2SRNrKhOaDrLZkjazg=";
+  };
+
+  build-system = [ python3Packages.poetry-core ];
+
+  dependencies = with python3Packages; [
+    babelfish
+    cleanit
+    click
+    numpy
+    opencv-python
+    pysrt
+    pytesseract
+    setuptools
+    trakit
+  ];
+
+  pythonRelaxDeps = [
+    "numpy"
+    "setuptools"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Rip your PGS subtitles";
+    homepage = "https://github.com/ratoaq2/pgsrip";
+    changelog = "https://github.com/ratoaq2/pgsrip/blob/${src.rev}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ eljamm ];
+    mainProgram = "pgsrip";
+  };
+}

pkgs/development/python-modules/cleanit/default.nix

@@ -0,0 +1,64 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  pythonOlder,
+  nix-update-script,
+
+  # build dependencies
+  poetry-core,
+
+  # dependencies
+  appdirs,
+  babelfish,
+  chardet,
+  click,
+  jsonschema,
+  pysrt,
+  pyyaml,
+
+  # tests
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "cleanit";
+  version = "0.4.8";
+  pyproject = true;
+
+  disabled = pythonOlder "3.9";
+
+  src = fetchFromGitHub {
+    owner = "ratoaq2";
+    repo = "cleanit";
+    rev = version;
+    hash = "sha256-z1QAWWm+yg/pRCQfPqGbL0EFFT9UwqIkwhmjUuRHyuk=";
+  };
+
+  build-system = [ poetry-core ];
+
+  dependencies = [
+    appdirs
+    babelfish
+    chardet
+    click
+    jsonschema
+    pysrt
+    pyyaml
+  ];
+
+  nativeCheckInputs = [ pytestCheckHook ];
+
+  pythonImportsCheck = [ "cleanit" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Command line tool that helps you to keep your subtitles clean";
+    homepage = "https://github.com/ratoaq2/cleanit";
+    changelog = "https://github.com/ratoaq2/cleanit/releases/tag/${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ eljamm ];
+    mainProgram = "cleanit";
+  };
+}

pkgs/development/python-modules/trakit/default.nix

@@ -0,0 +1,64 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  pythonOlder,
+  nix-update-script,
+
+  # build dependencies
+  poetry-core,
+
+  # dependencies
+  babelfish,
+  pyyaml,
+  rebulk,
+  unidecode,
+
+  # tests
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "trakit";
+  version = "0.2.2";
+  pyproject = true;
+
+  disabled = pythonOlder "3.9";
+
+  src = fetchFromGitHub {
+    owner = "ratoaq2";
+    repo = "trakit";
+    rev = version;
+    hash = "sha256-VV+pdsQ5WEALYZgu4AmvNce1rCTLSYPZtTMjh+aExsU=";
+  };
+
+  build-system = [ poetry-core ];
+
+  dependencies = [
+    babelfish
+    pyyaml
+    rebulk
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    unidecode
+  ];
+
+  disabledTests = [
+    # requires network access
+    "test_generate_config"
+  ];
+
+  pythonImportsCheck = [ "trakit" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Guess additional information from track titles";
+    homepage = "https://github.com/ratoaq2/trakit";
+    changelog = "https://github.com/ratoaq2/trakit/releases/tag/${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ eljamm ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -2125,6 +2125,8 @@ with pkgs;
 
   clevercsv = with python3Packages; toPythonApplication clevercsv;
 
+  cleanit = with python3Packages; toPythonApplication cleanit;
+
   clickgen = with python3Packages; toPythonApplication clickgen;
 
   cloud-init = python3.pkgs.callPackage ../tools/virtualization/cloud-init { inherit systemd; };

pkgs/top-level/python-packages.nix

@@ -2336,6 +2336,8 @@ self: super: with self; {
 
   clean-fid = callPackage ../development/python-modules/clean-fid { };
 
+  cleanit = callPackage ../development/python-modules/cleanit { };
+
   cleanlab = callPackage ../development/python-modules/cleanlab { };
 
   cleanvision = callPackage ../development/python-modules/cleanvision { };
@@ -16310,6 +16312,8 @@ self: super: with self; {
 
   traittypes = callPackage ../development/python-modules/traittypes { };
 
+  trakit = callPackage ../development/python-modules/trakit { };
+
   trampoline = callPackage ../development/python-modules/trampoline { };
 
   transaction = callPackage ../development/python-modules/transaction { };