build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

configure(allprojects) { project ->
    buildscript {
        repositories {
            jcenter()
            mavenCentral()
            maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
            mavenLocal()
        }
    }
}

project.ext.preDexLibs = !project.hasProperty('disablePreDex')

subprojects {
    group = 'hu.supercluster.gameoflife'

    ext.androidBuildToolsVersion    = '23.0.2';
    ext.androidMinSdkVersion        = 15;
    ext.androidCompileSdkVersion    = 23;
    ext.androidTargetSdkVersion     = 23;

    ext.androidAnnotationsVersion = '3.3.2';
    ext.androidAnnotationsAPIVersion = '3.3.2';

    repositories {
        mavenCentral()
        maven { url 'https://oss.sonatype.org/content/repositories/snapshots/' }
        maven { url "file://${System.getenv("ANDROID_HOME")}/extras/android/m2repository" }
        mavenLocal()
    }

    // Improve build server performance by allowing disabling of pre-dexing
    // (see http://tools.android.com/tech-docs/new-build-system/tips#TOC-Improving-Build-Server-performance.)
    project.plugins.whenPluginAdded { plugin ->
        if ("com.android.build.gradle.AppPlugin".equals(plugin.class.name)) {
            project.android.dexOptions.preDexLibraries = rootProject.ext.preDexLibs
        } else if ("com.android.build.gradle.LibraryPlugin".equals(plugin.class.name)) {
            project.android.dexOptions.preDexLibraries = rootProject.ext.preDexLibs
        }
    }
}

apply plugin: 'java' // ensure clean is also triggered for root build folder
apply plugin: 'build-dashboard'

buildDashboard {
    reports.html.destination = "build/"
}

test.reports.html.enabled = false     // just clean up dashboard from not generated reports
test.reports.junitXml.enabled = false // just clean up dashboard from not generated reports