Add promotion codes (#641)

* Add promotion codes

* Update API spec and fix failing tests

* Add promotion_code to subscription create

* Add code and active to PromotionCode.list

* Sort attributes

* :id is not a possible creation parameter

.travis.yml

@@ -17,7 +17,7 @@ matrix:
 sudo: false
 env:
   global:
-    - STRIPE_MOCK_VERSION=0.90.0
+    - STRIPE_MOCK_VERSION=0.95.0
     - MIX_ENV=test STRIPE_SECRET_KEY=non_empty_secret_key_string
 cache:
   directories:

lib/stripe/connect/account_link.ex

@@ -34,8 +34,8 @@ defmodule Stripe.AccountLink do
   @spec create(params, Stripe.options()) :: {:ok, t} | {:error, Stripe.Error.t()}
         when params: %{
                :account => Stripe.Account.t() | Stripe.id(),
-               :failure_url => String.t(),
-               :success_url => String.t(),
+               :refresh_url => String.t(),
+               :return_url => String.t(),
                :type => String.t(),
                optional(:collect) => String.t()
              }

lib/stripe/converter.ex

@@ -56,6 +56,7 @@ defmodule Stripe.Converter do
     plan
     price
     product
+    promotion_code
     recipient
     refund
     review

lib/stripe/subscriptions/promotion_code.ex

@@ -0,0 +1,133 @@
+defmodule Stripe.PromotionCode do
+  @moduledoc """
+  Work with Stripe promotion code objects.
+
+  You can:
+
+  - Create a promotion code
+  - Retrieve a promotion code
+  - Update a promotion code
+  - list all promotion codes
+
+  Stripe API reference: https://stripe.com/docs/api/promotion_codes
+  """
+
+  use Stripe.Entity
+  import Stripe.Request
+
+  @type t :: %__MODULE__{
+          id: Stripe.id(),
+          object: String.t(),
+          active: boolean,
+          code: String.t() | nil,
+          coupon: Stripe.Coupon.t(),
+          created: Stripe.timestamp(),
+          deleted: boolean | nil,
+          livemode: boolean,
+          max_redemptions: pos_integer | nil,
+          metadata: Stripe.Types.metadata(),
+          restrictions: restrictions(),
+          times_redeemed: non_neg_integer,
+          valid: boolean
+        }
+
+  @type restrictions :: %{
+          optional(:first_time_transaction) => boolean,
+          optional(:minimum_amount) => pos_integer,
+          optional(:minimum_amount_currency) => String.t()
+        }
+
+  defstruct [
+    :id,
+    :object,
+    :active,
+    :code,
+    :coupon,
+    :created,
+    :deleted,
+    :livemode,
+    :max_redemptions,
+    :metadata,
+    :restrictions,
+    :times_redeemed,
+    :valid
+  ]
+
+  @plural_endpoint "promotion_codes"
+
+  @doc """
+  Create a promotion code.
+  """
+  @spec create(params, Stripe.options()) :: {:ok, t} | {:error, Stripe.Error.t()}
+        when params: %{
+               :coupon => Stripe.id(),
+               optional(:code) => String.t(),
+               optional(:active) => boolean,
+               optional(:customer) => Stripe.id(),
+               optional(:max_redemptions) => pos_integer,
+               optional(:metadata) => Stripe.Types.metadata(),
+               optional(:restrictions) => restrictions()
+             }
+  def create(params, opts \\ []) do
+    new_request(opts)
+    |> put_endpoint(@plural_endpoint)
+    |> put_params(params)
+    |> put_method(:post)
+    |> make_request()
+  end
+
+  @doc """
+  Retrieve a promotion code.
+  """
+  @spec retrieve(Stripe.id() | t, Stripe.options()) :: {:ok, t} | {:error, Stripe.Error.t()}
+  def retrieve(id, opts \\ []) do
+    new_request(opts)
+    |> put_endpoint(@plural_endpoint <> "/#{get_id!(id)}")
+    |> put_method(:get)
+    |> make_request()
+  end
+
+  @doc """
+  Updates the metadata of a promotion code. Other promotion code details (coupon, customer,
+  expires_at, max_redemptions, restrictions) are, by design, not editable.
+
+  Takes the `id` and a map of changes.
+  """
+  @spec update(Stripe.id() | t, params, Stripe.options()) :: {:ok, t} | {:error, Stripe.Error.t()}
+        when params:
+               %{
+                 optional(:metadata) => Stripe.Types.metadata(),
+                 optional(:active) => boolean
+               }
+               | %{}
+  def update(id, params, opts \\ []) do
+    new_request(opts)
+    |> put_endpoint(@plural_endpoint <> "/#{get_id!(id)}")
+    |> put_method(:post)
+    |> put_params(params)
+    |> make_request()
+  end
+
+  @doc """
+  List all promotion codes.
+  """
+  @spec list(params, Stripe.options()) :: {:ok, Stripe.List.t(t)} | {:error, Stripe.Error.t()}
+        when params: %{
+               optional(:active) => boolean,
+               optional(:created) => Stripe.date_query(),
+               optional(:code) => String.t(),
+               optional(:coupon) => Stripe.id(),
+               optional(:customer) => Stripe.id(),
+               optional(:ending_before) => t | Stripe.id(),
+               optional(:limit) => 1..100,
+               optional(:starting_after) => t | Stripe.id()
+             }
+  def list(params \\ %{}, opts \\ []) do
+    new_request(opts)
+    |> put_endpoint(@plural_endpoint)
+    |> put_method(:get)
+    |> put_params(params)
+    |> cast_to_id([:ending_before, :starting_after])
+    |> make_request()
+  end
+end

lib/stripe/subscriptions/subscription.ex

@@ -149,6 +149,7 @@ defmodule Stripe.Subscription do
                optional(:metadata) => Stripe.Types.metadata(),
                optional(:prorate) => boolean,
                optional(:proration_behavior) => String.t(),
+               optional(:promotion_code) => Stripe.id(),
                optional(:tax_percent) => float,
                optional(:trial_end) => Stripe.timestamp(),
                optional(:trial_from_plan) => boolean,

test/stripe/connect/account_link_test.exs

@@ -4,9 +4,9 @@ defmodule Stripe.AccountLinkTest do
   test "is creatable" do
     params = %{
       account: "acct_123",
-      failure_url: "https://stripe.com",
-      success_url: "https://stripe.com",
-      type: "custom_account_verification"
+      refresh_url: "https://stripe.com",
+      return_url: "https://stripe.com",
+      type: "account_onboarding"
     }
 
     assert {:ok, %Stripe.AccountLink{}} = Stripe.AccountLink.create(params)

test/stripe/subscriptions/promotion_code_test.exs

@@ -0,0 +1,28 @@
+defmodule Stripe.PromotionCodeTest do
+  use Stripe.StripeCase, async: true
+
+  test "is listable" do
+    assert {:ok, %Stripe.List{data: promotion_codes}} = Stripe.PromotionCode.list()
+    assert_stripe_requested(:get, "/v1/promotion_codes")
+    assert is_list(promotion_codes)
+    assert %Stripe.PromotionCode{} = hd(promotion_codes)
+  end
+
+  test "is retrievable" do
+    assert {:ok, %Stripe.PromotionCode{}} = Stripe.PromotionCode.retrieve("FALL20")
+    assert_stripe_requested(:get, "/v1/promotion_codes/FALL20")
+  end
+
+  test "is creatable" do
+    params = %{code: "FALL21", max_redemptions: 2, coupon: "25OFF"}
+    assert {:ok, %Stripe.PromotionCode{}} = Stripe.PromotionCode.create(params)
+    assert_stripe_requested(:post, "/v1/promotion_codes")
+  end
+
+  test "is updateable" do
+    assert {:ok, %Stripe.PromotionCode{}} =
+             Stripe.PromotionCode.update("FALL20", %{active: false, metadata: %{key: "value"}})
+
+    assert_stripe_requested(:post, "/v1/promotion_codes/FALL20")
+  end
+end

test/stripe/subscriptions/subscription_item_test.exs

@@ -12,7 +12,7 @@ defmodule Stripe.SubscriptionItemTest do
     test "creates a subscription" do
       params = %{
         subscription: "sub_123",
-        plan: "plan_123"
+        price: "price_123"
       }
 
       assert {:ok, %Stripe.SubscriptionItem{}} = Stripe.SubscriptionItem.create(params)