coq_kernel: init at 1.6.0

pkgs/applications/editors/jupyter-kernels/coq/default.nix

@@ -0,0 +1,58 @@
+{ stdenv
+, callPackage
+, runCommand
+, makeWrapper
+, coq
+, imagemagick
+, python3
+}:
+
+# To test (in root nixpkgs dir):
+# $(nix-build -E 'with import ./. {}; jupyter.override { definitions = { coq = coq-kernel.definition; }; }')/bin/jupyter-notebook
+
+let
+  kernel = callPackage ./kernel.nix {};
+
+in
+
+rec {
+  launcher = runCommand "coq-kernel-launcher" {
+    inherit coq;
+    python = python3.withPackages (ps: [ ps.traitlets ps.jupyter_core ps.ipykernel kernel ]);
+    buildInputs = [ makeWrapper ];
+  } ''
+    mkdir -p $out/bin
+
+    makeWrapper $python/bin/python $out/bin/coq-kernel \
+      --add-flags "-m coq_jupyter" \
+      --suffix PATH : $coq/bin
+  '';
+
+  sizedLogo = size: stdenv.mkDerivation {
+    pname = "coq-logo-${size}x${size}.png";
+    inherit (coq) version;
+
+    src = coq.src;
+
+    buildInputs = [ imagemagick ];
+
+    dontConfigure = true;
+    dontInstall = true;
+
+    buildPhase = ''
+      convert ./ide/coqide/coq.png -resize ${size}x${size} $out
+    '';
+  };
+
+  definition = {
+    displayName = "Coq " + coq.version;
+    argv = [
+      "${launcher}/bin/coq-kernel"
+      "-f"
+      "{connection_file}"
+    ];
+    language = "coq";
+    logo32 = sizedLogo "32";
+    logo64 = sizedLogo "64";
+  };
+}

pkgs/applications/editors/jupyter-kernels/coq/kernel.nix

@@ -0,0 +1,31 @@
+{ lib
+, fetchFromGitHub
+, python3
+, coq
+}:
+
+python3.pkgs.buildPythonPackage rec {
+  pname = "coq_jupyter";
+  version = "1.6.0";
+
+  src = fetchFromGitHub {
+    owner = "EugeneLoy";
+    repo = "coq_jupyter";
+    rev = "v${version}";
+    sha256 = "sha256-+Pp51cxeqjg5MW4CEccNWVjNcY9iyFNATIEage9RWJ0=";
+  };
+
+  propagatedBuildInputs = (with python3.pkgs; [ipykernel future]) ++ [coq];
+
+  nativeBuildInputs = [ coq ];
+
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://github.com/EugeneLoy/coq_jupyter";
+    description = "Jupyter kernel for Coq";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ thomasjm ];
+    platforms = platforms.all;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -35852,6 +35852,8 @@ with pkgs;
 
   coq2html = callPackage ../tools/typesetting/coq2html { };
 
+  coq-kernel = callPackage ../applications/editors/jupyter-kernels/coq { };
+
   cryptoverif = callPackage ../applications/science/logic/cryptoverif { };
 
   crypto-org-wallet = callPackage ../applications/blockchains/crypto-org-wallet { };