Minimal Bazel infrastructure (#415).

.gitignore

@@ -1,5 +1,9 @@
 /build
 /docs/landing_source/.bundle
 /generated
+/bazel-*
+/ci/bazel-*
+/ci/prebuilt/thirdparty
+/ci/prebuilt/thirdparty_build
 cscope.*
 BROWSE

WORKSPACE

@@ -0,0 +1,15 @@
+workspace(name = "envoy")
+
+load("//bazel:repositories.bzl", "envoy_dependencies")
+
+envoy_dependencies()
+
+bind(
+    name = "googletest_main",
+    actual = "@googletest//:googletest_main",
+)
+
+bind(
+    name = "spdlog",
+    actual = "@spdlog_git//:spdlog",
+)

bazel/envoy_build_system.bzl

@@ -0,0 +1,47 @@
+# References to Envoy external dependencies should be wrapped with this function.
+def envoy_external_dep_path(dep):
+    return "//external:%s" % dep
+
+ENVOY_COPTS = [
+    "-fno-omit-frame-pointer",
+    "-Wall",
+    "-Wextra",
+    "-Werror",
+    "-Wnon-virtual-dtor",
+    "-Woverloaded-virtual",
+    "-Wold-style-cast",
+    "-std=c++0x",
+    "-includesource/precompiled/precompiled.h",
+    "-iquoteinclude",
+    "-iquotesource",
+]
+
+# Envoy C++ library targets should be specified with this function.
+def envoy_cc_library(name,
+                     srcs = [],
+                     public_hdrs = [],
+                     hdrs = [],
+                     external_deps = [],
+                     deps = [],
+                     copts = []):
+    native.cc_library(
+        name = name,
+        srcs = srcs,
+        hdrs = hdrs + public_hdrs,
+        deps = deps + [envoy_external_dep_path(dep) for dep in external_deps] +
+               ["//source/precompiled:precompiled_includes"],
+        copts = ENVOY_COPTS + copts,
+    )
+
+# Envoy C++ test targets should be specified with this function.
+def envoy_cc_test(name,
+                  srcs = [],
+                  deps = []):
+    native.cc_test(
+        name = name,
+        srcs = srcs,
+        deps = deps + ["//source/precompiled:precompiled_includes",
+                       "//test/precompiled:precompiled_includes"],
+        copts = ENVOY_COPTS + ["-includetest/precompiled/precompiled_test.h"],
+        linkopts = ["-pthread"]
+    )

bazel/repositories.bzl

@@ -0,0 +1,86 @@
+# The build rules below for external dependencies build rules are maintained
+# on a best effort basis. The rules are provided for developer convenience. For production builds,
+# we recommend building the libraries according to their canonical build systems and expressing the
+# dependencies in a manner similar to ci/WORKSPACE.
+
+def googletest_repositories():
+    BUILD = """
+# Copyright 2016 Google Inc. All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#
+################################################################################
+#
+
+cc_library(
+    name = "googletest",
+    srcs = [
+        "googlemock/src/gmock-all.cc",
+        "googletest/src/gtest-all.cc",
+    ],
+    hdrs = glob([
+        "googletest/include/**/*.h",
+        "googlemock/include/**/*.h",
+        "googletest/src/*.cc",
+        "googletest/src/*.h",
+        "googlemock/src/*.cc",
+    ]),
+    includes = [
+        "googlemock",
+        "googlemock/include",
+        "googletest",
+        "googletest/include",
+    ],
+    visibility = ["//visibility:public"],
+)
+
+cc_library(
+    name = "googletest_main",
+    srcs = ["googlemock/src/gmock_main.cc"],
+    visibility = ["//visibility:public"],
+    deps = [":googletest"],
+)
+"""
+    native.new_git_repository(
+        name = "googletest",
+        build_file_content = BUILD,
+        # v1.8.0 release
+        commit = "ec44c6c1675c25b9827aacd08c02433cccde7780",
+        remote = "https://github.com/google/googletest.git",
+    )
+
+def spdlog_repositories():
+    BUILD = """
+package(default_visibility = ["//visibility:public"])
+
+cc_library(
+    name = "spdlog",
+    hdrs = glob([
+        "include/**/*.h",
+        "include/**/*.cc",
+    ]),
+    strip_include_prefix = "include",
+)
+"""
+
+    native.new_git_repository(
+        name = "spdlog_git",
+        build_file_content = BUILD,
+        # v0.11.0 release
+        commit = "1f1f6a5f3b424203a429e9cb78e6548037adefa8",
+        remote = "https://github.com/gabime/spdlog.git",
+    )
+
+def envoy_dependencies():
+    googletest_repositories()
+    spdlog_repositories()

ci/WORKSPACE

@@ -0,0 +1,9 @@
+bind(
+    name = "googletest_main",
+    actual = "//ci/prebuilt:googletest_main",
+)
+
+bind(
+    name = "spdlog",
+    actual = "//ci/prebuilt:spdlog",
+)

ci/do_ci.sh

@@ -6,6 +6,26 @@ set -e
 
 echo "building using $NUM_CPUS CPUs"
 
+if [[ "$1" == "bazel.debug" ]]; then
+  echo "debug bazel build with tests..."
+  cd ci
+  ln -sf /thirdparty prebuilt
+  ln -sf /thirdparty_build prebuilt
+  # Not sandboxing, since non-privileged Docker can't do nested namespaces.
+  echo "Building..."
+  export CC=gcc-4.9
+  export CXX=g++-4.9
+  export USER=bazel
+  export TEST_TMPDIR=/source
+  BAZEL_OPTIONS="--strategy=CppCompile=standalone --strategy=CppLink=standalone \
+    --strategy=TestRunner=standalone --verbose_failures --package_path %workspace%:.."
+  [[ "$BAZEL_INTERACTIVE" == "1" ]] && BAZEL_BATCH="" || BAZEL_BATCH="--batch"
+  bazel $BAZEL_BATCH build $BAZEL_OPTIONS //source/...
+  echo "Testing..."
+  bazel $BAZEL_BATCH test $BAZEL_OPTIONS --test_output=all //test/...
+  exit 0
+fi
+
 . "$(dirname "$0")"/build_setup.sh
 
 if [[ "$1" == "fix_format" ]]; then

ci/prebuilt/BUILD

@@ -0,0 +1,24 @@
+package(default_visibility = ["//visibility:public"])
+
+cc_library(
+    name = "googletest_main",
+    srcs = [
+        "thirdparty_build/lib/libgmock.a",
+        "thirdparty_build/lib/libgtest.a",
+        "thirdparty_build/lib/libgtest_main.a",
+    ],
+    hdrs = glob([
+        "thirdparty_build/include/gmock/**/*.h",
+        "thirdparty_build/include/gtest/**/*.h",
+    ]),
+    strip_include_prefix = "thirdparty_build/include",
+)
+
+cc_library(
+    name = "spdlog",
+    hdrs = glob([
+        "thirdparty/spdlog-0.11.0/include/**/*.h",
+        "thirdparty/spdlog-0.11.0/include/**/*.cc",
+    ]),
+    strip_include_prefix = "thirdparty/spdlog-0.11.0/include",
+)

include/envoy/common/BUILD

@@ -0,0 +1,22 @@
+package(default_visibility = ["//visibility:public"])
+
+load("//bazel:envoy_build_system.bzl", "envoy_cc_library")
+
+envoy_cc_library(
+    name = "base_includes",
+    hdrs = [
+        "exception.h",
+        "pure.h",
+    ],
+)
+
+envoy_cc_library(
+    name = "time_includes",
+    hdrs = ["time.h"],
+    deps = [":base_includes"],
+)
+
+envoy_cc_library(
+    name = "optional_includes",
+    hdrs = ["optional.h"],
+)

source/common/common/BUILD

@@ -0,0 +1,12 @@
+package(default_visibility = ["//visibility:public"])
+
+load("//bazel:envoy_build_system.bzl", "envoy_cc_library")
+
+envoy_cc_library(
+    name = "utility_lib",
+    srcs = ["utility.cc"],
+    hdrs = ["utility.h"],
+    deps = [
+        "//include/envoy/common:time_includes",
+    ],
+)

source/precompiled/BUILD

@@ -0,0 +1,9 @@
+package(default_visibility = ["//visibility:public"])
+
+load("//bazel:envoy_build_system.bzl", "envoy_external_dep_path")
+
+cc_library(
+    name = "precompiled_includes",
+    hdrs = ["precompiled.h"],
+    deps = [envoy_external_dep_path("spdlog")],
+)

test/common/common/BUILD

@@ -0,0 +1,7 @@
+load("//bazel:envoy_build_system.bzl", "envoy_cc_test")
+
+envoy_cc_test(
+    name = "utility_test",
+    srcs = ["utility_test.cc"],
+    deps = ["//source/common/common:utility_lib"],
+)

test/precompiled/BUILD

@@ -0,0 +1,9 @@
+package(default_visibility = ["//visibility:public"])
+
+load("//bazel:envoy_build_system.bzl", "envoy_external_dep_path")
+
+cc_library(
+    name = "precompiled_includes",
+    hdrs = ["precompiled_test.h"],
+    deps = [envoy_external_dep_path("googletest_main")],
+)

test/precompiled/precompiled_test.h

@@ -2,7 +2,5 @@
 
 #include "precompiled/precompiled.h"
 
-#include "test/test_common/printers.h"
-
 #include "gmock/gmock.h"
 #include "gtest/gtest.h"