monkey_pants.socool

import ./monkey_pants_man.socool

{ f: 311.127, l: 1, g: 1/5, p: 0 }

drums = {
    O[
        (3/2, 1, 1/2, -1/3),
        (3/2, 0, 1/2, 1/3),
        (1, 1, 1, -1/2),
        (1, 0, 1, 1/2),
        (1/2, 2, 1/3, 1/4),
        (1/2, 0, 1/3, -1/4),
        (1/4, 1, 1/3, 1),
        (1/4, 0, 1/3, -1),
    ]
    | Overlay [
        Seq [
            Fm 1/2, Fm 0, Fm 0
        ] | Lm 1/3 | Gm 1/5,
        Seq [
           O[
                (3/2, 0, 1, -1/2),
                (11/8, 0, 1, 1/2),
                (25/24, 0, 1, 0),
            ] | Lm 1/5,
            O[
                (1/2, 0, 1, -1/2),
                (1/2, 0, 1, 1/2),
                (1/2, 0, 1, 0),
            ], 
            Fm 0, Fm 0, 
        ] | Lm 1/8, 
        Fm 0
    ]
    | Seq [
        Lm 2 | Fm 1/4 | Overlay [Fm 1 | Gm 1/2, Fm 2],
        Fm 3/4, Fm 1, 
        Seq [Fm 2, Fm 1/2] | Lm 1/2, 
        -- Fm 1/4, Fm 1, 
        -- Fm 1/4, Fm 1/4, 
        Seq [Fm 1, Fm 0, Fm 2 | Pa -1/6, Fm 0] | Lm 1/4,
        Seq [Fm 1/2, Fm 0, Fm 3 | Pa 1/6, Fm 0] | Lm 1/4,
        Seq [Fm 3/2 | Pa -1/2, Fm 4/3 | Pa 1/2, Fm 5/4] | Lm 1/3,
   ] | Lm 1/5
}

thing1 = {
    Seq [
        drums | Repeat 2 | Fm 9/8,
        monkey_pants_man.thing1,
    ]
}

thing2 = {
    O[
        (1, -3, 1, 1),
        (1, 0, 1, -1),
    ]
    | Seq [
        O[
            (7/6, 0, 1/8, 1),
            (7/6, 0, 1/8, -1),
            (7/8, -3, 1/4, 1),
            (7/8, 0, 1/4, -1),
            (3/4, -3, 1, 1),
            (3/4, 0, 1, -1),
        ],
        O[
            (7/4, -3, 1/16, 1),
            (7/4, 0, 1/16, -1),
            (4/5, -6, 1, 1/3),
            (4/5, 0, 1, -1/3),
            (2/3, -3, 1/4, 1/3),
            (2/3, 0, 1/4, -1/3),
        ],
        O[
            (7/4, -9, 1/16, 1),
            (7/4, 0, 1/16, -1),
            (4/5, -6, 1, 1/9),
            (4/5, 0, 1, -1/9),
            (3/4, -9, 1/4, 1/9),
            (3/4, 0, 1/4, -1/9),
        ]
    ]
    | FitLength thing1
}

thing3 = {
    O[
        (2, -3, 1, 1),
        (2, 0, 1, -1),
        (1, -3, 1, 1),
        (1, 0, 1, -1),
    ]
    | Overlay [
        Seq [
            Fm 0 | Lm 4, 
            Fm 3/2 | Lm 2, Fm 3/2, Fm 8/5, 
            Fm 3/2, Fm 4/3, Fm 7/6, Fm 1
        ] | Fa -1 | Pa -1/4,
        Seq [
            Fm 0 | Lm 4, 
            Fm 1 | Lm 2, Fm 9/8, Fm 1, 
            Fm 7/6, Fm 9/8, Fm 1, Fm 3/4
        ] | Pa 1/4
    ]
    | FitLength thing1
}

main = {
    Overlay [
        thing1
        | Overlay [Sine, Square | Gm 1/20 | Fm 1/4],
        thing2,
        thing3 | Gm 1/3
    ]
    -- | Repeat 5
    -- | Seq [Fm 1, Fm 7/8 | Lm 8/7]
    | Repeat 4
    | Lm 11/10
    | Fm 4/3
    | Repeat 8
}