Add NixOS Flake

.gitignore

@@ -1,3 +1,6 @@
+# Nix Build dir
+/result
+
 ### Intellij template
 # Covers JetBrains IDEs: IntelliJ, RubyMine, PhpStorm, AppCode, PyCharm, CLion, Android Studio, WebStorm and Rider
 # Reference: https://intellij-support.jetbrains.com/hc/en-us/articles/206544839
@@ -342,4 +345,3 @@ fabric.properties
 
 # Android studio 3.1+ serialized cache file
 .idea/caches/build_file_checksums.ser
-

README.md

@@ -9,6 +9,8 @@ It is compatible with all kinds of 13" and 16" models, both AMD/Intel CPUs and w
 
 # Install
 
+**This discripes how to install fw-fanctrl on every distro that is not NixOS! If you want to use it on NixOS show [here](#nixos)**
+
 ## Dependancies
 
 This tool depends on `lm-sensors` to fetch CPU temperature:
@@ -78,3 +80,56 @@ It is possible to hot swap the current strategy with another one by running the
 fw-fanctrl strategyName
 ```
 where `strategyName is one of the strategies described in the config file.
+
+
+# NixOS
+
+For NixOS this repo contains an Flake. You could add it to your config like this:
+
+```nix
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
+    fw-fanctrl = {
+      url = "github:TamtamHero/fw-fanctrl/main; # This is NOT a stable tested version
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+  outputs = {nixpkgs, fw-fanctrl}: {
+    nixosConfigurations.foo = nixpkgs.lib.nixosSystem {
+      system = "x86_64-linux";
+      modules = [
+          fw-fanctrl.nixosModules.default
+          configuration.nix
+      ];
+    };
+  }
+}
+```
+and then add in your *configuration.nix*:
+```nix
+# Enable fw-fanctrl
+programs.fw-fanctrl.enable = true;
+
+# Add a custom config
+programs.fw-fanctrl.config = {
+  defaultStrategy = "lazy";
+  strategies = {
+    "lazy" = {
+      fanSpeedUpdateFrequency = 5;
+      movingAverageInterval = 30;
+      speedCurve = [
+        { temp = 0; speed = 15; }
+        { temp = 50; speed = 15; }
+        { temp = 65; speed = 25; }
+        { temp = 70; speed = 35; }
+        { temp = 75; speed = 50; }
+        { temp = 85; speed = 100; }
+      ];
+    };
+  };
+};
+
+# Or just change the default strategy form the default config
+programs.fw-fanctrl.config.defaultStrategy = "medium";
+```

fanctrl.py

@@ -255,7 +255,7 @@ def main():
         nargs="?",
         help="Switches the strategy of a currently running fw-fanctrl instance",
     )
-    parser.add_argument("--config", type=str, help="Path to config file", default=".")
+    parser.add_argument("--config", type=str, help="Path to config file", default="/etc/fw-fanctrl/config.json")
     parser.add_argument(
         "--strategy",
         type=str,

flake.nix

@@ -0,0 +1,29 @@
+{
+  description = "A software to controll the Framework fan speed";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
+
+    flake-compat = {
+      url = "github:edolstra/flake-compat";
+      flake = false;
+    };
+  };
+
+  outputs = { self, nixpkgs, flake-compat }: {
+    packages.x86_64-linux.default = self.packages.x86_64-linux.fw-fanctrl;
+    packages.x86_64-linux.fw-fanctrl = (
+      import nixpkgs {
+        currentSystem = "x86_64-linux";
+        localSystem = "x86_64-linux";
+      }).pkgs.callPackage ./nix/packages/fw-fanctrl.nix {};
+
+    packages.x86_64-linux.fw-ectool = (
+      import nixpkgs {
+        currentSystem = "x86_64-linux";
+        localSystem = "x86_64-linux";
+      }).pkgs.callPackage ./nix/packages/fw-ectool.nix {};
+
+    nixosModules.default = import ./nix/module.nix;
+  };
+}

install.sh

