Add EventLoop::FileDescriptor module

src/crystal/system/event_loop.cr

@@ -45,6 +45,14 @@ abstract class Crystal::EventLoop
   end
 end
 
+require "./event_loop/file_descriptor"
+
+abstract class Crystal::EventLoop
+  # The FileDescriptor interface is always needed, so we include it right in
+  # the main interface.
+  include FileDescriptor
+end
+
 {% if flag?(:wasi) %}
   require "./wasi/event_loop"
 {% elsif flag?(:unix) %}

src/crystal/system/event_loop/file_descriptor.cr

@@ -0,0 +1,16 @@
+abstract class Crystal::EventLoop
+  module FileDescriptor
+    # Reads at least one byte from the file descriptor into *slice* and continues
+    # fiber when the read is complete.
+    # Returns the number of bytes read.
+    abstract def read(file_descriptor : Crystal::System::FileDescriptor, slice : Bytes) : Int32
+
+    # Writes at least one byte from *slice* to the file descriptor and continues
+    # fiber when the write is complete.
+    # Returns the number of bytes written.
+    abstract def write(file_descriptor : Crystal::System::FileDescriptor, slice : Bytes) : Int32
+
+    # Closes the file descriptor resource.
+    abstract def close(file_descriptor : Crystal::System::FileDescriptor) : Nil
+  end
+end

src/crystal/system/file_descriptor.cr

@@ -14,9 +14,17 @@ module Crystal::System::FileDescriptor
   # cooked mode otherwise.
   # private def system_raw(enable : Bool, & : ->)
 
-  # private def system_read(slice : Bool) : Int32
+  private def system_read(slice : Bytes) : Int32
+    event_loop.read(self, slice)
+  end
 
-  # private def system_write(slice : Bool) : Int32
+  private def system_write(slice : Bytes) : Int32
+    event_loop.write(self, slice)
+  end
+
+  private def event_loop : Crystal::EventLoop::FileDescriptor
+    Crystal::EventLoop.current
+  end
 end
 
 {% if flag?(:wasi) %}

src/crystal/system/unix/event_loop_libevent.cr

@@ -75,4 +75,28 @@ class Crystal::LibEvent::EventLoop < Crystal::EventLoop
       end
     end
   end
+
+  def read(file_descriptor : Crystal::System::FileDescriptor, slice : Bytes) : Int32
+    file_descriptor.evented_read("Error reading file_descriptor") do
+      LibC.read(file_descriptor.fd, slice, slice.size).tap do |return_code|
+        if return_code == -1 && Errno.value == Errno::EBADF
+          raise IO::Error.new "File not open for reading", target: file_descriptor
+        end
+      end
+    end
+  end
+
+  def write(file_descriptor : Crystal::System::FileDescriptor, slice : Bytes) : Int32
+    file_descriptor.evented_write("Error writing file_descriptor") do
+      LibC.write(file_descriptor.fd, slice, slice.size).tap do |return_code|
+        if return_code == -1 && Errno.value == Errno::EBADF
+          raise IO::Error.new "File not open for writing", target: file_descriptor
+        end
+      end
+    end
+  end
+
+  def close(file_descriptor : Crystal::System::FileDescriptor) : Nil
+    file_descriptor.evented_close
+  end
 end

src/crystal/system/unix/file_descriptor.cr

@@ -17,26 +17,6 @@ module Crystal::System::FileDescriptor
   STDOUT_HANDLE = 1
   STDERR_HANDLE = 2
 
-  private def system_read(slice : Bytes) : Int32
-    evented_read("Error reading file") do
-      LibC.read(fd, slice, slice.size).tap do |return_code|
-        if return_code == -1 && Errno.value == Errno::EBADF
-          raise IO::Error.new "File not open for reading", target: self
-        end
-      end
-    end
-  end
-
-  private def system_write(slice : Bytes) : Int32
-    evented_write("Error writing file") do
-      LibC.write(fd, slice, slice.size).tap do |return_code|
-        if return_code == -1 && Errno.value == Errno::EBADF
-          raise IO::Error.new "File not open for writing", target: self
-        end
-      end
-    end
-  end
-
   private def system_blocking?
     flags = fcntl(LibC::F_GETFL)
     !flags.bits_set? LibC::O_NONBLOCK
@@ -131,14 +111,14 @@ module Crystal::System::FileDescriptor
     # Mark the handle open, since we had to have dup'd a live handle.
     @closed = false
 
