linode-cli: remove deprecated perl version, init python version at 2.14.1

[ryantm]

Motivation for this change

This is the new official CLI for accessing the Linode APIs.

Things done

• Tested using sandboxing (nix.useSandbox on NixOS, or option sandbox in nix.conf on non-NixOS linux)
• Built on platform(s)
  • NixOS
  • macOS
  • other Linux distributions
• Tested via one or more NixOS test(s) if existing and applicable for the change (look inside nixos/tests)
• Tested compilation of all pkgs that depend on this change using nix-shell -p nixpkgs-review --run "nixpkgs-review wip"
• Tested execution of all binary files (usually in ./result/bin/)
• Determined the impact on package closure size (by running nix path-info -S before and after)
• Ensured that relevant documentation is up to date
• Fits CONTRIBUTING.md.

[jonringer]

we may want to replace the deprecated linode-cli package:
pkgs/tools/virtualization/linode-cli/default.nix

[jonringer]

also, they unfortunately mispackaged this as well for python3:

  ERROR: Could not find a version that satisfies the requirement enum34 (from linode-cli==2.14.1) (from versions: none)
  ERROR: No matching distribution found for enum34 (from linode-cli==2.14.1)

their METADATA:

Requires-Python: >=2.7
Requires-Dist: PyYAML
Requires-Dist: colorclass
Requires-Dist: enum34

enum34 should only be required if python<3.4

[jonringer]

buildPythonApplication shouldn't be used in python-modules, this should probably be moved to pkgs/tools/virtualization/linode-cli/default.nix, the top-level attr should be move to all-packages, and should look like:

  linode-cli = python3Packages.callPackage ../tools/virtualization/linode-cli/default.nix { };

[jonringer]

Here's what I came up with:

{ lib
, buildPythonApplication
, fetchFromGitHub
, fetchpatch
, isPy27
, terminaltables
, colorclass
, requests
, pyyaml
, enum34
, setuptools
}:

buildPythonApplication rec {
  pname = "linode-cli";
  version = "2.14.1";

  src = fetchFromGitHub {
    owner = "linode";
    repo = pname;
    rev = version;
    sha256 = "1hpdmbzs182iag471yvq3kwd1san04a58sczzbmw6vjv2kswn1c2";
  };

  patches = [
    # make enum34 depend on python version
    ( fetchpatch {
        url = "https://github.com/linode/linode-cli/pull/184/commits/4cf55759c5da33fbc49b9ba664698875d67d4f76.patch";
        sha256 = "04n9a6yh0abyyymvfzajhav6qxwvzjl2vs8jnqp3yqrma7kl0slj";
    })
  ];

  # remove need for git history
  prePatch = ''
    substituteInPlace setup.py \
      --replace "version=get_version()," "version='${version}',"
  '';

  propagatedBuildInputs = [
    terminaltables
    colorclass
    requests
    pyyaml
    setuptools
  ] ++ lib.optionals isPy27 [ enum34 ];

  # requires linode access token for unit tests, and running executable
  doCheck = false;

  meta = with lib; {
    homepage = "https://github.com/linode/linode-cli";
    description = "The Linode Command Line Interface";
    license = licenses.bsd3;
    maintainers = with maintainers; [ ryantm ];
  };

}

[jonringer]

I made a PR correcting the enum34 logic linode/linode-cli#184 , and included it here as a patch

[ryantm]

we may want to replace the deprecated linode-cli package:
pkgs/tools/virtualization/linode-cli/default.nix

cc @nixy maintainer of Perl linode-cli

[nixy]

we may want to replace the deprecated linode-cli package:
pkgs/tools/virtualization/linode-cli/default.nix

cc @nixy maintainer of Perl linode-cli

Seems fine to me, no objections here.