Add ACE Arsenal stats

addons/arsenal/ACE_Arsenal_Stats.hpp

@@ -0,0 +1,96 @@
+class GVAR(stats) {
+    class statBase {
+        scope = 1;
+        priority = 0;
+        stats[] = {};
+        displayName = "";
+        showBar = 0;
+        showText = 0;
+        barStatement = "";
+        textStatement = "";
+        condition = "true";
+        tabs[] = {{}, {}};
+    };
+    class ACE_bananaPotassium: statBase {
+        scope = 2;
+        displayName= CSTRING(statPotassium);
+        showBar = 1;
+        barStatement = "1";
+        condition = QUOTE((configName (_this select 1)) == 'ACE_Banana');
+        tabs[] = {{}, {7}};
+    };
+    class ACE_mass: statBase {
+        scope = 2;
+        displayName= "$STR_a3_rscdisplayarsenal_stat_weight";
+        showText = 1;
+        textStatement = QUOTE([ARR_2(_this select 0, _this select 1)] call FUNC(statTextStatement_mass));
+        tabs[] = {{0,1,2,3,4,5,6,7,8,9,10,11,12,13,14}, {0,1,2,3,4,5,6,7}};
+    };
+    class ACE_rateOfFire: statBase {
+        scope = 2;
+        priority = 5;
+        stats[] = {"reloadTime"};
+        displayName= "$STR_a3_rscdisplayarsenal_stat_rof";
+        showBar = 1;
+        showText = 1;
+        barStatement = QUOTE([ARR_3((_this select 0) select 0, _this select 1, [ARR_3([ARR_2(-1.4, 0.31)], [ARR_2(1, 0.01)], true)])] call FUNC(statBarStatement_default));
+        textStatement = QUOTE([ARR_3((_this select 0) select 0, _this select 1, [ARR_2([ARR_2(-1.4, 0.31)], false)])] call FUNC(statTextStatement_rateOfFire));
+        tabs[] = {{0,1}, {}};
+    };
+    class ACE_accuracy: statBase {
+        scope = 2;
+        priority = 4;
+        stats[] = {"dispersion"};
+        displayName = "$STR_a3_rscdisplayarsenal_stat_dispersion";
+        showBar = 1;
+        showText = 1;
+        barStatement = QUOTE([ARR_3((_this select 0) select 0, _this select 1, [ARR_3([ARR_2(-4, -1.7)], [ARR_2(1, 0.01)], true)])] call FUNC(statBarStatement_default));
+        textStatement = QUOTE([ARR_3((_this select 0) select 0, _this select 1, [ARR_2([ARR_2(-4, -1.7)], false)])] call FUNC(statTextStatement_accuracy));
+        tabs[] = {{0,1}, {}};
+    };
+    class ACE_maxZeroing: statBase {
+        scope = 2;
+        priority = 3;
+        stats[] = {"maxZeroing"};
+        displayName = "$STR_a3_rscdisplayarsenal_stat_range";
+        showBar = 1;
+        barStatement = QUOTE([ARR_3((_this select 0) select 0, _this select 1, [ARR_3([ARR_2(0, 2500)], [ARR_2(0.01, 1)], false)])] call FUNC(statBarStatement_default));
+        tabs[] = {{0,1,2}, {}};
+    };
+    class ACE_impact: statBase {
+        scope = 2;
+        priority = 2;
+        stats[] = {"hit", "initSpeed"};
+        displayName = "$STR_a3_rscdisplayarsenal_stat_impact";
+        showBar = 1;
+        barStatement = QUOTE([ARR_3(_this select 0, _this select 1, [ARR_3([ARR_2(0, 3.2)], [ARR_2(-1, 1100)], 2006)])] call FUNC(statBarStatement_impact));
+        tabs[] = {{0,1,2}, {}};
+    };
+    class ACE_ballisticProtection: statBase {
+        scope = 2;
+        priority = 5;
+        stats[] = {"passthrough"};
+        displayName = "$STR_a3_rscdisplayarsenal_stat_passthrough";
+        showBar = 1;
+        barStatement = QUOTE([ARR_3((_this select 0) select 0, _this select 1, [ARR_3([ARR_2(0, 0.63)], [ARR_2(0.01, 1)], false)])] call FUNC(statBarStatement_default));
+        tabs[] = {{3,4,6}, {}};
+    };
+    class ACE_explosiveResistance: statBase {
+        scope = 2;
+        priority = 4;
+        stats[] = {"armor"};
+        displayName = "$STR_a3_rscdisplayarsenal_stat_armor";
+        showBar = 1;
+        barStatement = QUOTE([ARR_3((_this select 0) select 0, _this select 1, [ARR_3([ARR_2(0, 0.80)], [ARR_2(0.01, 1)], false)])] call FUNC(statBarStatement_default));
+        tabs[] = {{3,4,6}, {}};
+    };
+    class ACE_load: statBase {
+        scope = 2;
+        priority = 3;
+        stats[] = {"maximumLoad"};
+        displayName = "$STR_a3_rscdisplayarsenal_stat_load";
+        showBar = 1;
+        barStatement = QUOTE([ARR_3((_this select 0) select 0, _this select 1, [ARR_3([ARR_2(0, 500)], [ARR_2(0.01, 1)], false)])] call FUNC(statBarStatement_default));
+        tabs[] = {{3,4,5}, {}};
+    };
+};

