build.gradle

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'eclipse'
apply plugin: 'maven'
apply plugin: 'signing'

group = 'nl.javadude.scannit'
version = '1.4.1-SNAPSHOT'

repositories {
	mavenCentral()
}

project.ext.trueZipVersion="7.7.8"

configurations {
}

dependencies {
	compile "org.javassist:javassist:3.17.1-GA"
	compile "org.slf4j:slf4j-api:1.7.12"
	compile "de.schlichtherle.truezip:truezip-kernel:${trueZipVersion}"
	compile "de.schlichtherle.truezip:truezip-file:${trueZipVersion}"
	compile "de.schlichtherle.truezip:truezip-driver-zip:${trueZipVersion}"
	testCompile "junit:junit:4.12"
	testCompile "org.hamcrest:hamcrest-core:1.3"
	testCompile "org.hamcrest:hamcrest-library:1.3"
	testRuntime "ch.qos.logback:logback-classic:1.1.3"
}

task sourcesJar(type: Jar) {
	from sourceSets.main.allSource
	classifier = 'sources'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
	classifier = "javadoc"
	from javadoc.destinationDir
}

artifacts {
	archives sourcesJar, javadocJar
}

signing {
	required { gradle.taskGraph.hasTask("uploadArchives") }
	sign configurations.archives
}

uploadArchives {
	if(project.hasProperty('sonatypeUsername')) {
		repositories.mavenDeployer {
			beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
			configuration = configurations.archives

			repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2") {
				authentication(userName: sonatypeUsername, password: sonatypePassword)
			}
			snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
				authentication(userName: sonatypeUsername, password: sonatypePassword)
			}

			pom.project {
				name "Scannit"
				packaging "jar"
				description "An extensible Java Metadata/annotation scanner"
				url "https://github.com/hierynomus/scannit"
				inceptionYear "2011"

				scm {
					url "https://github.com/hierynomus/scannit/"
				}

				licenses {
					license {
						name "The Apache Software License, Version 2.0"
						url "http://www.apache.org/licenses/LICENSE-2.0.txt"
						distribution "repo"
					}
				}

				developers {
					developer {
						id "hierynomus"
						name "Jeroen van Erp"
						url "http://www.javadude.nl"
						roles {
							role "Developer"
						}
					}
				}
			}
		}
	}
}