Validate conditional fields

[ostcar]

I have a list of structs. Dependent on the value of one field the structs have different other fields.

For example here is a yml file with two persons. Minors need someone responsible:

---
person1:
  name: Bob
  age: 35

person2:
  name: Bill
  age: 12
  responsible: Anna

I am trying to validate this with this schema:

person1: #Person
person2: #Person

#Person: {
	name: string
	age: int

    if age < 18 {
        responsible: string
    }
}

But cue vet returns: person2: field "responsible" not allowed in closed struct.

It seems, that conditional fields only work with cue eval.

Is there a way to conditionally validate a struct?

[extemporalgenome]

You can open a definition struct using ..., such as:

#Person: {
  name: string
  age: int

  if age < 18 {
      responsible: string
  }
  ...
}

However, that means data or other types that refer to #Person are now open ended to accept any other fields, which is often not desired.

I'm fairly new to CUE, but I believe the conventional approach is:

#Person: {
  name: string
  age:  int & >=0
}

#Person: {
  age:         <18
  responsible: string
  aspirations: [string]
} | {
  age: >=18
  regrets: [string]
}

This evaluates to:

#Person: {
    name:        string
    age:         uint & <18
    responsible: string
    aspirations: [string]
} | {
    name: string
    age:  >=18 & int
    regrets: [string]
}

[ostcar]

Thank you a lot. That worked perfectly!

[myitcv]

Please can you give a bit more detail on what you tried originally (including CUE version)?

Because it does/should work:

cue vet schema.cue persons.yaml

-- persons.yaml --
person1:
  name: Bob
  age: 35

person2:
  name: Bill
  age: 12
  responsible: Anna
-- schema.cue --
package p

person1: #Person
person2: #Person

#Person: {
	name: string
	age:  int

	if age < 18 {
		responsible: string
	}
}

Run with CUE version ed8bdaf which might be relevant.

[extemporalgenome]

So what is the preferred style? I'd imagine if for this kind of conditionally required extra field, since that's more convenient?

[ostcar]

I am using the cue version from the archlinux repo: cue version 0.2.2 linux/amd64

I am calling cue vet persons.yaml schema.cue

The output is:

person2: field "responsible" not allowed in closed struct:
    ./persons.yaml:8:17

[myitcv]

Ah @ostcar thanks for confirming.

Whilst v0.2.2 is indeed the latest stable release, you are strongly encouraged to use the latest v0.3.0 pre-release:

https://github.com/cuelang/cue/releases/tag/v0.3.0-beta.3

A significant amount has changed since v0.2.2 and, whilst the v0.3.0 release has been a long time in coming, it lays the foundations for all future work in CUE (not to mention being an incredibly complex rewrite).

[myitcv]

(sorry, that sent too early)

We are entirely focussed on getting v0.3.0 out the door as soon as possibly incidentally. At which point hopefully far fewer people will accidentally use an "old" version.

Thanks for confirming details in any case.

[ostcar]

I can confirm this. After I installed cue from the sources (GO111MODULE=on go get -u cuelang.org/go/cmd/[email protected]), the example works fine.

[cueckoo]

This discussion has been migrated to cue-lang/cue#706.

For more details about CUE's migration to a new home, please see cue-lang/cue#1078.