libcgi-perl: upgrade 4.38 -> 4.43; enable ptest

* Add libhtml-parser-perl to RDEPENDS for HTML::Entities dependency

Upstream release notes:

4.43 2019-05-01

    [ FIX / TESTING ]
    - support unquoted multipart/form-data name values (GH openembedded#234)

4.42 2019-03-26

    [ DOCUMENTATION ]
    - clarify licence also in Makefile.PL (GH openembedded#232)

4.41 2019-03-26

    [ DOCUMENTATION ]
    - clarify licence (GH openembedded#232)

4.40 2018-08-15

    [ FIX / TESTING ]
    - support perls < 5.10.1 in Makefile.PL by being more dynamic
      (GH openembedded#229, GH openembedded#230, thanks to Aristotle)

4.39 2018-08-13

    [ FIX / TESTING ]
    - specify CONFIGURE_REQUIRES in Makefile.PL so can use TEST_REQUIRES
      to build with older perls (GH openembedded#228)

Signed-off-by: Tim Orling <[email protected]>
Signed-off-by: Khem Raj <[email protected]>

meta-perl/recipes-perl/libcgi/libcgi-perl_4.43.bb

@@ -0,0 +1,50 @@
+DESCRIPTION = "CGI.pm is a stable, complete and mature solution for processing and preparing \
+HTTP requests and responses. Major features including processing form \
+submissions, file uploads, reading and writing cookies, query string generation \
+and manipulation, and processing and preparing HTTP headers."
+HOMEPAGE = "http://search.cpan.org/~leejo/CGI-4.28/lib/CGI.pod"
+SECTION = "libs"
+LICENSE = "Artistic-2.0 | GPL-2.0"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=415fc49abed2728f9480cd32c8d67beb"
+
+SRC_URI = "http://search.cpan.org/CPAN/authors/id/L/LE/LEEJO/CGI-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "8c1f2cf11e4410911827ea48d58aaecc"
+SRC_URI[sha256sum] = "14b94f9df6e48fc26ebc4fa1e01a7b534cbc1611028a49028f9ac9d8ca27b734"
+
+S = "${WORKDIR}/CGI-${PV}"
+
+inherit cpan ptest-perl
+
+RDEPENDS_${PN} += "\
+    libhtml-parser-perl \
+    perl-module-base \
+    perl-module-deprecate \
+    perl-module-if \
+"
+
+do_install_prepend() {
+    # requires "-T" (taint) command line option
+    rm -rf ${B}/t/push.t
+    rm -rf ${B}/t/utf8.t
+    # tests building of docs
+    rm -rf ${B}/t/compiles_pod.t
+}
+
+RDEPENDS_${PN}-ptest += " \
+    libtest-deep-perl \
+    perl-module-bytes \
+    perl-module-file-find \
+    perl-module-filehandle \
+    perl-module-findbin \
+    perl-module-lib \
+    perl-module-perlio \
+    perl-module-perlio-scalar \
+    perl-module-test-more \
+    perl-module-utf8 \
+"
+
+RPROVIDES_${PN} += "perl-module-cgi"
+
+BBCLASSEXTEND = "native"