filen-desktop: init at 3.0.41

pkgs/by-name/fi/filen-desktop/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  appimageTools,
+  makeDesktopItem,
+}:
+let
+  pname = "filen-desktop";
+  version = "3.0.41";
+
+  arch = builtins.head (builtins.split "-" stdenv.hostPlatform.system);
+
+  src = fetchurl {
+    url = "https://github.com/FilenCloudDienste/filen-desktop/releases/download/v${version}/Filen_linux_${arch}.AppImage";
+    sha256 = "sha256-Nao5By8Z8lMbRcp2Mgw+xaiiFzUxCm6S3SAE5FfDZpk=";
+  };
+
+  desktopItem = makeDesktopItem {
+    name = "filen-desktop";
+    desktopName = "Filen Desktop";
+    comment = "Encrypted Cloud Storage";
+    icon = "filen-desktop";
+    exec = "filen-desktop %u";
+    categories = [ "Office" ];
+  };
+
+  appimageContents = appimageTools.extract { inherit pname version src; };
+in
+appimageTools.wrapType2 rec {
+  inherit pname version src;
+
+  extraInstallCommands = ''
+    mkdir -p $out/share
+    cp -rt $out/share ${desktopItem}/share/applications ${appimageContents}/usr/share/icons
+    chmod -R +w $out/share
+    find $out/share/icons -type f -iname "*.png" -execdir mv {} "$pname.png" \;
+  '';
+
+  meta = with lib; {
+    homepage = "https://filen.io/products/desktop";
+    downloadPage = "https://github.com/FilenCloudDienste/filen-desktop/releases/";
+    description = "Filen Desktop Client for Linux";
+    longDescription = ''
+      Encrypted Cloud Storage built for your Desktop.
+      Sync your data, mount network drives, collaborate with others and access files natively — powered by robust encryption and seamless integration.
+    '';
+    mainProgram = "filen-desktop";
+    platforms = platforms.linux;
+    license = lib.licenses.agpl3Only;
+    maintainers = with maintainers; [ smissingham ];
+  };
+}