zsh expands arguments to scp/rsync

[skwp]

Sorin, I don't know if you want to integrate this little hack, or if there's a better way around. But I found zsh is a little annoying with the way you have to handle arguments to remote commands like scp/rsync. For example if you try to

rsync remote:/path/to/* . then it gives you an error like no matches found because it tries to expand the star glob locally.

The following link has a small bit of zsh code that combats that by auto escaping globs in remote commands.
http://superuser.com/questions/420525/scp-with-zsh-no-matches-found

Here is the code fragment:

autoload -U url-quote-magic
zle -N self-insert url-quote-magic
zstyle -e :urlglobber url-other-schema \
'[[ $words[1] == scp ]] && reply=("*") || reply=(http https ftp)'

What are your thoughts on this, as I am too much of a zsh noob to know if this is a good solution. It does seem to work...

[sorin-ionescu]

Would alias scp='noglob scp' fix that? Right now, I have alias scp='nocorrect scp' in utility/init.zsh.

[skwp]

Yeah that's another possible solution. Do you think alias is better?

[sorin-ionescu]

Yes, the following should fix the problem. I'm not sure why there is a nocorrect scp there. It must be an Oh My Zsh cruft.

alias rsync='noglob rsync'
alias scp='noglob scp'

Is there anything else in utility that should be noglob instead of nocorrect?

[sorin-ionescu]

I need an answer to my last question to know if I should just push with just those two aliases.

[skwp]

Probably ftp and sftp should go into that list as well. That's all I can think of for now.

[claudioabreu]

Yes, the following should fix the problem. I'm not sure why there is a nocorrect scp there. It must be an Oh My Zsh cruft.

alias rsync='noglob rsync'
alias scp='noglob scp'

Is there anything else in utility that should be noglob instead of nocorrect?

I know this topic is closed, but my solution for both rsync and scp follows:

In my ~/.zshrc I put:

alias scp='noglob scp_wrap'
function scp_wrap {
  local -a args
  local i
  for i in "$@"; do case $i in
    (*:*) args+=($i) ;;
    (*) args+=(${~i}) ;;
  esac; done
  command scp "${(@)args}"
}

alias rsync='noglob rsync_wrap'
function rsync_wrap {
  local -a args
  local i
  for i in "$@"; do case $i in
    (*:*) args+=($i) ;;
    (*) args+=(${~i}) ;;
  esac; done
  command rsync "${(@)args}"
}

[sjackman]

Since the noglob rsync alias is enabled by default, how do you run rsync if you do want globbing for a particular execution of that command? Is there a command like doglob rsync *.txt remote:/tmp/?

[sjackman]

Answered my own question (less than a minute later, sorry for the noise). The answer is command rsync *.txt remote:/tmp/ to use globbing for this one invocation of the command, and unalias rsync to use globbing for the lifetime of this shell.