Support merging/overriding for unspecified attr-set options within freeformTypes (for e.g. nixpkgs.config)

[Ma27]

In #80582 I tried to implement merging/overriding for nixpkgs.config, i.e. to make

{
  nixpkgs = mkMerge [
    { config.allowUnfree = true; }
    { config.allowUnfree = mkForce false; }
  ];
}

possible. We decided to close this back then because it was rather messy and later on freeformType was born. With this, you can create submodules with unspecified options (rather than using types.attrs for options such as nixpkgs.config).

Now it'd be theoretically possible to re-implement options.nixpkgs.config like this (the examples below assume this definition):

{
  options.nixpkgs.config = mkOption {
    type = types.submodule {
      freeformType = types.attrsOf types.oneOf (types.bool types.attrs);
      options.allowUnfree = mkOption {
        type = types.bool;
        default = false;
      };
    };
  };
}

This works perfectly fine with specified options or unspecified options that are not attribute-sets (e.g. nixpkgs.config.cudaSupport).

However, it's not possible to do merging&overriding for unspecified options that are attribute-sets. With the option definition from above, you'd get the following (wrong) result for unspecified options:

(evalModules {
  modules = [
    { /* def for `options.nixpkgs.config` from above here */ }
    { nixpkgs.config.vim.gui = true; }
    { nixpkgs.config.vim.gui = mkForce false; }
  ];
}).config.nixpkgs.config

results in

$ nix-instantiate foo.nix --eval --strict
{ allowUnfree = false; vim = { gui = { _type = "override"; content = false; priority = 50; }; }; }

I guess that this is because it cannot be distinguished between vim.gui being an attr-set and vim.gui containing info about an override.

One might argue that _type is internal and thus it can be assumed to be the result of an override (or any other module-system operation). I think it might be possible to recursively apply pushDownProperties onto unspecified freeform options, but I'm not really sure if that's a good idea, so I figured I'd leave it open for discussion if we actually want to implement support for overriding/merging for unspecified attr-sets within freeformTypes (and switch nixpkgs.config to such a definition).

cc @infinisil

[infinisil]

I think all you need to make it work is

freeformType = types.attrsOf types.anything

[Ma27]

Oh dang, thanks, that works fine %)

I guess I'll just try it against nixpkgs.config and file a PR later.