close #54, remove excluded dependencies from task inputs

ChangeLog.md

@@ -3,6 +3,8 @@ v1.0.0
 
 + Previously known as v0.9.0
 + All changes from 0.9.0-M1 to 0.9.0-M5
++ Properly configure the ShadowJar task inputs to observe the include/excludes from the `dependencies` block. This
+  allows UP-TO-DATE checking to work properly when changing the `dependencies` rules ([Issue #54](https://github.com/johnrengelman/shadow/issues/54))
 
 v0.9.0-M5
 =========

build.gradle

@@ -46,7 +46,9 @@ dependencies {
 }
 
 test {
-    testLogging.showStandardStreams = true
+    if (System.env.CI == 'true') {
+        testLogging.showStandardStreams = true
+    }
 }
 
 jar {

src/main/groovy/com/github/jengelman/gradle/plugins/shadow/tasks/ShadowJar.groovy

@@ -7,8 +7,17 @@ import com.github.jengelman.gradle.plugins.shadow.relocation.SimpleRelocator
 import com.github.jengelman.gradle.plugins.shadow.transformers.AppendingTransformer
 import com.github.jengelman.gradle.plugins.shadow.transformers.ServiceFileTransformer
 import com.github.jengelman.gradle.plugins.shadow.transformers.Transformer
+import org.apache.commons.io.FilenameUtils
+import org.gradle.api.file.FileCollection
+import org.gradle.api.file.FileTree
+import org.gradle.api.file.FileTreeElement
 import org.gradle.api.internal.DocumentationRegistry
 import org.gradle.api.internal.file.copy.CopyAction
+import org.gradle.api.specs.Spec
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.InputFiles
+import org.gradle.api.tasks.Optional
+import org.gradle.api.tasks.SkipWhenEmpty
 import org.gradle.api.tasks.TaskAction
 import org.gradle.api.tasks.bundling.Jar
 import org.gradle.api.tasks.util.PatternSet
@@ -40,6 +49,26 @@ class ShadowJar extends Jar {
         logger.info(shadowStats.toString())
     }
 
+    @Override
+    @InputFiles @SkipWhenEmpty @Optional
+    // SHADOW-54 Need to remove filtered dependencies from inputs list
+    public FileCollection getSource() {
+        super.source - excludedDependencies
+    }
+
+    /**
+     * Gets a list of dependency files that are being excluded
+     * @return
+     */
+    protected FileCollection getExcludedDependencies() {
+        def allDependencies = super.source.filter {
+            def ext = FilenameUtils.getExtension(it.name)
+            return ext == 'zip' || ext == 'jar'
+        }.asFileTree
+        def includedDependencies = allDependencies.matching(dependencyFilter.patternSet)
+        return allDependencies - includedDependencies
+    }
+
     /**
      * Configure inclusion/exclusion of module & project dependencies into uber jar
      * @param c

src/test/groovy/com/github/jengelman/gradle/plugins/shadow/FilteringSpec.groovy

@@ -4,6 +4,7 @@ import com.github.jengelman.gradle.plugins.shadow.util.AppendableMavenFileReposi
 import com.github.jengelman.gradle.plugins.shadow.util.PluginSpecification
 import org.gradle.testkit.functional.ExecutionResult
 import spock.lang.Ignore
+import spock.lang.Issue
 
 class FilteringSpec extends PluginSpecification {
 
@@ -108,6 +109,61 @@ class FilteringSpec extends PluginSpecification {
         doesNotContain(output, ['d.properties'])
     }
 
+    @Issue("SHADOW-54")
+    def "dependency exclusions affect UP-TO-DATE check"() {
+        given:
+        repo.module('shadow', 'c', '1.0')
+                .insertFile('c.properties', 'c')
+                .publish()
+        repo.module('shadow', 'd', '1.0')
+                .insertFile('d.properties', 'd')
+                .dependsOn('c')
+                .publish()
+
+        buildFile << '''
+            |dependencies {
+            |   compile 'shadow:d:1.0'
+            |}
+            |
+            |shadowJar {
+            |   dependencies {
+            |      exclude(dependency('shadow:d:1.0'))
+            |   }
+            |}
+        '''.stripMargin()
+
+        when:
+        runner.arguments << 'shadowJar'
+        ExecutionResult result = runner.run()
+
+        then:
+        success(result)
+
+        and:
+        contains(output, ['a.properties', 'a2.properties', 'b.properties', 'c.properties'])
+
+        and:
+        doesNotContain(output, ['d.properties'])
+
+        when: 'Update build file shadowJar dependency exclusion'
+        buildFile.text = buildFile.text.replace('exclude(dependency(\'shadow:d:1.0\'))',
+                                                'exclude(dependency(\'shadow:c:1.0\'))')
+
+        result = runner.run()
+
+        then:
+        success(result)
+
+        and:
+        assert !taskUpToDate(result, 'shadowJar')
+
+        and:
+        contains(output, ['a.properties', 'a2.properties', 'b.properties', 'd.properties'])
+
+        and:
+        doesNotContain(output, ['c.properties'])
+    }
+
     def "include dependency, excluding all others"() {
         given:
         repo.module('shadow', 'c', '1.0')

src/test/groovy/com/github/jengelman/gradle/plugins/shadow/util/PluginSpecification.groovy

@@ -83,6 +83,10 @@ class PluginSpecification extends Specification {
         assert result.standardError, 'Gradle build succeeded'
     }
 
+    boolean taskUpToDate(ExecutionResult result, String taskName) {
+        result.standardOutput.find(/:${taskName}(.*)/).trim().contains('UP-TO-DATE')
+    }
+
     protected getOutput() {
         file('build/libs/shadow.jar')
     }