feat(azure): create azure monitor workspace

.azure/infrastructure/main.bicep

@@ -125,6 +125,18 @@ module appInsights '../modules/applicationInsights/create.bicep' = {
   }
 }
 
+module monitorWorkspace '../modules/monitor-workspace/main.bicep' = {
+  scope: resourceGroup
+  name: 'monitorWorkspace'
+  params: {
+    namePrefix: namePrefix
+    location: location
+    subnetId: vnet.outputs.monitorSubnetId
+    vnetId: vnet.outputs.virtualNetworkId
+    tags: tags
+  }
+}
+
 module apimAvailabilityTest '../modules/applicationInsights/availabilityTest.bicep' = {
   scope: resourceGroup
   name: 'apimAvailabilityTest'

.azure/modules/monitor-workspace/main.bicep

@@ -0,0 +1,75 @@
+@description('The prefix used for naming resources to ensure unique names')
+param namePrefix string
+
+@description('The location where the resources will be deployed')
+param location string
+
+@description('The ID of the subnet for the Private Link')
+param subnetId string
+
+@description('Tags to apply to resources')
+param tags object
+
+@description('The ID of the virtual network for the private DNS zone')
+param vnetId string
+
+resource monitorWorkspace 'Microsoft.Monitor/accounts@2023-04-03' = {
+  name: '${namePrefix}-monitor'
+  location: location
+  properties: {
+    publicNetworkAccess: 'Disabled'
+  }
+  tags: tags
+}
+
+// private endpoint name max characters is 80
+var monitorPrivateEndpointName = '${namePrefix}-monitor-pe'
+
+resource monitorPrivateEndpoint 'Microsoft.Network/privateEndpoints@2024-03-01' = {
+  name: monitorPrivateEndpointName
+  location: location
+  properties: {
+    privateLinkServiceConnections: [
+      {
+        name: monitorPrivateEndpointName
+        properties: {
+          privateLinkServiceId: monitorWorkspace.id
+          groupIds: [
+            'prometheusMetrics'
+          ]
+        }
+      }
+    ]
+    customNetworkInterfaceName: '${namePrefix}-monitor-pe-nic'
+    subnet: {
+      id: subnetId
+    }
+  }
+  tags: tags
+}
+
+module privateDnsZone '../privateDnsZone/main.bicep' = {
+  name: '${namePrefix}-monitor-pdz'
+  params: {
+    namePrefix: namePrefix
+    defaultDomain: 'privatelink.${location}.prometheus.monitor.azure.com'
+    vnetId: vnetId
+    tags: tags
+  }
+}
+
+module privateDnsZoneGroup '../privateDnsZoneGroup/main.bicep' = {
+  name: '${namePrefix}-monitor-privateDnsZoneGroup'
+  dependsOn: [
+    privateDnsZone
+  ]
+  params: {
+    name: 'default'
+    dnsZoneGroupName: 'privatelink-${location}-prometheus-monitor-azure-com'
+    dnsZoneId: privateDnsZone.outputs.id
+    privateEndpointName: monitorPrivateEndpoint.name
+  }
+}
+
+output monitorWorkspaceId string = monitorWorkspace.id
+output monitorWorkspaceName string = monitorWorkspace.name

.azure/modules/vnet/main.bicep

@@ -263,6 +263,44 @@ resource serviceBusNSG 'Microsoft.Network/networkSecurityGroups@2024-03-01' = {
   tags: tags
 }
 
+resource monitorNSG 'Microsoft.Network/networkSecurityGroups@2024-03-01' = {
+  name: '${namePrefix}-monitor-nsg'
+  location: location
+  properties: {
+    securityRules: [
+      {
+        name: 'AllowAzureMonitorInbound'
+        type: 'Microsoft.Network/networkSecurityGroups/securityRules'
+        properties: {
+          protocol: 'Tcp'
+          sourcePortRange: '*'
+          destinationPortRanges: ['443']
+          sourceAddressPrefix: 'AzureMonitor'
+          destinationAddressPrefix: '*'
+          access: 'Allow'
+          priority: 120
+          direction: 'Inbound'
+        }
+      }
+      {
+        name: 'AllowAzureMonitorOutbound'
+        type: 'Microsoft.Network/networkSecurityGroups/securityRules'
+        properties: {
+          protocol: 'Tcp'
+          sourcePortRange: '*'
+          destinationPortRanges: ['443']
+          sourceAddressPrefix: '*'
+          destinationAddressPrefix: 'AzureMonitor'
+          access: 'Allow'
+          priority: 120
+          direction: 'Outbound'
+        }
+      }
+    ]
+  }
+  tags: tags
+}
+
 resource virtualNetwork 'Microsoft.Network/virtualNetworks@2024-03-01' = {
   name: '${namePrefix}-vnet'
   location: location
@@ -334,6 +372,17 @@ resource virtualNetwork 'Microsoft.Network/virtualNetworks@2024-03-01' = {
           }
         }
       }
+      {
+        name: 'monitorSubnet'
+        properties: {
+          addressPrefix: '10.0.6.0/24'
+          networkSecurityGroup: {
+            id: monitorNSG.id
+          }
+          privateEndpointNetworkPolicies: 'Disabled'
+          privateLinkServiceNetworkPolicies: 'Enabled'
+        }
+      }
     ]
   }
   tags: tags
@@ -362,3 +411,8 @@ output redisSubnetId string = resourceId(
   virtualNetwork.name,
   'redisSubnet'
 )
+output monitorSubnetId string = resourceId(
+  'Microsoft.Network/virtualNetworks/subnets',
+  virtualNetwork.name,
+  'monitorSubnet'
+)