@@ -65,8 +65,8 @@ function install() {
     cp "./fanctrl.py" "/usr/local/bin/fw-fanctrl"
     chmod +x "/usr/local/bin/fw-fanctrl"
     chown "$LOGNAME:$LOGNAME" "/usr/local/bin/fw-fanctrl"
-    mkdir -p "$HOME/.config/fw-fanctrl"
-    cp -n "./config.json" "$HOME/.config/fw-fanctrl/" || true
+    mkdir -p "/etc/fw-fanctrl"
+    cp -n "./config.json" "/etc/fw-fanctrl/config.json" || true
 
     # cleaning legacy file
     rm "/usr/local/bin/fanctrl.py" 2> "/dev/null" || true
@@ -120,4 +120,4 @@ else
     echo "Unknown command '$1'"
     exit 1
 fi
-exit 0
+exit 0

nix/module.nix

@@ -0,0 +1,117 @@
+{ options, config, lib, pkgs, ... }:
+
+with lib;
+with lib.types;
+let
+  cfg = config.programs.fw-fanctrl;
+  fw-ectool = pkgs.callPackage ./packages/fw-ectool.nix {};
+  fw-fanctrl = pkgs.callPackage ./packages/fw-fanctrl.nix {};
+  defaultConfig = builtins.fromJSON (builtins.readFile ../config.json);
+in
+{
+  options.programs.fw-fanctrl = {
+    enable = mkOption {
+      type = bool;
+      default = false;
+      description = ''
+        Enable fw-fanctrl systemd service and install the needed packages.
+      '';
+    };
+    configFile = mkOption {
+      type = lines;
+      default = builtins.readFile ../config.json;
+      description = ''
+        Config json that creates the config in /etc/fw-fanctrl/config.json.
+      '';
+    };
+    config = {
+      defaultStrategy = mkOption {
+        type = str;
+        default = defaultConfig.defaultStrategy;
+        description = "Default strategy to use";
+      };
+      strategyOnDischarging = mkOption {
+        type = str;
+        default = defaultConfig.strategyOnDischarging; 
+        description = "Default strategy on discharging";
+      };
+      batteryChargingStatusPath = mkOption {
+        type = str;
+        default = defaultConfig.batteryChargingStatusPath;
+      };
+      strategies = mkOption {
+        default = defaultConfig.strategies;
+        type = attrsOf (submodule (
+          { options, name, ... }:
+          {
+            options = {
+              name = mkOption {
+                type = str;
+                default = "";
+                description = "Name of the strategy";
+              };
+              fanSpeedUpdateFrequency = mkOption {
+                type = int;
+                default = 5;
+              };
+              movingAverageInterval = mkOption {
+                type = int;
+                default = 25;
+              };
+              speedCurve = mkOption {
+                default = [];
+                type = listOf (submodule (
+                  { options, ... }:
+                  {
+                    options = {
+                      temp = mkOption {
+                        type = int;
+                        default = 0;
+                        description = "Tempreture on which the fan speed should be changed";
+                      };
+                      speed = mkOption {
+                        type = int;
+                        default = 0;
+                        description = "Percent how fast the fan should run at";
+                      };
+                    };
+                  }
+                ));
+              }; 
+            };
+          }
+        ));
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    # Install package
+    environment.systemPackages = [
+      fw-fanctrl
+      fw-ectool
+    ];
+
+    # Create config
+    environment.etc."fw-fanctrl/config.json" = {
+      text = builtins.toJSON cfg.config;
+    };
+
+    # Create Service
+    systemd.services.fw-fanctrl = {
+      description = "Framework Fan Controller";
+      after = [ "multi-user.target" ];
+      serviceConfig = {
+        Type = "simple";
+        Restart = "always";
+        ExecStart = "${fw-fanctrl}/bin/fw-fanctrl --config /etc/fw-fanctrl/config.json --no-log";
+      };
+      enable = true;
+      wantedBy = [ "multi-user.target" ];
+    };
+
+    # Create suspend config
+    environment.etc."systemd/system-sleep/fw-fanctrl-suspend.sh".source =
+        pkgs.writeShellScript "fw-fanctrl-suspend.sh" (builtins.replaceStrings [ "runuser" "logname" "fw-fanctrl" ] [ "${pkgs.util-linux}/bin/runuser" "${pkgs.coreutils}/bin/logname" "${fw-fanctrl}/bin/fw-fanctrl" ] (builtins.readFile ../services/system-sleep/fw-fanctrl-suspend));
+  };
+}

nix/packages/fw-ectool.nix

@@ -0,0 +1,43 @@
+{
+  stdenv,
+  lib,
+  autoPatchelfHook,
+  libusb1,
+  libftdi1
+}:
+
+stdenv.mkDerivation {
+  version = "20-04-2024";
+  name = "fw-ectool";
+  src = ../../.;
+
+  outputs = [ "out" ];
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+  ];
+
+  propagatedBuildInputs = [
+    libusb1
+    libftdi1
+  ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    runHook preInstall
+    install -m755 ./bin/ectool $out/bin/ectool
+    ln -s $out/bin/ectool $out/bin/fw-ectool
+    chmod -R 755 $out/bin/*
+  '';
+
+  doCheck = false;
+
+  meta = with lib; {
+    mainProgram = "ectool";
+    homepage = "https://github.com/TamtamHero/fw-fanctrl";
+    description = "fw-ectool customized for fw-fanctrl";
+    platforms = with platforms; linux;
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ "Svenum" ];
+  };
+}