General - Change CBA Namespaces to HashMap

addons/advanced_throwing/XEH_postInit.sqf

@@ -10,16 +10,6 @@ if (!hasInterface) exitWith {};
 // Temporary Wind Info indication
 GVAR(tempWindInfo) = false;
 
-// Ammo/Magazines look-up hash for correctness of initSpeed
-GVAR(ammoMagLookup) = call CBA_fnc_createNamespace;
-{
-    {
-        private _ammo = getText (configFile >> "CfgMagazines" >> _x >> "ammo");
-        if (_ammo != "") then { GVAR(ammoMagLookup) setVariable [_ammo, _x]; };
-    } forEach (getArray (configFile >> "CfgWeapons" >> "Throw" >> _x >> "magazines"));
-} forEach getArray (configFile >> "CfgWeapons" >> "Throw" >> "muzzles");
-
-
 // Add keybinds
 ["ACE3 Weapons", QGVAR(prepare), localize LSTRING(Prepare), {
     // Condition

addons/advanced_throwing/XEH_preStart.sqf

@@ -1,3 +1,21 @@
 #include "script_component.hpp"
 
 #include "XEH_PREP.hpp"
+
+// Ammo/Magazines look-up hash for correctness of initSpeed
+private _cfgMagazines = configFile >> "CfgMagazines";
+private _cfgAmmo = configFile >> "CfgAmmo";
+private _cfgThrow = configFile >> "CfgWeapons" >> "Throw";
+
+private _ammoMagLookup = createHashMap;
+
+{
+    {
+        private _ammo = getText (_cfgMagazines >> _x >> "ammo");
+        if (_ammo != "") then {
+            _ammoMagLookup set [configName (_cfgAmmo >> _ammo), _x];
+        };
+    } forEach (getArray (_cfgThrow >> _x >> "magazines"));
+} forEach (getArray (_cfgThrow >> "muzzles"));
+
+uiNamespace setVariable [QGVAR(ammoMagLookup), compileFinal _ammoMagLookup];

addons/advanced_throwing/functions/fnc_drawThrowable.sqf

@@ -43,13 +43,10 @@ if ((!_primed) && {!((_throwableMag in (uniformItems ACE_player)) || {_throwable
 
 // Get correct throw power for primed grenade
 if (_primed) then {
-    private _ammoType = typeOf _activeThrowable;
-    _throwableMag = GVAR(ammoMagLookup) getVariable _ammoType;
-    if (isNil "_throwableMag") then {
-        // What we're trying to throw must not be a normal throwable because it is not in our lookup hash (e.g. 40mm smoke)
-        // Just use HandGrenade as it has an average initSpeed value
-        _throwableMag = "HandGrenade";
-    };
+    // If ammo type is not found:
+    // What we're trying to throw must not be a normal throwable because it is not in our lookup hash (e.g. 40mm smoke)
+    // Just use HandGrenade as it has an average initSpeed value
+    _throwableMag = (uiNamespace getVariable QGVAR(ammoMagLookup)) getOrDefault [typeOf _activeThrowable, "HandGrenade"];
 };
 
 // Some throwables have different classname for magazine and ammo

addons/captives/XEH_postInit.sqf

@@ -24,7 +24,7 @@ if (isServer) then {
     }];
 };
 
-["unit", FUNC(handlePlayerChanged)] call CBA_fnc_addPlayerEventHandler;
+["unit", LINKFUNC(handlePlayerChanged)] call CBA_fnc_addPlayerEventHandler;
 [QGVAR(moveInCaptive), LINKFUNC(vehicleCaptiveMoveIn)] call CBA_fnc_addEventHandler;
 [QGVAR(moveOutCaptive), LINKFUNC(vehicleCaptiveMoveOut)] call CBA_fnc_addEventHandler;
 

addons/common/XEH_postInit.sqf

@@ -145,7 +145,7 @@ if (isServer) then {
                     INFO_3("[%1] DC - Was Zeus [%2] while controlling unit [%3] - manually clearing `bis_fnc_moduleRemoteControl_owner`",[_x] call FUNC(getName),_dcPlayer,_x);
                     _x setVariable ["bis_fnc_moduleRemoteControl_owner", nil, true];
                 };
-            } forEach (curatorEditableObjects  _zeusLogic);
+            } forEach (curatorEditableObjects _zeusLogic);
         };
     }];
 };

