Merge pull request #668 from artichoke/dev/lopopolo-dns-zone-project

Migrate route53 zone setup to a project

terraform/projects/github-actions-oidc-provider/modules/global/variables.tf

@@ -1,10 +1,10 @@
 variable "phase" {
-  description = "Provisioning phase, either `per-host`, `per-cluster` or `global`"
+  description = "Provisioning phase, either `per-host`, `per-cluster`, `per-domain`, or `global`"
   type        = string
 
   validation {
-    condition     = var.phase == "per-host" || var.phase == "per-cluster" || var.phase == "global"
-    error_message = "The phase variable must be either 'per-host', 'per-cluster', or 'global'."
+    condition     = var.phase == "per-host" || var.phase == "per-cluster" || var.phase == "per-domain" || var.phase == "global"
+    error_message = "The phase variable must be either 'per-host', 'per-cluster', 'per-domain', or 'global'."
   }
 }
 

terraform/projects/github-actions-terraform-linting/modules/global/variables.tf

@@ -1,10 +1,10 @@
 variable "phase" {
-  description = "Provisioning phase, either `per-host`, `per-cluster` or `global`"
+  description = "Provisioning phase, either `per-host`, `per-cluster`, `per-domain`, or `global`"
   type        = string
 
   validation {
-    condition     = var.phase == "per-host" || var.phase == "per-cluster" || var.phase == "global"
-    error_message = "The phase variable must be either 'per-host', 'per-cluster', or 'global'."
+    condition     = var.phase == "per-host" || var.phase == "per-cluster" || var.phase == "per-domain" || var.phase == "global"
+    error_message = "The phase variable must be either 'per-host', 'per-cluster', 'per-domain', or 'global'."
   }
 }
 

terraform/projects/remote-state/modules/global/variables.tf

@@ -1,10 +1,10 @@
 variable "phase" {
-  description = "Provisioning phase, either `per-host`, `per-cluster` or `global`"
+  description = "Provisioning phase, either `per-host`, `per-cluster`, `per-domain`, or `global`"
   type        = string
 
   validation {
-    condition     = var.phase == "per-host" || var.phase == "per-cluster" || var.phase == "global"
-    error_message = "The phase variable must be either 'per-host', 'per-cluster', or 'global'."
+    condition     = var.phase == "per-host" || var.phase == "per-cluster" || var.phase == "per-domain" || var.phase == "global"
+    error_message = "The phase variable must be either 'per-host', 'per-cluster', 'per-domain', or 'global'."
   }
 }
 

terraform/projects/route53-dns/aws.tf

@@ -0,0 +1,22 @@
+provider "aws" {
+  region = var.region
+
+  default_tags {
+    tags = {
+      managed_by = "terraform"
+      plan       = var.plan
+    }
+  }
+}
+
+provider "aws" {
+  alias  = "us_east_1"
+  region = "us-east-1"
+
+  default_tags {
+    tags = {
+      managed_by = "terraform"
+      plan       = var.plan
+    }
+  }
+}

terraform/projects/route53-dns/domain-data.tf

@@ -0,0 +1,3 @@
+module "domain_data" {
+  source = "../../modules/domain-data"
+}

terraform/projects/route53-dns/domains.tf

@@ -0,0 +1,9 @@
+module "route53_dns_domain" {
+  for_each = toset(module.domain_data.domains)
+  source   = "./modules/per-domain"
+
+  plan        = var.plan
+  region      = var.region
+  phase       = "per-domain"
+  domain_name = each.value
+}

terraform/projects/route53-dns/main.tf

@@ -0,0 +1,9 @@
+terraform {
+  backend "s3" {
+    bucket         = "artichoke-forge-project-infrastructure-terraform-state"
+    region         = "us-west-2"
+    key            = "route53-dns/terraform.tfstate"
+    encrypt        = true
+    dynamodb_table = "terraform_statelock"
+  }
+}

terraform/projects/route53-dns/modules/per-domain/domain-data.tf

@@ -0,0 +1,3 @@
+module "domain_data" {
+  source = "../../../../modules/domain-data"
+}

terraform/projects/route53-dns/modules/per-domain/main.tf

@@ -0,0 +1,7 @@
+resource "aws_route53_zone" "zone" {
+  name = var.domain_name
+
+  lifecycle {
+    prevent_destroy = true
+  }
+}

terraform/projects/route53-dns/modules/per-domain/outputs.tf

@@ -0,0 +1,15 @@
+output "zone_name" {
+  value = aws_route53_zone.zone.name
+}
+
+output "zone_id" {
+  value = aws_route53_zone.zone.zone_id
+}
+
+output "zone_arn" {
+  value = aws_route53_zone.zone.arn
+}
+
+output "zone_name_servers" {
+  value = [for ns in aws_route53_zone.zone.name_servers : ns]
+}

terraform/projects/route53-dns/modules/per-domain/variables.tf

@@ -0,0 +1,34 @@
+variable "domain_name" {
+  description = "Domain name"
+  type        = string
+}
+
+variable "phase" {
+  description = "Provisioning phase, either `per-host`, `per-cluster`, `per-domain`, or `global`"
+  type        = string
+
+  validation {
+    condition     = var.phase == "per-host" || var.phase == "per-cluster" || var.phase == "per-domain" || var.phase == "global"
+    error_message = "The phase variable must be either 'per-host', 'per-cluster', 'per-domain', or 'global'."
+  }
+}
+
+variable "plan" {
+  description = "Plan name"
+  type        = string
+
+  validation {
+    condition     = length(var.plan) >= 3 && !can(regex("artichoke", var.plan))
+    error_message = "The plan variable must be at least 3 characters long and must not contain the string 'artichoke'."
+  }
+}
+
+variable "region" {
+  description = "AWS region"
+  type        = string
+
+  validation {
+    condition     = contains(["us-west-2", "us-west-1", "us-east-1", "us-east-2"], var.region)
+    error_message = "The region must be one of the following: us-west-2 (Oregon), us-west-1 (California), us-east-1, or us-east-2."
+  }
+}

terraform/projects/route53-dns/outputs.tf

@@ -0,0 +1,7 @@
+output "route53_dns_domains" {
+  description = "Route53 zone information for each domain"
+  value = {
+    for domain_name in module.domain_data.domains :
+    domain_name => module.route53_dns_domain[domain_name]
+  }
+}

terraform/projects/route53-dns/variables.tf

@@ -0,0 +1,11 @@
+variable "plan" {
+  description = "Plan name"
+  default     = "route53-dns"
+  type        = string
+}
+
+variable "region" {
+  description = "AWS region"
+  default     = "us-west-2"
+  type        = string
+}

terraform/projects/route53-dns/versions.tf

@@ -0,0 +1,10 @@
+terraform {
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = "~> 5.10"
+    }
+  }
+
+  required_version = "~> 1.0"
+}