Optimize 24-bit and 32-bit and/or/xor operations

src/crt/and.src

@@ -0,0 +1,63 @@
+	assume	adl=1
+
+	section	.text
+	public	__land
+
+if PREFER_OS_CRT
+
+__land := 0001A4h
+
+else
+
+__land:
+; CC: 28*r(PC)+11*r(SPL)+10*w(SPL)+1
+	push	af
+	and	a, e
+	ld	e, a
+;	jr	__iand.hijack_land
+	virtual
+		ld	a, 0
+		load .ld_a: byte from $$
+	end virtual
+	db	.ld_a	; push af -> ld a,*
+	require	__iand
+
+end if
+
+	section .text
+	public	__iand
+
+if PREFER_OS_CRT
+
+__iand := 000134h
+
+else
+
+__iand:
+; CC: 24*r(PC)+11*r(SPL)+10*w(SPL)+1
+	push	af
+	private	__iand.hijack_land
+.hijack_land:
+	push	hl
+	scf
+	sbc	hl, hl
+	add	hl, sp
+	push	bc
+	ld	a, (hl)
+	inc	hl
+	ld	sp, hl
+	inc	hl
+	inc	hl
+	and	a, (hl)
+	ld	(hl), a
+	pop	hl
+	ld	a, h
+	and	a, b
+	ld	h, a
+	ld	a, l
+	and	a, c
+	ld	l, a
+	pop	af
+	ret
+
+end if

src/crt/and_fast.src

@@ -0,0 +1,40 @@
+	assume	adl=1
+
+	section	.text
+	public	__land_fast
+__land_fast:
+; CC: 24*r(PC)+8*r(SPL)+7*w(SPL)+1
+	and	a, e
+	ld	e, a
+	require	__iand_fast
+
+	section	.text
+	public	__iand_fast
+__iand_fast:
+; CC: 22*r(PC)+8*r(SPL)+7*w(SPL)+1
+	push	hl
+	scf
+	sbc	hl, hl
+	add	hl, sp
+	push	bc
+	ld	a, (hl)
+	inc	hl
+	ld	sp, hl
+	inc	hl
+	inc	hl
+	and	a, (hl)
+	ld	(hl), a
+	pop	hl
+	require	__sand_fast
+
+	section	.text
+	public	__sand_fast
+__sand_fast:
+; CC: 8*r(PC)+3*r(SPL)+1
+	ld	a, h
+	and	a, b
+	ld	h, a
+	ld	a, l
+	and	a, c
+	ld	l, a
+	ret