addons/arsenal/XEH_PREP.hpp

@@ -1,4 +1,5 @@
 PREP(addListBoxItem);
+PREP(addStat);
 PREP(addVirtualItems);
 PREP(buttonCargo);
 PREP(buttonClearAll);
@@ -10,14 +11,18 @@ PREP(buttonLoadoutsLoad);
 PREP(buttonLoadoutsRename);
 PREP(buttonLoadoutsSave);
 PREP(buttonLoadoutsShare);
+PREP(buttonStats);
+PREP(buttonStatsPage);
 PREP(clearSearchbar);
+PREP(compileStats);
 PREP(fillLeftPanel);
 PREP(fillLoadoutsList);
 PREP(fillRightPanel);
 PREP(handleLoadoutsSearchbar);
 PREP(handleMouse);
 PREP(handleScrollWheel);
 PREP(handleSearchbar);
+PREP(handleStats);
 PREP(initBox);
 PREP(itemInfo);
 PREP(loadoutsChangeTab);
@@ -37,10 +42,16 @@ PREP(open3DEN);
 PREP(openBox);
 PREP(portVALoadouts);
 PREP(removeBox);
+PREP(removeStat);
 PREP(removeVirtualItems);
 PREP(scanConfig);
 PREP(showItem);
 PREP(sortPanel);
+PREP(statBarStatement_default);
+PREP(statBarStatement_impact);
+PREP(statTextStatement_accuracy);
+PREP(statTextStatement_mass);
+PREP(statTextStatement_rateOfFire);
 PREP(updateCamPos);
 PREP(updateRightPanel);
 PREP(updateUniqueItemsList);

addons/arsenal/XEH_preInit.sqf

@@ -1,4 +1,5 @@
 #include "script_component.hpp"
+#include "defines.hpp"
 
 ADDON = false;
 
