Add CPUID submodule

This is a small internal module which defines the API to query the Instruction
Set Architecture (ISA) of the current CPU.  This can be used for example to
select an artifact in a JLL package which is compatible with the current CPU.

base/sysinfo.jl

@@ -526,4 +526,39 @@ function which(program_name::String)
 end
 which(program_name::AbstractString) = which(String(program_name))
 
+### Submodule with information about CPU features
+module CPUID
+
+"""
+    ISA(features::Set{String})
+
+A structure which represents the Instruction Set Architecture (ISA) of a
+computer.  It holds the `Set` of features of the CPU.
+"""
+struct ISA
+    features::Set{String}
+end
+
+Base.:<(a::ISA, b::ISA) = a.features < b.features
+
+"""
+    CPU_ISA
+
+The [`ISA`](@ref) (instruction set architecture) of the current CPU.
+"""
+const CPU_ISA = let features = filter!(f -> startswith(f, "+"),
+                                            split(unsafe_string(ccall(:LLVMGetHostCPUFeatures, Cstring, ())), ","))
+    ISA(Set(replace.(features, r"^\+" => "")))
+end
+
+# Sets of features for the x86-64 microarchitectures come from
+# https://gcc.gnu.org/onlinedocs/gcc/x86-Options.html
+const x86_64_generic = ISA(Set(("mmx", "sse", "sse2")))
+const avx = ISA(Set((x86_64_generic.features..., "sse3", "ssse3", "sse4.1", "sse4.2", "popcnt", "avx", "aes", "pclmul")))
+const avx2 = ISA(Set((avx.features..., "movbe", "avx2", "fsgsbase", "rdrnd", "fma", "bmi", "bmi2", "f16c")))
+const avx512 = ISA(Set((avx2.features..., "pku", "rdseed", "adx", "prfchw", "clflushopt", "xsavec", "xsaves", "avx512f", "clwb", "avx512vl", "avx512bw", "avx512dq", "avx512cd")))
+const x86_64_isas = [avx512, avx2, avx, x86_64_generic]
+
+end # module CPUID
+
 end # module Sys

test/sysinfo.jl

@@ -6,3 +6,7 @@
 sprint(Base.Sys.cpu_summary)
 @test Base.Sys.uptime() > 0
 Base.Sys.loadavg()
+
+@test Base.Sys.CPUID.CPU_ISA isa Base.Sys.CPUID.ISA
+@test Base.Sys.CPUID.x86_64_generic < Base.Sys.CPUID.avx2
+@test Base.Sys.CPUID.avx512 > Base.Sys.CPUID.avx