azurerm_cdn_frontdoor_rule - documentation of transforms is wrong

[evandeworp]

Is there an existing issue for this?

• I have searched the existing issues

Community Note

• Please vote on this issue by adding a 👍 reaction to the original issue to help the community and maintainers prioritize this request
• Please do not leave "+1" or "me too" comments, they generate extra noise for issue followers and do not help prioritize the request
• If you are interested in working on this issue or have submitted a pull request, please leave a comment

Terraform Version

1.2.9

AzureRM Provider Version

3.23.0

Affected Resource(s)/Data Source(s)

azurerm_cdn_frontdoor_rule

Terraform Configuration Files

resource "azurerm_resource_group" "example" {
  name     = "example-cdn-frontdoor"
  location = "West Europe"
}

resource "azurerm_cdn_frontdoor_profile" "example" {
  name                = "example-profile"
  resource_group_name = azurerm_resource_group.example.name
}

resource "azurerm_cdn_frontdoor_endpoint" "example" {
  name                     = "example-endpoint"
  cdn_frontdoor_profile_id = azurerm_cdn_frontdoor_profile.example.id

  tags = {
    endpoint = "contoso.com"
  }
}

resource "azurerm_cdn_frontdoor_origin_group" "example" {
  name                     = "example-originGroup"
  cdn_frontdoor_profile_id = azurerm_cdn_frontdoor_profile.example.id
  session_affinity_enabled = true

  restore_traffic_time_to_healed_or_new_endpoint_in_minutes = 10

  health_probe {
    interval_in_seconds = 240
    path                = "/healthProbe"
    protocol            = "Https"
    request_type        = "GET"
  }

  load_balancing {
    additional_latency_in_milliseconds = 0
    sample_size                        = 16
    successful_samples_required        = 3
  }
}

resource "azurerm_cdn_frontdoor_origin" "example" {
  name                          = "example-origin"
  cdn_frontdoor_origin_group_id = azurerm_cdn_frontdoor_origin_group.example.id

  health_probes_enabled          = true
  certificate_name_check_enabled = false

  host_name          = azurerm_cdn_frontdoor_endpoint.example.host_name
  http_port          = 80
  https_port         = 443
  origin_host_header = "contoso.com"
  priority           = 1
  weight             = 500
}

resource "azurerm_cdn_frontdoor_rule_set" "example" {
  name                     = "exampleruleset"
  cdn_frontdoor_profile_id = azurerm_cdn_frontdoor_profile.example.id
}

resource "azurerm_cdn_frontdoor_rule" "example" {
  depends_on = [azurerm_cdn_frontdoor_origin_group.example, azurerm_cdn_frontdoor_origin.example]

  name                      = "examplerule"
  cdn_frontdoor_rule_set_id = azurerm_cdn_frontdoor_rule_set.example.id
  order                     = 1
  behavior_on_match         = "Continue"

  actions {
    route_configuration_override_action {
      cdn_frontdoor_origin_group_id = azurerm_cdn_frontdoor_origin_group.example.id
      forwarding_protocol           = "HttpsOnly"
      query_string_caching_behavior = "IncludeSpecifiedQueryStrings"
      query_string_parameters       = ["foo", "clientIp={client_ip}"]
      compression_enabled           = true
      cache_behavior                = "OverrideIfOriginMissing"
      cache_duration                = "365.23:59:59"
    }

    url_redirect_action {
      redirect_type        = "PermanentRedirect"
      redirect_protocol    = "MatchRequest"
      query_string         = "clientIp={client_ip}"
      destination_path     = "/exampleredirection"
      destination_hostname = "contoso.com"
      destination_fragment = "UrlRedirect"
    }
  }

  conditions {
    host_name_condition {
      operator         = "Equal"
      negate_condition = false
      match_values     = ["www.contoso.com", "images.contoso.com", "video.contoso.com"]
      transform        = ["Lowercase", "Trim"]
    }

    is_device_condition {
      operator         = "Equal"
      negate_condition = false
      match_values     = ["Mobile"]
    }

    post_args_condition {
      post_args_name = "customerName"
      operator       = "BeginsWith"
      match_values   = ["J", "K"]
      transform      = ["Uppercase"]
    }

    request_method_condition {
      operator         = "Equal"
      negate_condition = false
      match_values     = ["DELETE"]
    }

    url_filename_condition {
      operator         = "Equal"
      negate_condition = false
      match_values     = ["media.mp4"]
      transform        = ["Lowercase", "RemoveNulls", "Trim"]
    }
  }
}