@@ -20,4 +21,41 @@ GVAR(modList) = ["","curator","kart","heli","mark","expansion","expansionpremium
 [QGVAR(allowSharedLoadouts), "CHECKBOX", localize LSTRING(allowSharingSetting), localize LSTRING(settingCategory), true, true] call CBA_Settings_fnc_init;
 [QGVAR(EnableRPTLog), "CHECKBOX", [LSTRING(printToRPTSetting), LSTRING(printToRPTTooltip)], localize LSTRING(settingCategory), false, false] call CBA_Settings_fnc_init;
 
+[QGVAR(statsToggle), {
+    params ["_display", "_showStats"];
+
+    private _statsCtrlGroupCtrl = _display displayCtrl IDC_statsBox;
+    private _statsPreviousPageCtrl = _display displayCtrl IDC_statsPreviousPage;
+    private _statsNextPageCtrl = _display displayCtrl IDC_statsNextPage;
+    private _statsCurrentPageCtrl = _display displayCtrl IDC_statsCurrentPage;
+
+    private _statsButtonCtrl = _display displayCtrl IDC_statsButton;
+    private _statsButtonCloseCtrl = _display displayCtrl IDC_statsButtonClose;
+
+    {
+        _x ctrlShow (GVAR(showStats) && {_showStats});
+    } forEach [
+        _statsCtrlGroupCtrl,
+        _statsPreviousPageCtrl,
+        _statsNextPageCtrl,
+        _statsCurrentPageCtrl,
+        _statsButtonCloseCtrl
+    ];
+
+    _statsButtonCtrl ctrlShow (!GVAR(showStats) && {_showStats})
+}] call CBA_fnc_addEventHandler;
+
+[QGVAR(statsButton), {
+    _this call FUNC(buttonStats);
+}] call CBA_fnc_addEventHandler;
+
+[QGVAR(statsChangePage), {
+    _this call FUNC(buttonStatsPage);
+}] call CBA_fnc_addEventHandler;
+
+
+[QGVAR(displayStats), {
+    _this call FUNC(handleStats);
+}] call CBA_fnc_addEventHandler;
+
 ADDON = true;

addons/arsenal/XEH_preStart.sqf

@@ -3,3 +3,4 @@
 #include "XEH_PREP.hpp"
 
 call FUNC(scanConfig);
+call FUNC(compileStats);

addons/arsenal/config.cpp

@@ -39,3 +39,4 @@ class Cfg3DEN {
 #include "ui\RscAttributes.hpp"
 #include "CfgEventHandlers.hpp"
 #include "RscDisplayMain.hpp"
+#include "ACE_Arsenal_Stats.hpp"

addons/arsenal/defines.hpp

@@ -104,6 +104,32 @@
 #define IDC_buttonMisc 38
 #define IDC_buttonRemoveAllSelected 39
 #define IDC_buttonRemoveAll 40
+#define IDC_statsBox 51
+#define IDC_statsTitle1 5101
+#define IDC_statsBackground1 5102
+#define IDC_statsBar1 5103
+#define IDC_statsText1 5104
+#define IDC_statsTitle2 5105
+#define IDC_statsBackground2 5106
+#define IDC_statsBar2 5107
+#define IDC_statsText2 5108
+#define IDC_statsTitle3 5109
+#define IDC_statsBackground3 5110
+#define IDC_statsBar3 5111
+#define IDC_statsText3 5112
+#define IDC_statsTitle4 5113
+#define IDC_statsBackground4 5114
+#define IDC_statsBar4 5115
+#define IDC_statsText4 5116
+#define IDC_statsTitle5 5117
+#define IDC_statsBackground5 5118
+#define IDC_statsBar5 5119
+#define IDC_statsText5 5120
+#define IDC_statsPreviousPage 52
+#define IDC_statsNextPage 53
+#define IDC_statsCurrentPage 54
+#define IDC_statsButton 55
+#define IDC_statsButtonClose 56
 
 #define IDD_loadouts_display 1127002
 #define IDC_centerBox 3

addons/arsenal/functions/fnc_addStat.sqf

@@ -0,0 +1,99 @@
+/*
+ * Author: Alganthe
+ * Add a stat to ACE Arsenal.
+ *
+ * Arguments:
+ * 0: Tabs to add the stat to (ARRAY of ARRAYS)
+   * 0.1: Left tab indexes (ARRAY of NUMBERS)
+   * 0.2 Right tab indexes (ARRAY of NUMBERS)
+ * 1: Stat class (STRING) (A unique string for each stat)
+ * 2: Config entries to pass (ARRAY of STRINGS)
+ * 3: Title (STRING)
+ * 4: Show bar / show text bools (ARRAY of BOOLS)
+   * 4.1 Show bar (BOOL)
+   * 4.2 Show text (BOOL)
+ * 5: Array of statements (ARRAY of ARRAYS)
+   * 5.1: Bar code (CODE)
+   * 5.2 Text code (CODE)
+   * 5.3 Condition code (CODE)
+ * 6: Priority (NUMBER) (Optional)
+ *
+ * Return Value:
+ * 0: Array of IDs (ARRAY of STRINGS)
+ *
+ * Example:
+ * [[[0,1,2], [7]], "scopeStat", ["scope"], "Scope", [false, true], [{}, {
+        params ["_statsArray", "_itemCfg"];
+        getNumber (_itemCfg >> _statsArray select 0)
+    }, {true}]] call ACE_arsenal_fnc_addStat
+ *
+ * Public: Yes
+*/
+#include "script_component.hpp"
+params [
+    ["_tabs", [[], []], [[]], 2],
+    ["_class", "", [""]],
+    ["_stats", [], [[]]],
+    ["_title", "", [""]],
+    ["_bools", [false, false], [[]], 2],
+    ["_statements", [{}, {}, {true}], [[]], 3],
+    ["_priority", 0, [0]]
+];
+
+_tabs params [
+    ["_leftTabs", [], [[]]],
+    ["_rightTabs", [], [[]]]
+];
+
+_bools params [["_showBar", false, [false]], ["_showText", false, [false]]];
+
+_statements params [
+    ["_barStatement", {}, [{}]],
+    ["_textStatement", {}, [{}]],
+    ["_condition", {true}, [{}]]
+];
+
+private _statsListLeftPanel = uiNamespace getVariable QGVAR(statsListLeftPanel);
+private _statsListRightPanel = uiNamespace getVariable QGVAR(statsListRightPanel);
+private _returnArray = [];
+
+private _fnc_addToTabs = {
+    params ["_tabsList", "_tabsToAddTo", "_sideString", "_returnIndex"];
+    {
+        private _currentTab = _tabsList select _x;
+
+        private _finalID = [_class, _sideString, [str _x, format ["0%1", _x]] select (_x < 10)] joinString "";
+
+        if ({{_x select 0  == _finalID} count _x > 0} count _currentTab > 0) then {
+            TRACE_1("A stat with this ID already exists", _finalID);
+        } else {
+
+            private _arrayToSave = +_finalArray;
+            _arrayToSave set [0, _finalID];
+            _returnArray pushBack _finalID;
+
+            // Add to existing page if there's enough space, otherwise create a new page
+            if ({count _x < 5} count _currentTab > 0) then {
+                {
+                    if (count _x < 5) exitWith {
+                        (_currentTab select _forEachIndex) append [_arrayToSave];
+                    };
+                } foreach _currentTab;
+            } else {
+                _currentTab pushBack [_arrayToSave];
+            };
+        };
+    } foreach _tabsToAddTo;
+};
+
+private _finalArray = ["", _stats, _title, [_showBar, _showText], [_barStatement, _textStatement, _condition], _priority];
+
+if (count _leftTabs > 0) then {
+    [_statsListLeftPanel, _leftTabs, "L", 0] call _fnc_addToTabs;
+};
+
+if (count _rightTabs > 0) then {
+    [_statsListRightPanel, _rightTabs, "R", 1] call _fnc_addToTabs;
+};
+
+_returnArray

addons/arsenal/functions/fnc_buttonHide.sqf

@@ -48,5 +48,12 @@ private _showToggle = !ctrlShown (_display displayCtrl IDC_menuBar);
     IDC_buttonCurrentMag,
     IDC_buttonCurrentMag2,
     IDC_iconBackgroundCurrentMag,
-    IDC_iconBackgroundCurrentMag2
+    IDC_iconBackgroundCurrentMag2,
+    IDC_statsButton,
+    IDC_statsPreviousPage,
+    IDC_statsNextPage,
+    IDC_statsCurrentPage,
+    IDC_statsButtonClose
 ];
+
+[QGVAR(statsToggle), [_display, _showToggle]] call CBA_fnc_localEvent;

addons/arsenal/functions/fnc_buttonStats.sqf

@@ -0,0 +1,31 @@
+/*
+ * Author: Alganthe
+ * Toggle the stats control group
+ *
+ * Arguments:
+ * 0: Arsenal display <DISPLAY>
+ * 1: Button control <CONTROL>
+ *
+ * Return Value:
+ * None
+ *
+ * Public: No
+*/
+#include "script_component.hpp"
+#include "..\defines.hpp"
+
+params ["_display"];
+
+(_display displayCtrl IDC_statsButton) ctrlShow GVAR(showStats);
+GVAR(showStats) = !GVAR(showStats);
+
+{
+    (_display displayCtrl _x) ctrlShow GVAR(showStats);
+} foreach [
+    IDC_statsBox,
+    IDC_statsPreviousPage,
+    IDC_statsNextPage,
+    IDC_statsCurrentPage,
+    IDC_statsButtonClose
+];
+