Refactor client code and extract repository/library methods into new modules

haxelib.json

@@ -7,5 +7,8 @@
 	"classPath": "src",
 	"version": "4.0.2",
 	"releasenote": " * Fixed too strict requirements to haxelib.json data for private libs (#484)",
-	"contributors": ["HaxeFoundation", "back2dos", "ncannasse", "jason", "Simn", "nadako", "andyli"]
+	"contributors": ["HaxeFoundation", "back2dos", "ncannasse", "jason", "Simn", "nadako", "andyli"],
+	"dependencies":{
+		"hx3compat":"git:https://github.com/haxefoundation/hx3compat.git#f1f18201e5c0479cb5adf5f6028788b37f37b730"
+	}
 }

src/haxelib/Data.hx

@@ -131,7 +131,7 @@ abstract Dependencies(Dynamic<DependencyVersion>) from Dynamic<DependencyVersion
 
 		for (f in fields) {
 			var value:String = Reflect.field(this, f);
-
+			// TODO: Also do mercurial
 			var isGit = value != null && (value + "").startsWith("git:");
 
 			if ( !isGit ){
@@ -162,8 +162,28 @@ abstract Dependencies(Dynamic<DependencyVersion>) from Dynamic<DependencyVersion
 
 		return result;
 	}
+
 	public inline function iterator()
 		return toArray().iterator();
+
+	#if (haxe_ver >= 4.0)
+	public inline function keyValueIterator():KeyValueIterator<ProjectName, DependencyVersion> {
+		final fields = Reflect.fields(this);
+		var index = 0;
+		return {
+			next: function() {
+				final name = fields[index++];
+				return {key: ProjectName.ofString(name), value: Reflect.field(this, name)};
+			},
+			hasNext: function() return index < fields.length
+		}
+	}
+	#end
+
+	/** Returns an array of the names of the dependencies. **/
+	public inline function getNames():Array<ProjectName>
+		return [for(name in Reflect.fields(this)) ProjectName.ofString(name) ];
+
 }
 
 /** The type of a dependency version. **/
@@ -212,75 +232,6 @@ typedef Infos = {
 	var Apache = 'Apache';
 }
 
-/** A valid project name string. **/
-abstract ProjectName(String) to String {
-	static var RESERVED_NAMES = ["haxe", "all"];
-	static var RESERVED_EXTENSIONS = ['.zip', '.hxml'];
-	inline function new(s:String)
-		this = s;
-
-	@:to function toValidatable():Validatable
-		return {
-			validate:
-				function ():Option<String> {
-					for (r in rules)
-						if (!r.check(this))
-							return Some(r.msg.replace('%VALUE', '`' + Json.stringify(this) + '`'));
-						return None;
-				}
-		}
-
-	static var rules = {//using an array because order might matter
-		var a = new Array<{ msg: String, check:String->Bool }>();
-
-		function add(m, r)
-			a.push( { msg: m, check: r } );
-
-		add("%VALUE is not a String",
-			#if (haxe_ver < 4.1)
-				Std.is.bind(_, String)
-			#else
-				Std.isOfType.bind(_, String)
-			#end
-		);
-		add("%VALUE is too short", function (s) return s.length >= 3);
-		add("%VALUE contains invalid characters", Data.alphanum.match);
-		add("%VALUE is a reserved name", function(s) return RESERVED_NAMES.indexOf(s.toLowerCase()) == -1);
-		add("%VALUE ends with a reserved suffix", function(s) {
-			s = s.toLowerCase();
-			for (ext in RESERVED_EXTENSIONS)
-				if (s.endsWith(ext)) return false;
-			return true;
-		});
-
-		a;
-	}
-
-	/**
-		Validates that the project name is valid.
-
-		If it is invalid, returns `Some(e)` where e is an error
-		detailing why the project name is invalid.
-
-		If it is valid, returns `None`.
-	 **/
-	public function validate()
-		return toValidatable().validate();
-
-	/**
-		Returns `s` as a `ProjectName` if it is valid,
-		otherwise throws an error explaining why it is invalid.
-	 **/
-	static public function ofString(s:String)
-		return switch new ProjectName(s) {
-			case _.toValidatable().validate() => Some(e): throw e;
-			case v: v;
-		}
-
-	/** Default project name **/
-	static public var DEFAULT(default, null) = new ProjectName('unknown');
-}
-
 /** Class providing functions for working with project information. **/
 class Data {
 
@@ -399,15 +350,22 @@ class Data {
 		}
 	}
 
