How to change Janet's REPL prompt?

[MaxGyver83]

When I start janet, I see a prompt like this:

repl:1:>

I'm wondering how I can change it. I expected that it was defined somewhere in shell.c but it's not. Actually, it's defined in the function getprompt within cli-main in boot.janet.

Of course, I could change this function in the Janet source code and rebuild the project.

But as this is a Janet function, I guess it should be possible to change it without recompiling.

I have tried to copy defn cli-main + defn- run-main + def- getenv-alias to a file named ./profile.janet, to modify getprompt and to run JANET_PROFILE=profile.janet janet. But this doesn't change the prompt.

Is it possible at all to change the prompt at run-time? (I'm not asking because I need a different prompt so much but because I want to learn about Janet.)

[MaxGyver83]

I also tried to rename cli-main to cli-main-new in profile.janet and then in the REPL:

repl:1:> (set ((env-lookup (curenv)) 'cli-main) cli-main-new)
<function cli-main-new>

But still no effect.

Another try without luck:

repl:2:> (def cli-main cli-main-new)

[sogaiu]

This has been something I've wanted a nice way for as well but I haven't had much success. May be someone else has though (^^;

Some not-so-satisfactory approaches that I've used include:

1. Remove the prompt altogether -- invoke janet with TERM set to dumb: TERM=dumb janet

   $ TERM=dumb janet
   Janet 1.33.0-1394f1a5 linux/x64/gcc - '(doc)' for help
   (/ 2 3)
   0.666666666666667
   

2. Write a replacement program (in Janet, not C) that has a copy-modified boot.janet in it and use it instead of directly invoking janet. There is an example of that here [1]. Once installed, invoke like jref -r:

   $ jref -r
   jref - Janet 1.33.0-1394f1a5 linux/x64/gcc - '(doc)' for help
   (+ 1 2)
   # =>
   3
   
   

3. Modify boot.janet, rebuild janet, and use the customized janet as you mentioned already.

I hadn't tried your profile-based approach, may be I'll investigate that a bit.

---

[1] See this file for the modifications to pieces of boot.janet if interested.

[sogaiu]

So regarding the profile-based idea...

I think the TLDR is that the code that loads something specified by JANET_PROFILE lives inside the baked-in cli-main (that is defined in boot.janet) and thus, the profile-based approach is kind of "too late" as far as replacing cli-main is concerned. At least I don't think one can prevent the built-in cli-main from running (as it's hard-wired in shell.c).

It's possible to put an alternate cli-main in a file pointed at by JANET_PROFILE, start janet and invoke (cli-main (dyn :args)) to get the alternate version to run, but may be that's not so nice (^^;

[MaxGyver83]

Thank you. Calling (cli-main (dyn :args)) is an interesting option.

Maybe it's also possible to disassemble the original cli-main with (disasm cli-main), then to modify it and assemble it again!? Could this have an effect on the already running "instance" of cli-main?

[sogaiu]

I suspect that won't work because the bytecode for an already running instance of cli-main (a "fiber" in Janet's terms I think) will be a copy [1] made of bytecode baked-in to janet (the executable) and not be the same thing as the modified bytecode.

If that's off, may be someone can point that out (^^;

---

[1] At least partly if not fully...Not sure.

[sogaiu]

As a follow-up, to remove the "sub-prompts" (the prompts that hint about unclosed delimiters), I tried the following sort of thing (mildly adapting part of what is expressed in boot.janet's cli-main):

(def env (make-env))

(defn my-get-prompt
  [p]
  (def [line] (parser/where p))
  (if (empty? (parser/state p :delimiters))
    (string "repl:" line ":" "> ")
    ""))

(defn my-getstdin [prompt buf _]
  (file/write stdout prompt)
  (file/flush stdout)
  (file/read stdin :line buf))

(defn my-getchunk
  [buf p]
  # getline may not do what you want in some contexts (e.g. within emacs)
  (my-getstdin (my-get-prompt p) buf env))

(repl my-getchunk nil env)

What this might be useful for is in the context of editor tooling that might not want to be exposed to the aforementioned subprompts.

I plugged it into ajrepl and it seems to be working so far in limited testing.

[MaxGyver83]

Could you give an example how to use it?

I have tried this:
./janetrc:

(fn getprompt [p]
 (def [line] (parser/where p))
 (string "repl:" line ":" (parser/state p :delimiters) "$ "))

JANET_PROFILE=./janetrc ./build/janet

But it didn't work.

[sogaiu]

I think if the content of janetrc is this:

(defn getprompt
  [p]
  (def [line] (parser/where p))
  (string "repl:" line ":" (parser/state p :delimiters) "$ "))

you might have more luck.

[MaxGyver83]

Thank you, it works!

[MaxGyver83]

I just noticed that your solution is very similar to what I used in my (unpublished) fork:

commit 023c243f19edf687dce45716d8e343976e9cb52b
Author: Max Schillinger <[email protected]>
Date:   Sat Feb 3 09:55:51 2024 +0100

    Allow custom getprompt function via profile.janet

diff --git a/src/boot/boot.janet b/src/boot/boot.janet
index 46fcabae..49a8e0a6 100644
--- a/src/boot/boot.janet
+++ b/src/boot/boot.janet
@@ -4111,9 +4111,6 @@
         (if-not quiet
           (print "Janet " janet/version "-" janet/build " " (os/which) "/" (os/arch) "/" (os/compiler) " - '(doc)' for help"))
         (flush)
-        (defn getprompt [p]
-          (def [line] (parser/where p))
-          (string "repl:" line ":" (parser/state p :delimiters) "> "))
         (defn getstdin [prompt buf _]
           (file/write stdout prompt)
           (file/flush stdout)
@@ -4126,6 +4123,10 @@
           (put env *debug* true)
           (put env *redef* true))
         (def getter (if raw-stdin getstdin getline))
+        (def user-getprompt (env 'getprompt))
+        (def getprompt (or (if user-getprompt (user-getprompt :value))
+                           (fn [p] (def [line] (parser/where p))
+                               (string "repl:" line ":" (parser/state p :delimiters) "> "))))
         (defn getchunk [buf p]
           (getter (getprompt p) buf env))
         (setdyn *pretty-format* (if colorize "%.20Q" "%.20q"))

[sogaiu]

Oh yes, quite similar :)

---

I'm less confident about using the JANET_PROFILE mechanism for this kind of thing though. See the updated comment for a bit more detail.

[sogaiu]

Possibly of interest might be the recent addition of *repl-prompt*. See here for a relevant commit.

[MaxGyver83]

Sorry for my late response! That's really cool! I have just tested it.