Common - Add ace_common_fnc_addExplosionEventHandler

addons/common/XEH_PREP.hpp

@@ -269,6 +269,7 @@ PREP(_handleRequestAllSyncedEvents);
 // other eventhandlers
 PREP(addActionEventHandler);
 PREP(addActionMenuEventHandler);
+PREP(addExplosionEventHandler);
 PREP(addMapMarkerCreatedEventHandler);
 PREP(addPlayerEH);
 

addons/common/functions/fnc_addExplosionEventHandler.sqf

@@ -0,0 +1,38 @@
+#include "..\script_component.hpp"
+/*
+ * Author: johnb432, PabstMirror
+ * Adds event hander for explosions (for local projectiles)
+ * Warning: For shots that are tracers and explosive the event will trigger on all machines in range
+ *          This function may be changed after 2.18!
+ *
+ * Arguments:
+ * 0: Code to execute <CODE>
+ *
+ * Return Value:
+ * The CBA Event Handler Index <NUMBER>
+ *
+ * Example:
+ * [{systemChat "boom"}] call ace_common_fnc_addExplosionEventHandler
+ *
+ * Public: No (maybe after 2.18)
+ */
+
+params [["_code", {}, [{}]]];
+
+if !(missionNamespace getVariable [QGVAR(addExplosionEventHandlerActive), false]) then {
+    GVAR(addExplosionEventHandlerActive) = true;
+
+    addMissionEventHandler ["ProjectileCreated", {
+        params ["_projectile"];
+        TRACE_2("pc",typeOf _projectile,local _projectile);
+
+        if (!local _projectile) exitWith {}; // Rockets only explode on local clients
+
+        _projectile addEventHandler ["Explode", {
+            TRACE_1("exp",_this);
+            [QGVAR(explosion), _this] call CBA_fnc_localEvent;
+        }];
+    }];
+};
+
+[QGVAR(explosion), _code] call CBA_fnc_addEventHandler

addons/hearing/XEH_postInit.sqf

@@ -16,16 +16,17 @@ if (isServer) then {
     // Only install event handler if combat deafness is enabled
     if (!GVAR(enableCombatDeafness)) exitWith {};
 
-    addMissionEventHandler ["ProjectileCreated", {
-        params ["_projectile"];
-
-        if (!local _projectile) exitWith {};
-
-        // Rockets only explode on local clients
-        _projectile addEventHandler ["Explode", {
-            [QGVAR(explosion), _this] call CBA_fnc_globalEvent;
-        }];
-    }];
+    [{ // Convert ace_common's local explosion to a hearing global explosion event 
+        params ["_projectile", "_pos"];
+        TRACE_1("Explode",_this);
+
+        // If projectile is local only, don't raise event globally
+        if (isMultiplayer && {(netId _projectile) == "0:0"}) then { // TODO: netId always returns valid after 2.18
+            [QGVAR(explosion), [_projectile, _pos]] call CBA_fnc_localEvent;
+        } else {
+            [QGVAR(explosion), [_projectile, _pos]] call CBA_fnc_globalEvent;
+        };
+    }] call EFUNC(common,addExplosionEventHandler);
 }] call CBA_fnc_addEventHandler;
 
 if (!hasInterface) exitWith {};

addons/hearing/functions/fnc_explosion.sqf

@@ -6,13 +6,12 @@
  * Arguments:
  * 0: Projectile <OBJECT>
  * 1: Explosion position ASL <ARRAY>
- * 2: Velocity <ARRAY> (unused)
  *
  * Return Value:
  * None
  *
  * Example:
- * [_projectile, [0, 0, 0], [0, 0, 0]] call ace_hearing_fnc_explosion
+ * [_projectile, [0, 0, 0]] call ace_hearing_fnc_explosion
  *
  * Public: No
  */