hydra-check: 1.3.5 -> 2.0.1

pkgs/by-name/hy/hydra-check/package.nix

@@ -0,0 +1,52 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  openssl,
+  stdenv,
+  installShellFiles,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "hydra-check";
+  version = "2.0.1";
+
+  src = fetchFromGitHub {
+    owner = "nix-community";
+    repo = "hydra-check";
+    rev = "v${version}";
+    hash = "sha256-QdCXToHNymOdlTyQjk9eo7LTznGKB+3pIOgjjaGoTXg=";
+  };
+
+  cargoHash = "sha256-iqFUMok36G1qSUbfY7WD6etY0dtfro3F7mLoOELzxbs=";
+
+  nativeBuildInputs = [
+    pkg-config
+    installShellFiles
+  ];
+
+  buildInputs = [
+    openssl
+  ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd hydra-check \
+      --bash <($out/bin/hydra-check --shell-completion bash) \
+      --fish <($out/bin/hydra-check --shell-completion fish) \
+      --zsh <($out/bin/hydra-check --shell-completion zsh)
+  '';
+
+  meta = {
+    description = "Check hydra for the build status of a package";
+    homepage = "https://github.com/nix-community/hydra-check";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      makefu
+      artturin
+      bryango
+      doronbehar
+    ];
+    mainProgram = "hydra-check";
+  };
+}

pkgs/top-level/all-packages.nix

@@ -9489,8 +9489,6 @@ with pkgs;
 
   hydra = callPackage ../by-name/hy/hydra/package.nix { nix = nixVersions.nix_2_24; };
 
-  hydra-check = with python3.pkgs; toPythonApplication hydra-check;
-
   icu-versions = callPackages ../development/libraries/icu { };
   inherit (icu-versions)
     icu60

pkgs/top-level/python-aliases.nix

@@ -274,6 +274,7 @@ mapAliases ({
   htmllaundry = throw "htmllaundry has been removed because it is abandoned"; # added 2024-06-04
   HTSeq = htseq; # added 2023-02-19
   hyperkitty = throw "Please use pkgs.mailmanPackages.hyperkitty"; # added 2022-04-29
+  hydra-check = throw "The Python package hydra-check was removed in favor of the top-level rust based pkgs.hydra-check"; # added 2022-04-29
   ihatemoney = throw "ihatemoney was removed because it is no longer maintained downstream"; # added 2023-04-08
   IMAPClient = imapclient; # added 2021-10-28
   imdbpy = throw "imdbpy has been renamed to cinemagoer"; # added 2022-08-08

pkgs/top-level/python-packages.nix

@@ -6065,8 +6065,6 @@ self: super: with self; {
 
   hydra-core = callPackage ../development/python-modules/hydra-core { };
 
-  hydra-check = callPackage ../development/python-modules/hydra-check { };
-
   hydrawiser = callPackage ../development/python-modules/hydrawiser { };
 
   hydrogram = callPackage ../development/python-modules/hydrogram { };