added ANTLR visitor for parsing Logstash configuration

build.gradle

@@ -45,6 +45,7 @@ subprojects {
     sourceCompatibility = '1.8'
     spotless {
         java {
+            targetExclude 'build/generated-src/antlr/**'
             // TODO: enrich format rules
             removeUnusedImports()
         }

config/checkstyle/checkstyle-suppressions.xml

@@ -0,0 +1,9 @@
+<?xml version="1.0"?>
+<!DOCTYPE suppressions PUBLIC
+        "-//Puppy Crawl//DTD Suppressions 1.1//EN"
+        "http://checkstyle.sourceforge.net/dtds/suppressions_1_1.dtd">
+
+<suppressions>
+    <!-- suppress all checks on files generated by ANTLR -->
+    <suppress files="data-prepper-logstash-configuration[\\/]build[\\/]generated-src[\\/]antlr[\\/]main[\\/]*" checks="[a-zA-Z0-9]*"/>
+</suppressions>

config/checkstyle/checkstyle.xml

@@ -6,6 +6,10 @@
 <module name="Checker">
     <property name="charset" value="UTF-8" />
 
+    <module name="SuppressionFilter">
+        <property name="file" value="${config_loc}/checkstyle-suppressions.xml" />
+    </module>
+
     <!-- Checks Java files and forbids empty Javadoc comments -->
     <module name="RegexpMultiline">
         <property name="id" value="EmptyJavadoc"/>

data-prepper-logstash-configuration/build.gradle

@@ -0,0 +1,23 @@
+plugins {
+    id 'java'
+    id 'antlr'
+    id 'idea'
+}
+
+repositories {
+    mavenCentral()
+}
+
+dependencies {
+    antlr "org.antlr:antlr4:4.9.2"
+    testImplementation "org.hamcrest:hamcrest:2.2"
+    testImplementation "org.mockito:mockito-inline:${versionMap.mockito}"
+    testImplementation platform("org.junit:junit-bom:${versionMap.junitJupiter}")
+}
+
+generateGrammarSource {
+    maxHeapSize = "128m"
+    arguments += ['-listener', '-visitor']
+    outputDirectory = new File("build/generated-src/antlr/main/org/opensearch/dataprepper/logstash/".toString())
+}
+compileJava.dependsOn generateGrammarSource

data-prepper-logstash-configuration/src/main/antlr/Logstash.g4

@@ -0,0 +1,141 @@
+/*
+* ANTLR grammar file for parsing Logstash configurations
+*/
+grammar Logstash;
+
+@header {
+    package org.opensearch.dataprepper.logstash;
+}
+/*
+* Parser Rules
+*/
+config: filler plugin_section filler (filler plugin_section)* filler;
+
+filler: (COMMENT | WS | NEWLINE)*;
+
+plugin_section: plugin_type filler '{'
+      filler (branch_or_plugin filler)*
+    '}';
+
+plugin_type: ('input' | 'filter' | 'output');
+
+branch_or_plugin: branch | plugin;
+
+plugin:
+    name filler '{'
+      filler
+      attributes
+      filler
+    '}';
+
+attributes:( attribute (filler attribute)*)?;
+
+attribute: name filler '=>' filler value;
+
+name: BAREWORD | STRING;
+
+value: plugin | BAREWORD | STRING | NUMBER | array | hash;
+
+branch: r_if (filler else_if)* (filler r_else)?;
+
+r_if: 'if' filler condition filler '{' filler (branch_or_plugin filler)* '}';
+
+else_if: 'else' filler 'if' filler condition filler '{' filler ( branch_or_plugin filler)* '}';
+
+r_else: 'else' filler '{' filler (branch_or_plugin filler)* '}';
+
+condition: expression (filler boolean_operator filler expression)*;
+
+expression:
+    (
+        ('(' filler condition filler ')')
+      | negative_expression
+      | in_expression
+      | not_in_expression
+      | compare_expression
+      | regexp_expression
+      | rvalue
+    );
+
+array:
+    '['
+    filler
+    (
+      value (filler ',' filler value)*
+    )?
+    filler
+    ']';
+
+hash:
+    '{'
+      filler
+      hashentries?
+      filler
+    '}';
+
+hashentries: hashentry (WS hashentry)*;
+
+hashentry: hashname filler '=>' filler value;
+
+hashname: BAREWORD | STRING | NUMBER;
+
+boolean_operator: ('and' | 'or' | 'xor' | 'nand');
+
+negative_expression:
+    (
+        ('!' filler '(' filler condition filler ')')
+      | ('!' filler selector)
+    );
+
+in_expression: rvalue filler in_operator filler rvalue;
+
+not_in_expression: rvalue filler not_in_operator filler rvalue;
+
+rvalue: STRING | NUMBER | selector | array | method_call | regexp;
+
+regexp:  '/' ('\\' | ~'/' .)*? '/';
+
+selector: selector_element+;
+
+compare_expression: rvalue filler compare_operator filler rvalue;
+
+regexp_expression: rvalue filler  regexp_operator filler (STRING | regexp);
+
+selector_element: '[' ~( '[' | ']' | ',' )+ ']';
+
+in_operator: 'in';
+
+not_in_operator: 'not' filler 'in';
+
+method_call:
+      BAREWORD filler '(' filler
+        (
+          rvalue ( filler ',' filler rvalue )*
+        )?
+      filler ')';
+
+compare_operator: ('==' | '!=' | '<=' | '>=' | '<' | '>') ;
+
+regexp_operator: ('=~' | '!~');
+
+/*
+* Lexer Rules
+*/
+
+COMMENT: (WS? '#' ~('\r'|'\n')*)+;
+
+NEWLINE: ('\r'? '\n' | '\r')+ -> skip;
+
+WS: ( NEWLINE | ' ' | '\t')+;
+
+fragment DIGIT: [0-9];
+
+NUMBER: '-'? DIGIT+ ('.' DIGIT*)?;
+
+BAREWORD: [a-zA-Z0-9_]+;
+
+STRING: DOUBLE_QUOTED_STRING | SINGLE_QUOTED_STRING;
+
+fragment DOUBLE_QUOTED_STRING : ('"' ( '\\"' | . )*? '"');
+
+fragment SINGLE_QUOTED_STRING : ('\'' ('\'' | . )*? '\'');

data-prepper-logstash-configuration/src/main/java/org/opensearch/dataprepper/logstash/exception/LogstashConfigurationException.java

@@ -0,0 +1,13 @@
+package org.opensearch.dataprepper.logstash.exception;
+
+/**
+ * Exception for Logstash configuration converter
+ *
+ * @since 1.2
+ */
+public class LogstashConfigurationException extends RuntimeException {
+
+    public LogstashConfigurationException(String errorMessage) {
+        super(errorMessage);
+    }
+}

data-prepper-logstash-configuration/src/main/java/org/opensearch/dataprepper/logstash/exception/LogstashGrammarException.java

@@ -0,0 +1,13 @@
+package org.opensearch.dataprepper.logstash.exception;
+
+/**
+ * Exception thrown when ANTLR fails to parse the Logstash configuration
+ *
+ * @since 1.2
+ */
+public class LogstashGrammarException extends LogstashParsingException {
+
+    public LogstashGrammarException(String errorMessage) {
+        super(errorMessage);
+    }
+}

data-prepper-logstash-configuration/src/main/java/org/opensearch/dataprepper/logstash/exception/LogstashParsingException.java

@@ -0,0 +1,13 @@
+package org.opensearch.dataprepper.logstash.exception;
+
+/**
+ * Exception thrown when ANTLR visitor is unable to convert Logstash configuration into Logstash model objects
+ *
+ * @since 1.2
+ */
+public class LogstashParsingException extends LogstashConfigurationException {
+
+    public LogstashParsingException(String errorMessage) {
+        super(errorMessage);
+    }
+}

data-prepper-logstash-configuration/src/main/java/org/opensearch/dataprepper/logstash/model/LogstashPluginType.java

@@ -1,12 +1,35 @@
 package org.opensearch.dataprepper.logstash.model;
 
+import java.util.Arrays;
+import java.util.Map;
+import java.util.function.Function;
+import java.util.stream.Collectors;
+
 /**
  * Types of plugins in Logstash configuration
  *
  * @since 1.2
  */
 public enum LogstashPluginType {
-    INPUT,
-    FILTER,
-    OUTPUT
+    INPUT("input"),
+    FILTER("filter"),
+    OUTPUT("output");
+
+    private final String value;
+
+    private static final Map<String, LogstashPluginType> VALUES_MAP = Arrays.stream(LogstashPluginType.values())
+            .collect(Collectors.toMap(LogstashPluginType::toString, Function.identity()));
+
+    LogstashPluginType(final String value) {
+        this.value = value;
+    }
+
+    @Override
+    public String toString() {
+        return value;
+    }
+
+    public static LogstashPluginType getByValue(final String value) {
+        return VALUES_MAP.get(value.toLowerCase());
+    }
 }