addons/common/functions/fnc_actionKeysNamesConverted.sqf

@@ -43,18 +43,18 @@ if (isNil "_keyTable") then {
     };
 };
 
-private _keyCache = uiNamespace getVariable [QGVAR(keyNameCache), locationNull];
+private _keyCache = uiNamespace getVariable QGVAR(keyNameCache);
 
-if (isNull _keyCache) then {
-    _keyCache = call CBA_fnc_createNamespace;
+if (isNil "_keyCache") then {
+    _keyCache = createHashMap;
     uiNamespace setVariable [QGVAR(keyNameCache), _keyCache];
 };
 
 params [["_action", "", [""]]];
 
 private _keybinds = actionKeysNamesArray _action apply {
     private _keyName = _x;
-    private _keybind = _keyCache getVariable _keyName;
+    private _keybind = _keyCache get _keyName;
 
     if (isNil "_keybind") then {
         private _key = -1;
@@ -101,7 +101,7 @@ private _keybinds = actionKeysNamesArray _action apply {
 
         // cache
         _keybind = [_key, _shift, _ctrl, _alt];
-        _keyCache setVariable [_keyName, _keybind];
+        _keyCache set [_keyName, _keybind];
     };
 
     _keybind

addons/common/functions/fnc_getSettingData.sqf

@@ -32,7 +32,6 @@ scopeName "main";
     if (_x select 0 == _name) then {
         _x breakOut "main";
     };
-    false
-} count GVAR(settings);
+} forEach GVAR(settings);
 
 []

addons/common/functions/fnc_registerItemReplacement.sqf

@@ -20,15 +20,23 @@
 params [["_oldItem", "", [0,""]], ["_newItems", "", ["", []]], ["_replaceInherited", false, [false]]];
 TRACE_3("registerItemReplacement",_oldItem,_newItems,_replaceInherited);
 
-
 // Setup on first run
 if (isNil QGVAR(itemReplacements)) then {
-    GVAR(itemReplacements) = [] call CBA_fnc_createNamespace;
+    GVAR(itemReplacements) = createHashMap;
     GVAR(inheritedReplacements) = [];
     GVAR(oldItems) = [];
     ["loadout", LINKFUNC(replaceRegisteredItems)] call CBA_fnc_addPlayerEventHandler;
 };
 
+// Get config case
+if (_oldItem isEqualType "") then {
+    private _configCase = _oldItem call FUNC(getConfigName);
+
+    if (_configCase != "") then {
+        _oldItem = _configCase;
+    };
+};
+
 // Save item replacement
 // $ prefix is used for types (numbers) and replacements with inheritance
 if (_replaceInherited) then {
@@ -42,9 +50,8 @@ if (_newItems isEqualType "") then {
     _newItems = [_newItems];
 };
 
-private _oldReplacements = GVAR(itemReplacements) getVariable [_oldItem, []];
+private _oldReplacements = GVAR(itemReplacements) getOrDefault [_oldItem, [], true];
 _oldReplacements append _newItems;
-GVAR(itemReplacements) setVariable [_oldItem, _oldReplacements];
 
 // Force item scan when new replacement was registered in PostInit
 if !(isNull ACE_player) then {

addons/common/functions/fnc_replaceRegisteredItems.sqf

@@ -42,15 +42,15 @@ for "_i" from 0 to count _newItems - 1 do {
     private _replacements = [];
 
     // Determine replacement items: direct replacements, ...
-    private _directReplacements = GVAR(itemReplacements) getVariable _item;
+    private _directReplacements = GVAR(itemReplacements) get _item;
     if (!isNil "_directReplacements") then {
         _doReplace = true;
         _replacements append _directReplacements;
     };
 
     // ... item type replacements ...
     private _type = getNumber (_cfgWeapons >> _item >> "ItemInfo" >> "type");
-    private _typeReplacements = GVAR(itemReplacements) getVariable ("$" + str _type);
+    private _typeReplacements = GVAR(itemReplacements) get ("$" + str _type);
     if (!isNil "_typeReplacements") then {
         _doReplace = true;
         _replacements append _typeReplacements;
@@ -59,7 +59,7 @@ for "_i" from 0 to count _newItems - 1 do {
     // ... and inherited replacements
     {
         if (_item isKindOf [_x, _cfgWeapons]) then {
-            private _inheritedReplacements = GVAR(itemReplacements) getVariable _x;
+            private _inheritedReplacements = GVAR(itemReplacements) get _x;
             if (!isNil "_inheritedReplacements") then {
                 _doReplace = true;
                 _replacements append _inheritedReplacements;

addons/dagr/XEH_postInit.sqf

@@ -30,4 +30,4 @@ GVAR(vectorConnected) = false;
 GVAR(noVectorData) = true;
 GVAR(vectorGrid) = "00000000";
 
-[QEGVAR(vector,rangefinderData), FUNC(handleRangeFinderData)] call CBA_fnc_addEventHandler;
+[QEGVAR(vector,rangefinderData), LINKFUNC(handleRangeFinderData)] call CBA_fnc_addEventHandler;

addons/dogtags/XEH_preInit.sqf

@@ -6,6 +6,6 @@ PREP_RECOMPILE_START;
 #include "XEH_PREP.hpp"
 PREP_RECOMPILE_END;
 
-GVAR(disabledFactions) = [] call CBA_fnc_createNamespace;
+GVAR(disabledFactions) = createHashMap;
 
 ADDON = true;

addons/dogtags/functions/fnc_canCheckDogtag.sqf

@@ -21,6 +21,6 @@ params ["_player", "_target"];
 if (isNull _target) exitWith {false};
 
 // check if disabled for faction
-if ([GVAR(disabledFactions) getVariable faction _target] param [0, false]) exitWith {false};
+if (GVAR(disabledFactions) getOrDefault [toLowerANSI faction _target, false]) exitWith {false};
 
 (!alive _target) || {_target getVariable ["ACE_isUnconscious", false]}

addons/dogtags/functions/fnc_canTakeDogtag.sqf

@@ -21,6 +21,6 @@ params ["_player", "_target"];
 if (isNull _target) exitWith {false};
 
 // check if disabled for faction
-if ([GVAR(disabledFactions) getVariable faction _target] param [0, false]) exitWith {false};
+if (GVAR(disabledFactions) getOrDefault [toLowerANSI faction _target, false]) exitWith {false};
 
 (!alive _target) || {_target getVariable ["ACE_isUnconscious", false]}

addons/dogtags/functions/fnc_disableFactionDogtags.sqf

@@ -17,4 +17,4 @@
 
 params [["_faction", "", [""]]];
 
-GVAR(disabledFactions) setVariable [_faction, true];
+GVAR(disabledFactions) set [toLowerANSI _faction, true];

addons/explosives/functions/fnc_addClacker.sqf

@@ -31,7 +31,7 @@ private _detonators = [_unit] call FUNC(getDetonators);
     if !(_x in _detonators) exitWith{
         _hasRequired = false;
     };
-} count _requiredItems;
+} forEach _requiredItems;
 
 if !(_hasRequired) exitWith {};
 private _config = ConfigFile >> "CfgMagazines" >> _magazineClass >> "ACE_Triggers" >> configName _config;

addons/frag/XEH_postInit.sqf

@@ -18,7 +18,7 @@ if (isServer) then {
 }] call CBA_fnc_addEventHandler;
 
 // Cache for ammo type configs
-GVAR(cacheRoundsTypesToTrack) = [false] call CBA_fnc_createNamespace;
+GVAR(cacheRoundsTypesToTrack) = createHashMap;
 
 
 // Debug stuff:

addons/frag/functions/fnc_findReflections.sqf

@@ -120,7 +120,7 @@ if (_zIndex < 5) then {
     // _dirvec = _pos vectorFromTo ((player modelToWorldVisualWorld (player selectionPosition "Spine3")));
     // _dirvec = _dirvec vectorMultiply 100;
     // _can setVelocity _dirvec;
-    [DFUNC(doExplosions), 0, [_explosions, 0]] call CBA_fnc_addPerFrameHandler;
+    [LINKFUNC(doExplosions), 0, [_explosions, 0]] call CBA_fnc_addPerFrameHandler;
     [_pfhID] call CBA_fnc_removePerFrameHandler;
 };
 END_COUNTER(fnc_findReflections);

addons/frag/functions/fnc_fired.sqf

@@ -19,7 +19,7 @@
 //IGNORE_PRIVATE_WARNING ["_unit", "_weapon", "_muzzle", "_mode", "_ammo", "_magazine", "_projectile", "_vehicle", "_gunner", "_turret"];
 TRACE_10("firedEH:",_unit,_weapon,_muzzle,_mode,_ammo,_magazine,_projectile,_vehicle,_gunner,_turret);
 
-private _shouldAdd = GVAR(cacheRoundsTypesToTrack) getVariable _ammo;
+private _shouldAdd = GVAR(cacheRoundsTypesToTrack) get _ammo;
 if (isNil "_shouldAdd") then {
     TRACE_1("no cache for round",_ammo);
 
@@ -40,7 +40,7 @@ if (isNil "_shouldAdd") then {
     };
 
     TRACE_6("Setting Cache",_skip,_explosive,_indirectRange,_force,_fragPower,_shouldAdd);
-    GVAR(cacheRoundsTypesToTrack) setVariable [_ammo, _shouldAdd];
+    GVAR(cacheRoundsTypesToTrack) set [_ammo, _shouldAdd];
 };
 
 if (_shouldAdd) then {

addons/hearing/XEH_postInit.sqf

@@ -4,7 +4,7 @@ if (!hasInterface) exitWith {};
 
 #include "initKeybinds.inc.sqf"
 
-GVAR(cacheAmmoLoudness) = call CBA_fnc_createNamespace;
+GVAR(cacheAmmoLoudness) = createHashMap;
 
 GVAR(deafnessDV) = 0;
 GVAR(deafnessPrior) = 0;

addons/hearing/functions/fnc_firedNear.sqf

@@ -44,7 +44,7 @@ if (_silencer != "") then {
     _audibleFireCoef = getNumber (configFile >> "CfgWeapons" >> _silencer >> "ItemInfo" >> "AmmoCoef" >> "audibleFire");
 };
 
-private _loudness = GVAR(cacheAmmoLoudness) getVariable (format ["%1%2",_weapon,_ammo]);
+private _loudness = GVAR(cacheAmmoLoudness) get (format ["%1%2",_weapon,_ammo]);
 if (isNil "_loudness") then {
     private _muzzles = getArray (configFile >> "CfgWeapons" >> _weapon >> "muzzles");
     private _weaponMagazines = getArray (configFile >> "CfgWeapons" >> _weapon >> "magazines");
@@ -86,7 +86,7 @@ if (isNil "_loudness") then {
         _loudness = (_caliber ^ 1.25 / 10) * (_initspeed / 1000) / 5;
         TRACE_6("building cache",_weapon,_ammo,_magazine,_initSpeed,_caliber,_loudness);
     };
-    GVAR(cacheAmmoLoudness) setVariable [(format ["%1%2",_weapon,_ammo]), _loudness];
+    GVAR(cacheAmmoLoudness) set [(format ["%1%2",_weapon,_ammo]), _loudness];
 };
 
 _loudness = _loudness * _audibleFireCoef;

addons/map/XEH_postInitClient.sqf

@@ -8,7 +8,7 @@ LOG(MSG_INIT);
 // Calculate the maximum zoom allowed for this map
 call FUNC(determineZoom);
 
-GVAR(flashlights) = [] call CBA_fnc_createNamespace;
+GVAR(flashlights) = createHashMap;
 
 ["CBA_settingsInitialized", {
     if (isMultiplayer && {GVAR(DefaultChannel) != -1}) then {

addons/map/functions/fnc_isFlashlight.sqf

@@ -17,14 +17,12 @@
 
 params [["_class", "", [""]]];
 
-private _isFlashlight = GVAR(flashlights) getVariable _class;
-
-if (isNil "_isFlashlight") then {
+GVAR(flashlights) getOrDefaultCall [_class, {
     private _items = ([_class] + (_class call CBA_fnc_switchableAttachments));
     private _cfgWeapons = configFile >> "CfgWeapons";
 
     // if this item or any of the switchable items is a flashlight
-    _isFlashlight = _items findIf {
+    _items findIf {
         private _weaponConfig = _cfgWeapons >> _x;
 
         [
@@ -34,10 +32,5 @@ if (isNil "_isFlashlight") then {
             isText (_x >> "ACE_Flashlight_Colour")
             || {!(getArray (_x >> "ambient") in [[], [0,0,0]]) && {getNumber (_x >> "irLight") == 0}}
         } != -1 // return
-    } != -1;
-
-    // cache value
-    GVAR(flashlights) setVariable [_class, _isFlashlight];
-};
-
-_isFlashlight // return
+    } != -1 // return
+}, true] // return

addons/map_gestures/XEH_preInit.sqf

@@ -8,6 +8,6 @@ PREP_RECOMPILE_END;
 
 #include "initSettings.inc.sqf"
 
-GVAR(GroupColorCfgMappingNew) = call CBA_fnc_createNamespace;
+GVAR(GroupColorCfgMappingNew) = createHashMap;
 
 ADDON = true;

addons/map_gestures/functions/fnc_addGroupColorMapping.sqf

@@ -28,4 +28,4 @@ if (_group == "") exitWith {ERROR("Group ID is blank, which is not valid.")};
 if (!([_leadColor] call FUNC(isValidColorArray))) exitWith {ERROR("leadColor is not a valid color array.")};
 if (!([_unitColor] call FUNC(isValidColorArray))) exitWith {ERROR("color is not a valid color array.")};
 
-GVAR(GroupColorCfgMappingNew) setVariable [_group, [_leadColor, _unitColor]];
+GVAR(GroupColorCfgMappingNew) set [toLower _group, [_leadColor, _unitColor]];

addons/map_gestures/functions/fnc_drawMapGestures.sqf

@@ -41,7 +41,7 @@ private _players = [_positions, FUNC(getProximityPlayers), missionNamespace, QGV
         };
 
         // If color settings for the group exist, then use those, otherwise fall back to the default colors
-        private _colorMap = GVAR(GroupColorCfgMappingNew) getVariable [(groupID (group _x)), [GVAR(defaultLeadColor), GVAR(defaultColor)]];
+        private _colorMap = GVAR(GroupColorCfgMappingNew) getOrDefault [toLower groupID (group _x), [GVAR(defaultLeadColor), GVAR(defaultColor)]];
         private _color = _colorMap select (_x != leader _x);
 
         TRACE_2("",_colorMap,_color);

addons/medical_blood/XEH_preInit.sqf

@@ -8,22 +8,8 @@ PREP_RECOMPILE_END;
 
 #include "initSettings.inc.sqf"
 
-// Damage types which do not cause blood spurts
-GVAR(noBloodDamageTypes) = createHashMapFromArray (call (uiNamespace getVariable QGVAR(noBloodDamageTypes)));
-
 // blood object model namespace
-GVAR(models) = [] call CBA_fnc_createNamespace;
-
-{
-    _x params ["_name", "_model"];
-
-    // createSimpleObject expects a path without the leading slash
-    if ((_model select [0,1]) isEqualTo "\") then {
-        _model = _model select [1];
-    };
-
-    GVAR(models) setVariable [_name, _model];
-} forEach [
+GVAR(models) = createHashMapFromArray [
     // higher number means bigger model
     ["blooddrop_1", QPATHTOF(data\ace_drop_1.p3d)],
     ["blooddrop_2", QPATHTOF(data\ace_drop_2.p3d)],

addons/medical_blood/XEH_preStart.sqf

@@ -4,7 +4,4 @@
 
 // Damage types which do not cause blood spurts
 private _noBloodDamageTypes = "getNumber (_x >> 'noBlood') == 1" configClasses (configFile >> "ACE_Medical_Injuries" >> "damageTypes");
-uiNamespace setVariable [
-    QGVAR(noBloodDamageTypes),
-    compileFinal str (_noBloodDamageTypes apply {[configName _x, nil]})
-];
+uiNamespace setVariable [QGVAR(noBloodDamageTypes), compileFinal (_noBloodDamageTypes createHashMapFromArray [])];

addons/medical_blood/functions/fnc_createBlood.sqf

@@ -21,7 +21,7 @@
 params ["_type", "_position", "_source"];
 TRACE_3("Creating blood",_type,_position,_source);
 
-private _model = GVAR(models) getVariable _type;
+private _model = GVAR(models) get _type;
 
 private _bloodDrop = createSimpleObject [_model, [0, 0, 0]];
 _bloodDrop setDir random 360;