Add flake.nix

flake.nix

@@ -0,0 +1,43 @@
+{
+  description = "like jq, but for HTML.";
+
+  inputs = {
+    nixpkgs.url = "nixpkgs"; # Resolves to github:NixOS/nixpkgs
+    # Helpers for system-specific outputs
+    flake-utils.url = "github:numtide/flake-utils";
+    crate2nix = {
+      url = "github:kolloch/crate2nix";
+      flake = false;
+    };
+  };
+
+  outputs = { self, nixpkgs, crate2nix, flake-utils }:
+    # Create system-specific outputs for the standard Nix systems
+    # https://github.com/numtide/flake-utils/blob/master/default.nix#L3-L9
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system};
+        crateName = "htmlq";
+
+        inherit (import "${crate2nix}/tools.nix" { inherit pkgs; })
+          generatedCargoNix;
+
+        project = pkgs.callPackage (generatedCargoNix {
+          name = crateName;
+          src = ./.;
+        }) {
+          defaultCrateOverrides = pkgs.defaultCrateOverrides // {
+            # Crate dependency overrides go here
+          };
+        };
+      in {
+        packages.${crateName} = project.rootCrate.build;
+
+        defaultPackage = self.packages.${system}.${crateName};
+
+        devShell = pkgs.mkShell {
+          inputsFrom = builtins.attrValues self.packages.${system};
+          buildInputs = [ pkgs.cargo pkgs.rust-analyzer pkgs.clippy ];
+        };
+      });
+}