Add nix flake

.envrc

@@ -0,0 +1,4 @@
+if ! has nix_direnv_version || ! nix_direnv_version 2.3.0; then
+  source_url "https://raw.githubusercontent.com/nix-community/nix-direnv/2.3.0/direnvrc" "sha256-Dmd+j63L84wuzgyjITIfSxSD57Tx7v51DMxVZOsiUD8="
+fi
+use flake

.gitignore

@@ -15,3 +15,5 @@ ipl.rom
 
 !res/qoob_pro_none_upgrade.elf
 !res/qoob_sx_13c_upgrade.elf
+
+.direnv

default.nix

@@ -0,0 +1,7 @@
+(import (let
+  lockFile = builtins.fromJSON (builtins.readFile ./flake.lock);
+  info = lockFile.nodes.flake-compat.locked;
+in builtins.fetchTarball {
+  url = "https://api.${info.host or "github.com"}/repos/${info.owner}/${info.repo}/tarball/${info.rev}";
+  ${if info ? narHash then "sha256" else null} = info.narHash;
+}) { src = ./.; }).defaultNix

flake.nix

@@ -0,0 +1,70 @@
+{
+  description = "A utilitarian bootloader for the GameCube";
+
+  inputs = {
+    flake-compat = {
+      url = "github:edolstra/flake-compat";
+      flake = false;
+    };
+    nixpkgs.url = "github:9ary/nixpkgs/devkitPPC";
+    flake-parts = {
+      url = "github:hercules-ci/flake-parts";
+      inputs.nixpkgs-lib.follows = "nixpkgs";
+    };
+    systems.flake = false;
+  };
+
+  outputs = { ... } @ inputs: inputs.flake-parts.lib.mkFlake {
+    inherit inputs;
+  } ({ config, flake-parts-lib, getSystem, inputs, lib, options, ... }:
+    let
+      rootConfig = config;
+      rootOptions = options;
+    in
+    {
+      _file = ./flake.nix;
+      imports = [ ];
+      config.perSystem = { config, inputs', nixpkgs, options, pkgs, system, ... }:
+        let
+          systemConfig = config;
+          systemOptions = options;
+        in
+        {
+          _file = ./flake.nix;
+          config = {
+            devShells.default = pkgs.callPackage
+              ({ mkShell
+              , devkitPPC
+              , gamecube-tools
+              , meson
+              , ninja
+              , p7zip
+              , python3
+              }: mkShell {
+                name = "iplboot";
+                nativeBuildInputs = [
+                  # The cross toolchain
+                  devkitPPC
+                  gamecube-tools
+
+                  # The build system
+                  meson ninja
+
+                  # Compressing binaries and the release archive
+                  p7zip
+
+                  # For build scripts
+                  python3
+                ];
+
+                env = {
+                  # For the libogc2 Makefile
+                  DEVKITPPC = devkitPPC;
+                };
+              })
+              { };
+          };
+        };
+      config.systems = import inputs.systems;
+  });
+}

shell.nix

@@ -0,0 +1,7 @@
+(import (let
+  lockFile = builtins.fromJSON (builtins.readFile ./flake.lock);
+  info = lockFile.nodes.flake-compat.locked;
+in builtins.fetchTarball {
+  url = "https://api.${info.host or "github.com"}/repos/${info.owner}/${info.repo}/tarball/${info.rev}";
+  ${if info ? narHash then "sha256" else null} = info.narHash;
+}) { src = ./.; }).shellNix