Debug Output/Panic Output

Not applicable.

Expected Behaviour

Successful plan should be created since, according to documentation https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/cdn_frontdoor_rule, the argument name in multiple places is "transform" but all these arguments in the documentation should be "transforms".

(Even the example of https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/cdn_frontdoor_rule has "transforms" being used instead of "transform").

Actual Behaviour

PS C:> terraform plan
╷
│ Error: Unsupported argument
│
│ on main.tf line 96, in resource "azurerm_cdn_frontdoor_rule" "example":
│ 96: transform = ["Lowercase", "Trim"]
│
│ An argument named "transform" is not expected here. Did you mean "transforms"?
╵
╷
│ Error: Unsupported argument
│
│ on main.tf line 109, in resource "azurerm_cdn_frontdoor_rule" "example":
│ 109: transform = ["Uppercase"]
│
│ An argument named "transform" is not expected here. Did you mean "transforms"?
╵
╷
│ Error: Unsupported argument
│
│ on main.tf line 122, in resource "azurerm_cdn_frontdoor_rule" "example":
│ 122: transform = ["Lowercase", "RemoveNulls", "Trim"]
│
│ An argument named "transform" is not expected here. Did you mean "transforms"?

Steps to Reproduce

terraform plan

Important Factoids

No response

References

No response

[WodansSon]

@evandeworp, thank you for opening this issue. This issue will be fixed with my latest FrontDoor PR #18231. Fixed with this commit.

[evandeworp]

Since the documentation is being fixed, might as well fix the example in the documentation as well. The example in https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/cdn_frontdoor_rule fails with:

│ Error: Missing required argument
│
│ on main.tf line 6, in resource "azurerm_cdn_frontdoor_profile" "example":
│ 6: resource "azurerm_cdn_frontdoor_profile" "example" {
│
│ The argument "sku_name" is required, but no definition was found.

In the documented example, please change:

resource "azurerm_cdn_frontdoor_profile" "example" {
name = "example-profile"
resource_group_name = azurerm_resource_group.example.name
}

To:

resource "azurerm_cdn_frontdoor_profile" "example" {
name = "example-profile"
resource_group_name = azurerm_resource_group.example.name
sku_name = "Standard_AzureFrontDoor"
}

[WodansSon]

Since the documentation is being fixed, might as well fix the example in the documentation as well. The example in https://registry.terraform.io/providers/hashicorp/azurerm/latest/docs/resources/cdn_frontdoor_rule fails with:

│ Error: Missing required argument │ │ on main.tf line 6, in resource "azurerm_cdn_frontdoor_profile" "example": │ 6: resource "azurerm_cdn_frontdoor_profile" "example" { │ │ The argument "sku_name" is required, but no definition was found.

In the documented example, please change:

resource "azurerm_cdn_frontdoor_profile" "example" { name = "example-profile" resource_group_name = azurerm_resource_group.example.name }

To:

resource "azurerm_cdn_frontdoor_profile" "example" { name = "example-profile" resource_group_name = azurerm_resource_group.example.name sku_name = "Standard_AzureFrontDoor" }

@evandeworp, thanks for the comment, this is a known issue and will be fixed moving forward. As these resources are still currently under development these examples are not guaranteed to work but are only offered as a possible configuration once the resources have been fully released. This is my last task once everything has been finalized with the resources. I will add examples and fix all of the example configurations in the documentation. This is an incredibly complex and difficult resource to implement, so I appreciate your patience while we work this out. 🚀

[github-actions]

I'm going to lock this issue because it has been closed for 30 days ⏳. This helps our maintainers find and focus on the active issues.
If you have found a problem that seems similar to this, please open a new issue and complete the issue template so we can capture all the details necessary to investigate further.