PathParams middleware

README.md

@@ -110,6 +110,7 @@ This is very similar to how [Plug Router](https://github.com/elixir-plug/plug#th
 - [`Tesla.Middleware.MethodOverride`](https://hexdocs.pm/tesla/Tesla.Middleware.MethodOverride.html) - set X-Http-Method-Override
 - [`Tesla.Middleware.Logger`](https://hexdocs.pm/tesla/Tesla.Middleware.Logger.html) - log requests (method, url, status, time)
 - [`Tesla.Middleware.KeepRequest`](https://hexdocs.pm/tesla/Tesla.Middleware.KeepRequest.html) - keep request body & headers
+- [`Tesla.Middleware.PathParams`](https://hexdocs.pm/tesla/Tesla.Middleware.PathParams.html) - use templated URLs
 
 #### Formats
 - [`Tesla.Middleware.FormUrlencoded`](https://hexdocs.pm/tesla/Tesla.Middleware.FormUrlencoded.html) - urlencode POST body parameter, useful for POSTing a map/keyword list

lib/tesla/adapter/hackney.ex

@@ -95,14 +95,15 @@ if Code.ensure_loaded?(:hackney) do
     defp handle({:ok, status, headers, body}), do: {:ok, status, headers, body}
 
     defp handle_async_response({ref, %{headers: headers, status: status}})
-    when not (is_nil(headers) or is_nil(status)) do
+         when not (is_nil(headers) or is_nil(status)) do
       {:ok, status, headers, ref}
     end
 
     defp handle_async_response({ref, output}) do
       receive do
         {:hackney_response, ^ref, {:status, status, _}} ->
-           handle_async_response({ref, %{output | status: status}})
+          handle_async_response({ref, %{output | status: status}})
+
         {:hackney_response, ^ref, {:headers, headers}} ->
           handle_async_response({ref, %{output | headers: headers}})
       end

lib/tesla/middleware/path_params.ex

@@ -0,0 +1,43 @@
+defmodule Tesla.Middleware.PathParams do
+  @behaviour Tesla.Middleware
+
+  @moduledoc """
+  Use templated URLs with separate params.
+
+  Useful when logging or reporting metric per URL.
+
+
+  ### Example usage
+  ```
+  defmodule MyClient do
+    use Tesla
+
+    plug Tesla.Middleware.BaseURl, "https://api.example.com"
+    plug Tesla.Middleware.Logger # or some monitoring middleware
+    plug Tesla.Middleware.PathParams
+
+    def user(id) do
+      params = [id: id]
+      get("/users/:id", opts: [path_params: params])
+    end
+  end
+  ```
+  """
+
+  @rx ~r/:([\w_]+)/
+
+  @doc false
+  @impl true
+  def call(env, next, _) do
+    url = build_url(env.url, env.opts[:path_params])
+    Tesla.run(%{env | url: url}, next)
+  end
+
+  defp build_url(url, nil), do: url
+
+  defp build_url(url, params) do
+    Regex.replace(@rx, url, fn match, key ->
+      to_string(params[String.to_existing_atom(key)] || match)
+    end)
+  end
+end

test/tesla/middleware/path_params_test.exs

@@ -0,0 +1,37 @@
+defmodule Tesla.Middleware.PathParamsTest do
+  use ExUnit.Case, async: true
+  alias Tesla.Env
+
+  @middleware Tesla.Middleware.PathParams
+
+  test "no params" do
+    assert {:ok, env} = @middleware.call(%Env{url: "/users/:id"}, [], nil)
+    assert env.url == "/users/:id"
+  end
+
+  test "passed params" do
+    opts = [path_params: [id: 42]]
+    assert {:ok, env} = @middleware.call(%Env{url: "/users/:id", opts: opts}, [], nil)
+    assert env.url == "/users/42"
+  end
+
+  test "value is not given" do
+    opts = [path_params: [y: 42]]
+    assert {:ok, env} = @middleware.call(%Env{url: "/users/:x", opts: opts}, [], nil)
+    assert env.url == "/users/:x"
+  end
+
+  test "value is nil" do
+    opts = [path_params: [id: nil]]
+    assert {:ok, env} = @middleware.call(%Env{url: "/users/:id", opts: opts}, [], nil)
+    assert env.url == "/users/:id"
+  end
+
+  test "placeholder contains another placeholder" do
+    opts = [path_params: [id: 1, id_post: 2]]
+
+    assert {:ok, env} = @middleware.call(%Env{url: "/users/:id/p/:id_post", opts: opts}, [], nil)
+
+    assert env.url == "/users/1/p/2"
+  end
+end