New example for a data playground Terraform setup

examples/data-solutions/data-playground/README.md

@@ -0,0 +1,42 @@
+# Data Playground
+
+This example creates a minimum viable template for a data experimentation project with the needed APIs enabled, basic VPC and Firewall set in place, GCS bucket and an AI notebook to get started.
+
+## Managed resources and services
+
+This sample creates several distinct groups of resources:
+
+- projects
+    - Service Project configured for GCE instances and GCS buckets
+- networking
+    - VPC network
+    - One default subnet
+    - Firewall rules for [SSH access via IAP](https://cloud.google.com/iap/docs/using-tcp-forwarding) and open communication within the VPC
+- Vertex AI notebook
+  - One Jupyter lab notebook instance with public access
+- GCS
+    - One bucket initial bucket
+
+
+
+## Variables
+| name                   | description                                                                                                              | type   | required | default             |
+| ---------------------- | ------------------------------------------------------------------------------------------------------------------------ | ------ | -------- | ------------------- |
+| billing\_account       | Billing account id used as default for new projects.                                                                     | string | ✓        |                     |
+| project\_service\_name | Name for the project.                                                                                                    | string | ✓        |                     |
+| root\_node             | The resource name of the parent Folder or Organization. Must be of the form folders/folder\_id or organizations/org\_id. | string | ✓        |                     |
+| location               | The location where resources will be deployed                                                                            | string |          | europe              |
+| region                 | The region where resources will be deployed.                                                                             | string |          | europe-west1        |
+| zone                   | The zone where resources will be deployed.                                                                               | string |          | b                   |
+| vpc\_ip\_cidr\_range   | Ip range used in the subnet deployed in the project                                                                      | string |          | 10.0.0.0/20         |
+| vpc\_name              | Name of the VPC created in the project.                                                                                  | string |          | data-playground-vpc |
+| vpc\_subnet\_name      | Name of the subnet created in the project                                                                                | string |          | default-subnet      |
+
+
+## Outputs
+| Name                                                                                                                                                  | Description             |
+| ----------------------------------------------------------------------------------------------------------------------------------------------------- | ----------------------- |
+| bucket  | GCS Bucket URL.         |
+| project | Project id              |
+| vpc                                                                                                                                                   | VPC Network name        |
+| notebook                                                                                                                                              | Vertex AI notebook name |

examples/data-solutions/data-playground/main.tf

@@ -0,0 +1,101 @@
+# Copyright 2022 Google LLC
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     https://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+###############################################################################
+#                                   Project                                   #
+###############################################################################
+
+module "project" {
+  source          = "../../../modules/project"
+  billing_account = var.billing_account
+  name            = var.project_name
+  parent          = var.root_node
+  prefix          = "data-playground"
+
+  services = [
+    "stackdriver.googleapis.com",
+    "compute.googleapis.com",
+    "storage-component.googleapis.com",
+    "storage.googleapis.com",
+    "servicenetworking.googleapis.com",
+    "bigquery.googleapis.com",
+    "bigquerystorage.googleapis.com",
+    "bigqueryreservation.googleapis.com",
+    "dataflow.googleapis.com",
+    "notebooks.googleapis.com",
+    "composer.googleapis.com"
+  ]
+}
+
+###############################################################################
+#                                Networking                                   #
+###############################################################################
+
+module "vpc" {
+  source     = "../../../modules/net-vpc"
+  project_id = module.project.project_id
+  name       = var.vpc_name
+  subnets = [
+    {
+      ip_cidr_range      = var.vpc_ip_cidr_range
+      name               = var.vpc_subnet_name
+      region             = var.region
+      secondary_ip_range = {}
+    }
+  ]
+}
+
+module "vpc-firewall" {
+  source       = "../../../modules/net-vpc-firewall"
+  project_id   = module.project.project_id
+  network      = module.vpc.name
+  admin_ranges = [var.vpc_ip_cidr_range]
+}
+
+###############################################################################
+#                                GCS                                          #
+###############################################################################
+
+module "base-gcs-bucket" {
+  source     = "../../../modules/gcs"
+  project_id = module.project.project_id
+  prefix     = module.project.project_id
+  name       = "base"
+}
+
+###############################################################################
+#                         Vertex AI Notebook                                   #
+###############################################################################
+
+resource "google_notebooks_instance" "playground" {
+  name         = "data-play-notebook"
+  location     = format("%s-%s", var.region, var.zone)
+  machine_type = "e2-medium"
+  project      = module.project.project_id
+
+  container_image {
+    repository = "gcr.io/deeplearning-platform-release/base-cpu"
+    tag        = "latest"
+  }
+
+  install_gpu_driver = true
+  boot_disk_type     = "PD_SSD"
+  boot_disk_size_gb  = 110
+
+  no_public_ip    = false
+  no_proxy_access = false
+
+  network = module.vpc.network.id
+  subnet  = module.vpc.subnets[format("%s/%s", var.region, var.vpc_subnet_name)].id
+}

examples/data-solutions/data-playground/outputs.tf

@@ -0,0 +1,33 @@
+# Copyright 2022 Google LLC
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     https://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+output "bucket" {
+  description = "GCS Bucket URL."
+  value       = module.base-gcs-bucket.url
+}
+
+output "project" {
+  description = "Project id"
+  value       = module.project.project_id
+}
+
+output "vpc" {
+  description = "VPC Network"
+  value       = module.vpc.name
+}
+
+output "notebook" {
+  description = "Vertex AI notebook"
+  value       = resource.google_notebooks_instance.playground.name
+}

examples/data-solutions/data-playground/variables.tf

@@ -0,0 +1,64 @@
+# Copyright 2022 Google LLC
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     https://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+variable "billing_account" {
+  description = "Billing account id used as default for new projects."
+  type        = string
+}
+
+variable "location" {
+  description = "The location where resources will be deployed."
+  type        = string
+  default     = "europe"
+}
+
+variable "project_name" {
+  description = "Name for the project."
+  type        = string
+}
+
+variable "region" {
+  description = "The region where resources will be deployed."
+  type        = string
+  default     = "europe-west1"
+}
+
+variable "zone" {
+  description = "The zone where resources will be deployed."
+  type        = string
+  default     = "b"
+}
+
+variable "root_node" {
+  description = "The resource name of the parent Folder or Organization. Must be of the form folders/folder_id or organizations/org_id."
+  type        = string
+}
+
+variable "vpc_ip_cidr_range" {
+  description = "Ip range used in the subnet deployed in the project."
+  type        = string
+  default     = "10.0.0.0/20"
+}
+
+variable "vpc_name" {
+  description = "Name of the VPC created in the project."
+  type        = string
+  default     = "data-playground-vpc"
+}
+
+variable "vpc_subnet_name" {
+  description = "Name of the subnet created in the project."
+  type        = string
+  default     = "default-subnet"
+}

examples/data-solutions/data-playground/versions.tf

@@ -0,0 +1,27 @@
+# Copyright 2022 Google LLC
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     https://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+terraform {
+  required_version = ">= 1.1.0"
+  required_providers {
+    google = {
+      source  = "hashicorp/google"
+      version = ">= 4.17.0"
+    }
+    google-beta = {
+      source  = "hashicorp/google-beta"
+      version = ">= 4.17.0"
+    }
+  }
+}