build.gradle

/*
 * Copyright (c) 2015 Intel Corporation
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

version = '0.1.1'

buildscript {
    ext {
        springBootVersion = '1.3.3.RELEASE'
    }
    repositories {
        mavenCentral()
        maven {
            url 'http://repo.spring.io/release'
            url 'https://plugins.gradle.org/m2/'
        }
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
        classpath("io.spring.gradle:dependency-management-plugin:0.5.6.RELEASE")
        classpath 'gradle.plugin.nl.javadude.gradle.plugins:license-gradle-plugin:0.12.1'
    }
}

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'spring-boot'
apply plugin: 'io.spring.dependency-management'
apply plugin: 'application'
apply plugin: 'com.github.hierynomus.license'

jar {
    baseName = 'hbase-rest'
    version = project.version
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenLocal()
    mavenCentral()
    maven {
        url 'http://repo.spring.io/release'
    }
    maven {
        url 'http://repo.spring.io/libs-release'
    }
}

configurations {
    all*.exclude group: '', module: 'servlet-api'
    all*.exclude group: 'org.slf4j', module: 'log4j-over-slf4j'
    all*.exclude group: 'org.slf4j', module: 'slf4j-log4j12'
}

dependencies {
    compile("org.springframework.boot:spring-boot-starter-web")
    compile("org.springframework.boot:spring-boot-devtools")

    compile("org.trustedanalytics:hadoop-utils:0.6.11")

    compile("io.springfox:springfox-swagger-ui:2.4.0") {
        exclude group: 'com.google.guava', module: 'guava'
    }
    compile("io.springfox:springfox-swagger2:2.4.0") {
        exclude group: 'com.google.guava', module: 'guava'
    }

    testCompile("org.springframework.boot:spring-boot-starter-test")
}

eclipse {
    classpath {
        containers.remove('org.eclipse.jdt.launching.JRE_CONTAINER')
        containers 'org.eclipse.jdt.launching.JRE_CONTAINER/org.eclipse.jdt.internal.debug.ui.launcher.StandardVMType/JavaSE-1.8'
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.8'
}

task('info') << {
    println jar.baseName
    println jar.version
}

springBoot {
    mainClass = "org.trustedanalytics.examples.hbase.Main"
}

license {
    header rootProject.file('license/license_header.txt')
    ext.year = Calendar.getInstance().get(Calendar.YEAR)
    strictCheck true
}

task copyApplicationManifest(type: Copy) {
    from "src/cloudfoundry"
    include "**/*.yml"
    into "."

    filter org.apache.tools.ant.filters.ReplaceTokens, tokens: [
            version: project.version
    ]
}

assemble.dependsOn copyApplicationManifest