Implement Non Fungible Token Royalty (EIP2981)

CHANGELOG.md

@@ -2,6 +2,7 @@
 
 ## Unreleased
 
+ * `ERC2891`: add a new extension of `ERC721` to handle royalty information.([#3012](https://github.com/OpenZeppelin/openzeppelin-contracts/pull/3012))
  * `GovernorTimelockControl`: improve the `state()` function to have it reflect cases where a proposal has been canceled directly on the timelock. ([#2977](https://github.com/OpenZeppelin/openzeppelin-contracts/pull/2977))
  * `Math`: add a `abs(int256)` method that returns the unsigned absolute value of a signed value. ([#2984](https://github.com/OpenZeppelin/openzeppelin-contracts/pull/2984))
  * Preset contracts are now deprecated in favor of [Contracts Wizard](https://wizard.openzeppelin.com). ([#2986](https://github.com/OpenZeppelin/openzeppelin-contracts/pull/2986))

contracts/interfaces/IERC2981.sol

@@ -7,6 +7,11 @@ import "./IERC165.sol";
 
 /**
  * @dev Interface for the NFT Royalty Standard
+ *
+ * A standardized way to retrieve royalty payment information for non-fungible tokens (NFTs) to enable universal
+ * support for royalty payments across all NFT marketplaces and ecosystem participants.
+ *
+ * _Available since v4.5._
  */
 interface IERC2981 is IERC165 {
     /**

contracts/mocks/ERC1155RoyaltyMock.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity ^0.8.0;
+
+import "../token/ERC1155/extensions/ERC1155Royalty.sol";
+
+contract ERC1155RoyaltyMock is ERC1155Royalty {
+    constructor(string memory uri) ERC1155(uri) {}
+
+    function setTokenRoyalty(
+        uint256 tokenId,
+        address recipient,
+        uint96 fraction
+    ) public {
+        _setTokenRoyalty(tokenId, recipient, fraction);
+    }
+
+    function setDefaultRoyalty(address recipient, uint96 fraction) public {
+        _setDefaultRoyalty(recipient, fraction);
+    }
+
+    function mint(
+        address to,
+        uint256 id,
+        uint256 value,
+        bytes memory data
+    ) public {
+        _mint(to, id, value, data);
+    }
+
+    function burn(
+        address from,
+        uint256 id,
+        uint256 amount
+    ) public {
+        _burn(from, id, amount);
+    }
+
+    function deleteRoyalty() public {
+        _deleteDefaultRoyalty();
+    }
+}

contracts/mocks/ERC721RoyaltyMock.sol

@@ -0,0 +1,33 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity ^0.8.0;
+
+import "../token/ERC721/extensions/ERC721Royalty.sol";
+
+contract ERC721RoyaltyMock is ERC721Royalty {
+    constructor(string memory name, string memory symbol) ERC721(name, symbol) {}
+
+    function setTokenRoyalty(
+        uint256 tokenId,
+        address recipient,
+        uint96 fraction
+    ) public {
+        _setTokenRoyalty(tokenId, recipient, fraction);
+    }
+
+    function setDefaultRoyalty(address recipient, uint96 fraction) public {
+        _setDefaultRoyalty(recipient, fraction);
+    }
+
+    function mint(address to, uint256 tokenId) public {
+        _mint(to, tokenId);
+    }
+
+    function burn(uint256 tokenId) public {
+        _burn(tokenId);
+    }
+
+    function deleteRoyalty() public {
+        _deleteDefaultRoyalty();
+    }
+}

contracts/token/ERC1155/extensions/ERC1155Royalty.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: MIT
+// OpenZeppelin Contracts v4.4.0 (token/ERC1155/extensions/ERC1155Royalty.sol)
+
+pragma solidity ^0.8.0;
+
+import "../ERC1155.sol";
+import "../../common/ERC2981.sol";
+import "../../../utils/introspection/ERC165.sol";
+
+/**
+ * @dev Implementation of the ERC1155 Royalty extension allowing royalty information to be stored and retrieved, as defined in
+ * https://eips.ethereum.org/EIPS/eip-2981[EIP-2981].
+ *
+ * Adds the {_setTokenRoyalty} methods to set the token royalty information, and {_setDefaultRoyalty} method to set a default
+ * royalty information.
+ *
+ * NOTE: As specified in EIP-2981, royalties are technically optional and payment is not enforced by this contract.
+ * See https://eips.ethereum.org/EIPS/eip-2981#optional-royalty-payments[Rationale] in the EIP.
+ *
+ * _Available since v4.5._
+ */
+abstract contract ERC1155Royalty is ERC2981, ERC1155 {
+    /**
+     * @dev See {IERC165-supportsInterface}.
+     */
+    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC1155, ERC2981) returns (bool) {
+        return interfaceId == type(IERC2981).interfaceId || super.supportsInterface(interfaceId);
+    }
+
+    /**
+     * @dev Destroys `tokenId`.
+     * The royalty information is cleared when the token is burned.
+     *
+     * Requirements:
+     *
+     * - `tokenId` must exist.
+     *
+     * Emits a {Transfer} event.
+     */
+    function _burn(
+        address from,
+        uint256 id,
+        uint256 amount
+    ) internal virtual override {
+        super._burn(from, id, amount);
+        _resetTokenRoyalty(id);
+    }
+}

contracts/token/ERC721/extensions/ERC721Royalty.sol

@@ -0,0 +1,44 @@
+// SPDX-License-Identifier: MIT
+// OpenZeppelin Contracts v4.4.0 (token/ERC721/extensions/ERC721Royalty.sol)
+
+pragma solidity ^0.8.0;
+
+import "../ERC721.sol";
+import "../../common/ERC2981.sol";
+import "../../../utils/introspection/ERC165.sol";
+
+/**
+ * @dev Implementation of the ERC721 Royalty extension allowing royalty information to be stored and retrieved, as defined in
+ * https://eips.ethereum.org/EIPS/eip-2981[EIP-2981].
+ *
+ * Adds the {_setTokenRoyalty} methods to set the token royalty information, and {_setDefaultRoyalty} method to set a default
+ * royalty information.
+ *
+ * NOTE: As specified in EIP-2981, royalties are technically optional and payment is not enforced by this contract.
+ * See https://eips.ethereum.org/EIPS/eip-2981#optional-royalty-payments[Rationale] in the EIP.
+ *
+ * _Available since v4.5._
+ */
+abstract contract ERC721Royalty is ERC2981, ERC721 {
+    /**
+     * @dev See {IERC165-supportsInterface}.
+     */
+    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC721, ERC2981) returns (bool) {
+        return interfaceId == type(IERC2981).interfaceId || super.supportsInterface(interfaceId);
+    }
+
+    /**
+     * @dev Destroys `tokenId`.
+     * The royalty information is cleared when the token is burned.
+     *
+     * Requirements:
+     *
+     * - `tokenId` must exist.
+     *
+     * Emits a {Transfer} event.
+     */
+    function _burn(uint256 tokenId) internal virtual override {
+        super._burn(tokenId);
+        _resetTokenRoyalty(tokenId);
+    }
+}

contracts/token/common/ERC2981.sol

@@ -0,0 +1,113 @@
+// SPDX-License-Identifier: MIT
+// OpenZeppelin Contracts v4.4.0 (token/common/ERC2981.sol)
+
+pragma solidity ^0.8.0;
+
+import "../../interfaces/IERC2981.sol";
+import "../../utils/introspection/ERC165.sol";
+
+/**
+ * @dev Implementation of the Royalty Standard allowing royalty information to be stored and retrieved.
+ *
+ * Adds the {_setTokenRoyalty} methods to set the token royalty information, and {_setDefaultRoyalty} method to set a default
+ * royalty information.
+ *
+ * NOTE: As specified in EIP-2981, royalties are technically optional and payment is not enforced by this contract.
+ * See https://eips.ethereum.org/EIPS/eip-2981#optional-royalty-payments[Rationale] in the EIP.
+ *
+ * _Available since v4.5._
+ */
+abstract contract ERC2981 is IERC2981, ERC165 {
+    struct RoyaltyInfo {
+        address receiver;
+        uint96 royaltyFraction;
+    }
+
+    RoyaltyInfo private _defaultRoyaltyInfo;
+    mapping(uint256 => RoyaltyInfo) private _tokenRoyaltyInfo;
+
+    /**
+     * @dev See {IERC165-supportsInterface}.
+     */
+    function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC165) returns (bool) {
+        return interfaceId == type(IERC2981).interfaceId || super.supportsInterface(interfaceId);
+    }
+
+    /**
+     * @dev Sets the royalty info for a specific token id, overriding the default royalty info.
+     *
+     * Requirements:
+     * - `tokenId` must be already mined.
+     * - `receiver` cannot be the zero address.
+     * - `fraction` must indicate the percentage fraction using two decimals.
+     */
+    function _setTokenRoyalty(
+        uint256 tokenId,
+        address receiver,
+        uint96 fraction
+    ) internal virtual {
+        require(fraction <= _feeDenominator(), "ERC2981: Royalty percentage will exceed salePrice");
+        require(receiver != address(0), "ERC2981: Invalid parameters");
+
+        _tokenRoyaltyInfo[tokenId] = RoyaltyInfo(receiver, fraction);
+    }
+
+    /**
+     * @dev Sets the royalty info that tokens will default to.
+     *
+     * Requirements:
+     * - `receiver` cannot be the zero address.
+     * - `fraction` must indicate the percentage fraction. Needs to be set appropriately
+     * according to the _feeDenominator granularity.
+     */
+    function _setDefaultRoyalty(address receiver, uint96 fraction) internal virtual {
+        require(fraction <= _feeDenominator(), "ERC2981: Royalty percentage will exceed salePrice");
+        require(receiver != address(0), "ERC2981: Invalid receiver");
+
+        _defaultRoyaltyInfo = RoyaltyInfo(receiver, fraction);
+    }
+
+    /**
+     * @dev See {IERC2981-royaltyInfo}
+     */
+    function royaltyInfo(uint256 _tokenId, uint256 _salePrice) external view override returns (address, uint256) {
+        RoyaltyInfo memory royalty = _tokenRoyaltyInfo[_tokenId];
+
+        if (royalty.receiver == address(0)) {
+            royalty = _defaultRoyaltyInfo;
+        }
+
+        uint256 royaltyAmount = (_salePrice * royalty.royaltyFraction) / _feeDenominator();
+
+        return (royalty.receiver, royaltyAmount);
+    }
+
+    /**
+     * @dev Returns the percentage granularity being used. The default denominator is 10000
+     *  but it can be customized by an override.
+     */
+    function _feeDenominator() internal pure virtual returns (uint96) {
+        return 10000;
+    }
+
+    /**
+     * @dev Removes `tokenId` royalty information.
+     * The royalty information is cleared and the token royalty fallbacks to the default royalty.
+     *
+     * Requirements:
+     *
+     * - `tokenId` royalty information must exist.
+     *
+     */
+    function _resetTokenRoyalty(uint256 tokenId) internal virtual {
+        delete _tokenRoyaltyInfo[tokenId];
+    }
+
+    /**
+     * @dev Removes default royalty information.
+     *
+     */
+    function _deleteDefaultRoyalty() internal virtual {
+        delete _defaultRoyaltyInfo;
+    }
+}

test/token/ERC1155/extensions/ERC1155Royalty.test.js

@@ -0,0 +1,41 @@
+const { BN, constants } = require('@openzeppelin/test-helpers');
+const { expect } = require('chai');
+const { ZERO_ADDRESS } = constants;
+
+const { shouldBehaveLikeERC2981 } = require('../../common/ERC2981.behavior');
+
+const ERC1155RoyaltyMock = artifacts.require('ERC1155RoyaltyMock');
+
+contract('ERC1155Royalty', function (accounts) {
+  const [ account1, account2 ] = accounts;
+  const uri = 'https://token.com';
+  const tokenId1 = new BN('1');
+  const tokenId2 = new BN('2');
+  const salePrice = new BN('1000');
+  const firstTokenAmount = new BN('42');
+  const secondTokenAmount = new BN('23');
+
+  beforeEach(async function () {
+    this.token = await ERC1155RoyaltyMock.new(uri);
+
+    await this.token.mint(account1, tokenId1, firstTokenAmount, '0x');
+    await this.token.mint(account1, tokenId2, secondTokenAmount, '0x');
+    this.account1 = account1;
+    this.account2 = account2;
+    this.tokenId1 = tokenId1;
+    this.tokenId2 = tokenId2;
+    this.salePrice = salePrice;
+  });
+
+  describe('token specific functions', function () {
+    it('removes royalty information after burn', async function () {
+      await this.token.burn(account1, tokenId1, firstTokenAmount);
+      const tokenInfo = await this.token.royaltyInfo(tokenId1, salePrice);
+
+      expect(tokenInfo[0]).to.be.equal(ZERO_ADDRESS);
+      expect(tokenInfo[1]).to.be.bignumber.equal(new BN('0'));
+    });
+  });
+
+  shouldBehaveLikeERC2981();
+});

test/token/ERC721/extensions/ERC721Royalty.test.js

@@ -0,0 +1,35 @@
+const { BN, constants } = require('@openzeppelin/test-helpers');
+const ERC721RoyaltyMock = artifacts.require('ERC721RoyaltyMock');
+const { ZERO_ADDRESS } = constants;
+
+const { shouldBehaveLikeERC2981 } = require('../../common/ERC2981.behavior');
+
+contract('ERC721Royalty', function (accounts) {
+  const [ account1, account2 ] = accounts;
+  const tokenId1 = new BN('1');
+  const tokenId2 = new BN('2');
+  const salePrice = new BN('1000');
+
+  beforeEach(async function () {
+    this.token = await ERC721RoyaltyMock.new('My Token', 'TKN');
+
+    await this.token.mint(account1, tokenId1);
+    await this.token.mint(account1, tokenId2);
+    this.account1 = account1;
+    this.account2 = account2;
+    this.tokenId1 = tokenId1;
+    this.tokenId2 = tokenId2;
+    this.salePrice = salePrice;
+  });
+
+  describe('token specific functions', function () {
+    it('removes royalty information after burn', async function () {
+      await this.token.burn(tokenId1);
+      const tokenInfo = await this.token.royaltyInfo(tokenId1, salePrice);
+
+      expect(tokenInfo[0]).to.be.equal(ZERO_ADDRESS);
+      expect(tokenInfo[1]).to.be.bignumber.equal(new BN('0'));
+    });
+  });
+  shouldBehaveLikeERC2981();
+});