-	/** Extracts project information from `jsondata`, validating it according to `check`. **/
-	public static function readData( jsondata: String, check : CheckLevel ) : Infos {
+	/**
+		Extracts project information from `jsondata`, validating it according to `check`.
+
+		`defaultName` is the project name to use if it is empty when the check value allows it.
+	**/
+	public static function readData( jsondata: String, check : CheckLevel, ?defaultName:ProjectName ) : Infos {
+		if (defaultName == null)
+			defaultName = ProjectName.DEFAULT;
+
 		var doc:Infos =
 			try Json.parse(jsondata)
 			catch ( e : Dynamic )
 				if (check >= CheckLevel.CheckSyntax)
 					throw 'JSON parse error: $e';
 				else {
-					name : ProjectName.DEFAULT,
+					name : defaultName,
 					url : '',
 					version : SemVer.DEFAULT,
 					releasenote: 'No haxelib.json found',
@@ -436,7 +394,7 @@ class Data {
 			doc.classPath = '';
 
 		if (doc.name.validate() != None)
-			doc.name = ProjectName.DEFAULT;
+			doc.name = defaultName;
 
 		if (doc.description == null)
 			doc.description = '';

src/haxelib/ProjectName.hx

@@ -0,0 +1,82 @@
+package haxelib;
+
+import haxe.Json;
+import haxe.ds.Option;
+
+import haxelib.Validator;
+
+using StringTools;
+
+/** A valid project name string. **/
+abstract ProjectName(String) to String {
+	static var RESERVED_NAMES = ["haxe", "all"];
+	static var RESERVED_EXTENSIONS = ['.zip', '.hxml'];
+
+	inline function new(s:String)
+		this = s;
+
+	@:to function toValidatable():Validatable
+		return {
+			validate: function():Option<String> {
+				for (r in rules)
+					if (!r.check(this))
+						return Some(r.msg.replace('%VALUE', '`' + Json.stringify(this) + '`'));
+				return None;
+			}
+		}
+
+	static var rules = { // using an array because order might matter
+		var a = new Array<{msg:String, check:String->Bool}>();
+		function add(m, r)
+			a.push({msg: m, check: r});
+		add("%VALUE is not a String", #if (haxe_ver < 4.1) Std.is .bind(_, String) #else Std.isOfType.bind(_, String) #end
+		);
+		add("%VALUE is too short", function(s) return s.length >= 3);
+		add("%VALUE contains invalid characters", Data.alphanum.match);
+		add("%VALUE is a reserved name", function(s) return RESERVED_NAMES.indexOf(s.toLowerCase()) == -1);
+		add("%VALUE ends with a reserved suffix", function(s) {
+			s = s.toLowerCase();
+			for (ext in RESERVED_EXTENSIONS)
+				if (s.endsWith(ext))
+					return false;
+			return true;
+		});
+		a;
+	}
+
+	/**
+		Validates that the project name is valid.
+
+		If it is invalid, returns `Some(e)` where e is an error
+		detailing why the project name is invalid.
+
+		If it is valid, returns `None`.
+	**/
+	public function validate()
+		return toValidatable().validate();
+
+	public function toLowerCase():ProjectName
+		return new ProjectName(this.toLowerCase());
+
+	/**
+		Returns `s` as a `ProjectName` if it is valid,
+		otherwise throws an error explaining why it is invalid.
+	**/
+	static public function ofString(s:String)
+		return switch new ProjectName(s) {
+			case _.toValidatable().validate() => Some(e): throw e;
+			case v: v;
+		}
+
+	/**
+		If `alias` is just a different capitalization of `correct`, returns `correct`.
+
+		If `alias` is completely different, returns `alias` instead.
+	**/
+	static public function getCorrectOrAlias(correct:ProjectName, alias:ProjectName) {
+		return if (correct.toLowerCase() == alias.toLowerCase()) correct else alias;
+	}
+
+	/** Default project name **/
+	static public var DEFAULT(default, null) = new ProjectName('unknown');
+}

src/haxelib/Util.hx

@@ -0,0 +1,60 @@
+package haxelib;
+
+#if macro
+import haxe.macro.Expr;
+
+using haxe.macro.Tools;
+#end
+
+using StringTools;
+
+class Util {
+	macro static public function rethrow(e) {
+		return if (haxe.macro.Context.defined("neko"))
+			macro neko.Lib.rethrow(e);
+		else
+			macro throw e;
+	}
+
+	#if macro
+	static function readVersionFromHaxelibJson() {
+		return haxe.Json.parse(sys.io.File.getContent("haxelib.json")).version;
+	}
+	#end
+
+	macro static public function getHaxelibVersion() {
+		return macro $v{readVersionFromHaxelibJson()};
+	}
+
+	macro static public function getHaxelibVersionLong() {
+		var version:String = readVersionFromHaxelibJson();
+		var p;
+		try {
+			//check if the .git folder exist
+			//prevent getting the git info of a parent directory
+			if (!sys.FileSystem.isDirectory(".git"))
+				throw "Not a git repo.";
+
+			//get commit sha
+			p = new sys.io.Process("git", ["rev-parse", "HEAD"]);
+			final sha = p.stdout.readAll().toString().trim();
+			p.close();
+
+			//check to see if there is changes, staged or not
+			p = new sys.io.Process("git", ["status", "--porcelain"]);
+			final changes = p.stdout.readAll().toString().trim();
+			p.close();
+
+			version += switch(changes) {
+				case "":
+					' ($sha)';
+				case _:
+					' ($sha - dirty)';
+			}
+			return macro $v{version};
+		} catch(e:Dynamic) {
+			if (p != null) p.close();
+			return macro $v{version};
+		}
+	}
+}