-    evented_reopen
+    event_loop.close(self)
   end
 
   private def system_close
     # Perform libevent cleanup before LibC.close.
     # Using a file descriptor after it has been closed is never defined and can
     # always lead to undefined results. This is not specific to libevent.
-    evented_close
+    event_loop.close(self)
 
     file_descriptor_close
   end

src/crystal/system/wasi/event_loop.cr

@@ -35,6 +35,30 @@ class Crystal::Wasi::EventLoop < Crystal::EventLoop
   def create_fd_read_event(io : IO::Evented, edge_triggered : Bool = false) : Crystal::EventLoop::Event
     raise NotImplementedError.new("Crystal::Wasi::EventLoop.create_fd_read_event")
   end
+
+  def read(file_descriptor : Crystal::System::FileDescriptor, slice : Bytes) : Int32
+    file_descriptor.evented_read("Error reading file_descriptor") do
+      LibC.read(file_descriptor.fd, slice, slice.size).tap do |return_code|
+        if return_code == -1 && Errno.value == Errno::EBADF
+          raise IO::Error.new "File not open for reading", target: file_descriptor
+        end
+      end
+    end
+  end
+
+  def write(file_descriptor : Crystal::System::FileDescriptor, slice : Bytes) : Int32
+    file_descriptor.evented_write("Error writing file_descriptor") do
+      LibC.write(file_descriptor.fd, slice, slice.size).tap do |return_code|
+        if return_code == -1 && Errno.value == Errno::EBADF
+          raise IO::Error.new "File not open for writing", target: file_descriptor
+        end
+      end
+    end
+  end
+
+  def close(file_descriptor : Crystal::System::FileDescriptor) : Nil
+    file_descriptor.evented_close
+  end
 end
 
 struct Crystal::Wasi::Event

src/crystal/system/win32/event_loop_iocp.cr

@@ -148,6 +148,27 @@ class Crystal::Iocp::EventLoop < Crystal::EventLoop
   def create_timeout_event(fiber) : Crystal::EventLoop::Event
     Crystal::Iocp::Event.new(fiber, timeout: true)
   end
+
+  def read(file_descriptor : Crystal::System::FileDescriptor, slice : Bytes) : Int32
+    handle = file_descriptor.windows_handle
+    file_descriptor.overlapped_operation(handle, "ReadFile", file_descriptor.read_timeout) do |overlapped|
+      ret = LibC.ReadFile(handle, slice, slice.size, out byte_count, overlapped)
+      {ret, byte_count}
+    end.to_i32
+  end
+
+  def write(file_descriptor : Crystal::System::FileDescriptor, slice : Bytes) : Int32
+    handle = file_descriptor.windows_handle
+
+    file_descriptor.overlapped_operation(handle, "WriteFile", file_descriptor.write_timeout, writing: true) do |overlapped|
+      ret = LibC.WriteFile(handle, slice, slice.size, out byte_count, overlapped)
+      {ret, byte_count}
+    end.to_i32
+  end
+
+  def close(file_descriptor : Crystal::System::FileDescriptor) : Nil
+    LibC.CancelIoEx(file_descriptor.windows_handle, nil) unless file_descriptor.system_blocking?
+  end
 end
 
 class Crystal::Iocp::Event

src/crystal/system/win32/file_descriptor.cr

@@ -26,10 +26,7 @@ module Crystal::System::FileDescriptor
     elsif system_blocking?
       read_blocking(handle, slice)
     else
-      overlapped_operation(handle, "ReadFile", read_timeout) do |overlapped|
-        ret = LibC.ReadFile(handle, slice, slice.size, out byte_count, overlapped)
-        {ret, byte_count}
-      end.to_i32
+      event_loop.read(self, slice)
     end
   end
 
@@ -53,10 +50,7 @@ module Crystal::System::FileDescriptor
     if system_blocking?
       write_blocking(handle, slice).to_i32
     else
-      overlapped_operation(handle, "WriteFile", write_timeout, writing: true) do |overlapped|
-        ret = LibC.WriteFile(handle, slice, slice.size, out byte_count, overlapped)
-        {ret, byte_count}
-      end.to_i32
+      event_loop.write(self, slice)
     end
   end
 
@@ -75,7 +69,8 @@ module Crystal::System::FileDescriptor
     bytes_written
   end
 
-  private def system_blocking?
+  # :nodoc:
+  def system_blocking?
     @system_blocking
   end
 
@@ -167,7 +162,7 @@ module Crystal::System::FileDescriptor
   end
 
   private def system_close
-    LibC.CancelIoEx(windows_handle, nil) unless system_blocking?
+    event_loop.close(self)
 
     file_descriptor_close
   end