Use with rotary encoder? (just UP DOWN and ENTER)

[rykener]

Is it possible to use this library with a rotary encoder, essentially only having the navigation options of UP DOWN and ENTER? In the examples I'm playing with it seems like you need to also have a LEFT RIGHT and BACK option.

[forntoh]

#29 (reply in thread)

[Amha-Endrayes]

Yes.
This is what I did to get mine setup.
I used this encoder library called SimpleRotary and changed the following in the menu navigation code:
(the example below is based on the callbacks example included in the library)

/*
 Menu Item Callbacks

 https://lcdmenu.forntoh.dev/examples/command-and-toggle

*/

#include <ItemSubMenu.h>
#include <ItemToggle.h>
#include <LcdMenu.h>
#include <SimpleRotary.h> 

#define LCD_ROWS 2
#define LCD_COLS 16

//============================================
// Encoder Connection:
//============================================
// Pin A0 (DT), Pin A1(CLK) and Button Pin A2(SW):
// SimpleRotary menuEncoder(DT, CLK, SW);

SimpleRotary menuEncoder(A0, A1, A2);


// Declare the call back function
void toggleBacklight(uint16_t isOn);

// prettier-ignore
MAIN_MENU(
    ITEM_BASIC("Start service"),
    ITEM_BASIC("Connect to WiFi"),
    ITEM_TOGGLE("Backlight", toggleBacklight),
    ITEM_BASIC("Blink SOS"),
    ITEM_BASIC("Blink random")
);

LcdMenu menu(LCD_ROWS, LCD_COLS);

void setup() {
    Serial.begin(9600);
    menu.setupLcdWithMenu(0x27, mainMenu);
}

void loop() {
    startMenuWithEncoder(); //Function Definition at the Bottom
    
   //add the rest of your code here:
}
/**
 * Define callback
 */
void toggleBacklight(uint16_t isOn) { menu.setBacklight(isOn); }

//===================================================================
// ====================== ADD THIS CUSTOM FUNCION  ========================
//===================================================================
void startMenuWithEncoder() {
  /* Setups the menu to be used with an encoder.
   * You will need the SimpleRotarty Library for it work
   * switches the menu based on: 
   * A: CW or CCW rotation for UP and DOWN
   * B: short or Long SW press for ENTER and BACK 
   */
  byte i, j;

  // i will be: 0 = not turning, 1 = CW, 2 = CCW
  i = menuEncoder.rotate();

  // j will be: 0 = not pushed, 1 = pushed, 2 = long pushed
  j = menuEncoder.pushType(650);   //sets the millsecond button  
				   //has to be pushed for it to 
  				   //beconsidered a long push.

  if (i == 1) {
    menu.up();
  } else if (i == 2) {
    menu.down();
  } else if (j == 1) {
    menu.enter();
  } else if (j == 2) {
    menu.back();
  }

}

I hope this helps.

PS: Thank You @forntoh for the amazing Menu Library!