xppen: init package with nixos module

maintainers/maintainer-list.nix

@@ -13171,6 +13171,12 @@
       fingerprint = "7A10 AB8E 0BEC 566B 090C  9BE3 D812 6E55 9CE7 C35D";
     }];
   };
+  nasrally = {
+    email = "[email protected]";
+    github = "nasrally";
+    githubId = 50599445;
+    name = "Nikita Grishko";
+  };
   nat-418 = {
     github = "nat-418";
     githubId = 93013864;

nixos/modules/module-list.nix

@@ -286,6 +286,7 @@
   ./programs/xfconf.nix
   ./programs/xfs_quota.nix
   ./programs/xonsh.nix
+  ./programs/xppen.nix
   ./programs/xss-lock.nix
   ./programs/xwayland.nix
   ./programs/yabar.nix

nixos/modules/programs/xppen.nix

@@ -0,0 +1,35 @@
+{ config, lib, pkgs, ... }:
+
+with lib; let
+  cfg = config.programs.xppen;
+in
+
+{
+  options.programs.xppen = {
+    enable = mkEnableOption (lib.mdDoc "XPPen PenTablet application");
+    package = mkPackageOption pkgs "xppen" { };
+  };
+
+  config = mkIf cfg.enable {
+    hardware.uinput.enable = true;
+
+    environment.systemPackages = [
+      cfg.package
+    ];
+
+    services.udev.packages = [ cfg.package ];
+
+    system.activationScripts.xppen.text = with pkgs; ''
+      install -m 755 -d "/var/lib/pentablet/conf/xppen"
+
+      readarray -d "" files < <(find ${xppen}/usr/lib/pentablet/conf -type f -print0)
+
+      for file in "''${files[@]}"; do
+        file_new="/var''${file#${xppen + "/usr"}}"
+        if [ ! -f $file_new ]; then
+          install -m 666 "''$file" "''$file_new"
+        fi
+      done
+    '';
+  };
+}

pkgs/by-name/xp/xppen/package.nix

@@ -0,0 +1,64 @@
+{ stdenv
+, lib
+, fetchzip
+, autoPatchelfHook
+
+, libusb1
+, qt5
+, libGL
+}:
+stdenv.mkDerivation {
+  pname = "xppen";
+  version = "3.4.9";
+
+  src = fetchzip {
+    extension = "tar.gz";
+    url = "https://www.xp-pen.com/download/file.html?id=1936&pid=990&ext=gz";
+    hash = "sha256-A/dv6DpelH0NHjlGj32tKv37S+9q3F8cYByiYlMuqLg=";
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook qt5.wrapQtAppsHook ];
+
+  buildInputs = [ qt5.full libusb1 libGL ];
+
+  dontConfigure = true;
+  dontBuild = true;
+  dontCheck = true;
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin $out/share/doc $out/usr/lib/pentablet
+
+    cp -r App/usr/share/. $out/share
+    cp -r App/usr/lib/pentablet/doc/. $out/share/doc
+    cp -r App/lib $out/lib
+
+    cp -r App/usr/lib/pentablet/. $out/bin/
+    cp -r $out/bin/conf $out/usr/lib/pentablet
+
+    rm $out/bin/PenTablet.sh
+    rm -r $out/bin/conf
+    rm -r $out/bin/doc
+    rm -r $out/bin/lib
+    rm -r $out/bin/platforms
+    runHook postInstall
+  '';
+
+  postInstall = ''
+    sed -i 's#/usr/lib/pentablet#/var/lib/pentablet#g' $out/bin/PenTablet
+
+    substituteInPlace $out/share/applications/xppentablet.desktop \
+      --replace "/usr/lib/pentablet/PenTablet.sh" "PenTablet" \
+      --replace "/usr/share/icons/hicolor/256x256/apps/xppentablet.png" "xppentablet"
+  '';
+
+  meta = with lib; {
+    description = "XPPen driver";
+    homepage = "https://www.xp-pen.com/";
+    downloadPage = "https://www.xp-pen.com/download/";
+    license = licenses.unfree;
+    maintainers = with maintainers; [ nasrally ];
+    mainProgram = "PenTablet";
+    platforms = platforms.linux;
+  };
+}