-
-
Notifications
You must be signed in to change notification settings - Fork 139
/
fireplace.vim
2591 lines (2332 loc) · 79.2 KB
/
fireplace.vim
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
" Location: autoload/fireplace.vim
" Author: Tim Pope <http://tpo.pe/>
if exists('g:autoloaded_fireplace')
finish
endif
let g:autoloaded_fireplace = 1
" Section: Utilities
function! s:map(mode, lhs, rhs, ...) abort
if get(g:, 'fireplace_no_maps')
return
endif
let flags = (a:0 ? a:1 : '') . (a:rhs =~# '^<Plug>' ? '' : '<script>')
let head = a:lhs
let tail = ''
let keys = get(g:, a:mode.'remap', {})
if type(keys) != type({})
return
endif
while !empty(head)
if has_key(keys, head)
let head = keys[head]
if empty(head)
return
endif
break
endif
let tail = matchstr(head, '<[^<>]*>$\|.$') . tail
let head = substitute(head, '<[^<>]*>$\|.$', '', '')
endwhile
if flags !~# '<unique>' || empty(mapcheck(head.tail, a:mode))
exe a:mode.'map <buffer>' flags head.tail a:rhs
endif
endfunction
function! s:pr(obj) abort
if type(a:obj) == v:t_string
return a:obj
elseif type(a:obj) == v:t_list
return '(' . join(map(copy(a:obj), 's:pr(v:val)'), ' ') . ')'
elseif type(a:obj) == v:t_dict
return '{' . join(map(keys(a:obj), 's:pr(v:val) . " " . s:pr(a:obj[v:val])'), ', ') . '}'
else
return string(a:obj)
endif
endfunction
function! s:cword() abort
let isk = &l:iskeyword
try
setlocal iskeyword+=',#,%,&,/,.
return substitute(expand('<cword>'), "^#*''*", '', '')
finally
let &l:iskeyword = isk
endtry
endfunction
function! s:zipfile_url(archive, path) abort
if get(g:, 'loaded_zipPlugin')[1:-1] > 31
return 'zipfile://' . a:archive . '::' . a:path
else
return 'zipfile:' . a:archive . '::' . a:path
endif
endfunction
" Section: Escaping
function! s:str(string) abort
return '"' . escape(a:string, '"\') . '"'
endfunction
function! s:qsym(symbol) abort
if a:symbol =~# '^[[:alnum:]?*!+/=<>.:-]\+$'
return "'".a:symbol
else
return '(symbol '.s:str(a:symbol).')'
endif
endfunction
function! s:to_ns(path) abort
return tr(substitute(a:path, '\.\w\+$', '', ''), '\/_', '..-')
endfunction
" Section: Completion
let s:jar_contents = {}
function! fireplace#jar_contents(path) abort
if !exists('s:pythonx')
let s:pythonx = 0
if has('pythonx')
try
pythonx import zipfile
let s:pythonx = 1
catch /^Vim(pythonx):Traceback/
endtry
endif
endif
if !exists('s:zipinfo')
if executable('zipinfo')
let s:zipinfo = 'zipinfo -1 '
elseif executable('jar')
let s:zipinfo = 'jar tf '
elseif executable('python')
let s:zipinfo = 'python -c '.shellescape('import zipfile, sys; print chr(10).join(zipfile.ZipFile(sys.argv[1]).namelist())').' '
elseif executable('python3')
let s:zipinfo = 'python3 -c '.shellescape('import zipfile, sys; print chr(10).join(zipfile.ZipFile(sys.argv[1]).namelist())').' '
else
let s:zipinfo = ''
endif
endif
if !has_key(s:jar_contents, a:path)
if !filereadable(a:path)
let s:jar_contents[a:path] = []
elseif s:pythonx
try
let s:jar_contents[a:path] = pyxeval('zipfile.ZipFile(' . json_encode(a:path) . ').namelist()')
catch /^Vim(let):Traceback/
let s:jar_contents[a:path] = []
endtry
elseif !empty(s:zipinfo)
let s:jar_contents[a:path] = split(system(s:zipinfo . shellescape(a:path)), "\n")
if v:shell_error
let s:jar_contents[a:path] = []
endif
endif
endif
return copy(get(s:jar_contents, a:path, []))
endfunction
function! fireplace#EvalComplete(A, L, P, ...) abort
let prefix = matchstr(a:A, '\%(.* \|^\)\%(#\=[\[{('']\)*')
let keyword = strpart(a:A, strlen(prefix))
try
return sort(map(fireplace#omnicomplete(a:0 ? a:1() : fireplace#client(), keyword, ''), 'prefix . v:val.word'))
catch /^Fireplace:/
return []
endtry
endfunction
function! fireplace#eval_complete(A, L, P) abort
return fireplace#EvalComplete(a:A, a:L, a:P)
endfunction
function! fireplace#CljEvalComplete(A, L, P) abort
return fireplace#EvalComplete(a:A, a:L, a:P, function('fireplace#clj'))
endfunction
function! fireplace#CljsEvalComplete(A, L, P) abort
return fireplace#EvalComplete(a:A, a:L, a:P, function('fireplace#cljs'))
endfunction
function! fireplace#NsComplete(A, L, P) abort
let matches = []
for dir in fireplace#path()
if dir =~# '\.jar$'
let files = filter(fireplace#jar_contents(dir), 'v:val =~# "\\.clj$"')
else
let files = split(glob(dir."/**/*.clj", 1), "\n")
call map(files, 'v:val[strlen(dir)+1 : -1]')
endif
let matches += files
endfor
return filter(map(matches, 's:to_ns(v:val)'), 'a:A ==# "" || a:A ==# v:val[0 : strlen(a:A)-1]')
endfunction
function! fireplace#ns_complete(A, L, P) abort
return fireplace#NsComplete(a:A, a:L, a:P)
endfunction
let s:short_types = {
\ 'function': 'f',
\ 'macro': 'm',
\ 'var': 'v',
\ 'special-form': 's',
\ 'class': 'c',
\ 'keyword': 'k',
\ 'local': 'l',
\ 'namespace': 'n',
\ 'field': 'i',
\ 'method': 'f',
\ 'static-field': 'i',
\ 'static-method': 'f',
\ 'resource': 'r'
\ }
function! s:candidate(val) abort
let type = get(a:val, 'type', '')
let arglists = get(a:val, 'arglists', [])
return {
\ 'word': get(a:val, 'candidate'),
\ 'kind': get(s:short_types, type, type),
\ 'info': get(a:val, 'doc', ''),
\ 'menu': empty(arglists) ? '' : '(' . join(arglists, ' ') . ')'
\ }
endfunction
function! s:get_complete_context() abort
" Find toplevel form
" If cursor is on start parenthesis we don't want to find the form
" If cursor is on end parenthesis we want to find the form
let [line1, col1] = searchpairpos('(', '', ')', 'Wrnb', g:fireplace#skip)
let [line2, col2] = searchpairpos('(', '', ')', 'Wrnc', g:fireplace#skip)
if (line1 == 0 && col1 == 0) || (line2 == 0 && col2 == 0)
return ""
endif
if line1 == line2
let expr = getline(line1)[col1-1 : col2-1]
else
let expr = getline(line1)[col1-1 : -1] . ' '
\ . join(getline(line1+1, line2-1), ' ')
\ . getline(line2)[0 : col2-1]
endif
" Calculate the position of cursor inside the expr
if line1 == line('.')
let p = col('.') - col1
else
let p = strlen(getline(line1)[col1-1 : -1])
\ + strlen(join(getline(line1 + 1, line('.') - 1), ' '))
\ + col('.')
endif
return strpart(expr, 0, p) . ' __prefix__ ' . strpart(expr, p)
endfunction
function! s:complete_extract(msg) abort
let trans = '{"word": (v:val =~# ''[./]'' ? "" : matchstr(a:base, ''^.\+/'')) . v:val}'
let value = get(a:msg, 'value', get(a:msg, 'completions'))
if type(value) == type([])
if type(get(value, 0)) == type({})
return map(value, 's:candidate(v:val)')
elseif type(get(value, 0)) == type([])
return map(value[0], trans)
elseif type(get(value, 0)) == type('')
return map(value, trans)
else
return []
endif
endif
endfunction
function! s:complete_add(msg) abort
for entry in s:complete_extract(a:msg)
call complete_add(entry)
endfor
endfunction
function! s:complete_delegate(queue, callback, msg) abort
call extend(a:queue, s:complete_extract(a:msg))
if index(get(a:msg, 'status', []), 'done') !=# -1
call a:callback(a:queue)
endif
endfunction
function! fireplace#omnicomplete(findstart, base, ...) abort
if a:findstart is# 1 || a:findstart is# '1'
let line = strpart(getline('.'), 0, col('.') - 1)
return col('.') - strlen(matchstr(line, '\k\+$')) - 1
else
let err = s:op_missing_error('complete', 'cider-nrepl')
if len(err)
throw err
endif
let request = {
\ 'op': 'complete',
\ 'symbol': a:base,
\ 'ns': type(a:findstart) == v:t_dict ? v:null : v:true,
\ 'extra-metadata': ['arglists', 'doc'],
\ 'context': a:0 ? a:1 : s:get_complete_context()
\ }
if type(a:findstart) == v:t_func
return fireplace#message(request, function('s:complete_delegate', [[], a:findstart]))
elseif type(a:findstart) == v:t_dict
return s:complete_extract(a:findstart.Message(request, v:t_dict))
endif
let id = fireplace#message(request, function('s:complete_add')).id
while !fireplace#client().done(id)
call complete_check()
sleep 1m
endwhile
return []
endif
endfunction
" Section: REPL client
function! s:NormalizeNs(client, payload) abort
if get(a:payload, 'ns') is# v:true
let a:payload.ns = a:client.BufferNs()
elseif get(a:payload, 'ns') is# v:false
let a:payload.ns = a:client.UserNs()
elseif type(get(a:payload, 'ns', '')) == v:t_number
let a:payload.ns = a:client.BufferNs(a:payload.ns)
endif
if empty(get(a:payload, 'ns', 1))
call remove(a:payload, 'ns')
endif
return a:payload
endfunction
let s:clj = {}
function! s:CljBufferNs(...) dict abort
if call('s:bufext', a:0 ? a:000 : get(self, 'args', [])) =~# '^clj[cx]\=$'
let ns = call('fireplace#ns', a:000)
return ns =~# '^\%(cljs\.\)\=user$' ? '' : ns
else
return ''
endif
endfunction
function! s:CljExt() dict abort
return 'clj'
endfunction
function! s:CljReplNs() dict abort
return 'clojure.repl'
endfunction
function! s:CljUserNs() dict abort
return 'user'
endfunction
let s:clj = {
\ 'BufferNs': function('s:CljBufferNs'),
\ 'Ext': function('s:CljExt'),
\ 'ReplNs': function('s:CljReplNs'),
\ 'UserNs': function('s:CljUserNs')}
function! s:CljsBufferNs(...) dict abort
if call('s:bufext', a:0 ? a:000 : get(self, 'args', [])) =~# '^clj[scx]$'
let ns = call('fireplace#ns', a:000)
return ns =~# '^\%(cljs\.\)\=user$' ? '' : ns
else
return ''
endif
endfunction
function! s:CljsExt() dict abort
return 'cljs'
endfunction
function! s:CljsReplNs() dict abort
return 'cljs.repl'
endfunction
function! s:CljsUserNs() dict abort
return 'cljs.user'
endfunction
let s:cljs = {
\ 'BufferNs': function('s:CljsBufferNs'),
\ 'Ext': function('s:CljsExt'),
\ 'ReplNs': function('s:CljsReplNs'),
\ 'UserNs': function('s:CljsUserNs')}
function! s:EvalQuery(...) dict abort
let opts = {'session': v:false}
for l:Arg in a:000
if type(Arg) == v:t_string
let opts.code = Arg
elseif type(Arg) == v:t_dict && type(get(Arg, 'Session')) ==# v:t_func
let client = Arg
elseif type(Arg) == v:t_dict
call extend(opts, Arg)
elseif type(Arg) == v:t_func
let l:Callback = Arg
endif
endfor
let opts.code = printf(g:fireplace#reader, get(opts, 'code', 'null'))
if exists('Callback')
return self.Eval(opts, { m -> len(get(m, 'value', '')) ? Callback(eval(m.value)) : 0 })
endif
let response = self.Eval(opts)
call s:output_response(response)
if get(response, 'ex', '') !=# ''
let err = 'Clojure: '.response.ex
elseif has_key(response, 'value')
return empty(response.value) ? '' : eval(response.value[-1])
else
let err = 'fireplace.vim: No value in '.string(response)
endif
throw err
endfunction
let s:common = {'Query': function('s:EvalQuery')}
let s:repl = extend(extend({"requires": {}}, s:clj), s:common)
let s:repl.user_ns = s:repl.UserNs
if !exists('s:repls')
let s:repls = []
let s:repl_paths = {}
let s:repl_portfiles = {}
endif
function! s:repl.Client() dict abort
return self
endfunction
function! s:repl.Session() dict abort
return self.session
endfunction
function! s:repl.Path() dict abort
return self.transport._path
endfunction
let s:repl.path = s:repl.Path
function! s:repl.message(payload, ...) dict abort
call s:NormalizeNs(self, a:payload)
if has_key(a:payload, 'ns') && a:payload.ns !=# self.UserNs()
let ignored_error = self.Preload(a:payload.ns)
endif
let session = self.Session()
return call(session.message, [a:payload] + a:000, session)
endfunction
let s:repl.Message = s:repl.message
function! s:repl.done(id) dict abort
if type(a:id) == v:t_string
return !has_key(self.transport.requests, a:id)
elseif type(a:id) == v:t_dict
return index(get(a:id, 'status', []), 'done') >= 0
else
return -1
endif
endfunction
let s:repl.Done = s:repl.done
function! s:repl.preload(lib) dict abort
if !empty(a:lib) && a:lib !=# self.UserNs() && !get(self.requires, a:lib)
let reload = has_key(self.requires, a:lib) ? ' :reload' : ''
let self.requires[a:lib] = 0
if self.Ext() ==# 'clj'
let qsym = s:qsym(a:lib)
let expr = '(clojure.core/when-not (clojure.core/find-ns '.qsym.') (try'
\ . ' ((or (clojure.core/resolve ''clojure.core/load-one) (fn [x _ _] (clojure.core/require x))) '.qsym.' true true)'
\ . ' (catch Exception e (clojure.core/when-not (clojure.core/find-ns '.qsym.') (throw e)))))'
else
let expr = '(ns '.self.UserNs().' (:require '.a:lib.reload.'))'
endif
let result = self.Message({'op': 'eval', 'code': expr, 'ns': self.UserNs(), 'session': ''}, v:t_dict)
let self.requires[a:lib] = !has_key(result, 'ex')
if has_key(result, 'ex')
return result
endif
endif
return {}
endfunction
let s:repl.Preload = s:repl.preload
function! s:repl.Eval(...) dict abort
let options = {'op': 'eval', 'code': ''}
for l:Arg in a:000
if type(Arg) == v:t_string
let options.code = Arg
elseif type(Arg) == v:t_dict
call extend(options, Arg)
elseif type(Arg) == v:t_func
let l:Callback = Arg
endif
endfor
let options = s:NormalizeNs(self, options)
if has_key(options, 'ns') && options.ns !=# self.UserNs()
let error = self.Preload(options.ns)
if !empty(error)
return error
endif
endif
let response = self.Message(options, exists('l:Callback') ? Callback : v:t_dict)
if index(get(response, 'status', []), 'namespace-not-found') < 0
return response
endif
throw 'Fireplace: namespace not found: ' . get(options, 'ns', '?')
endfunction
let s:repl.eval = s:repl.Eval
function! s:repl.HasOp(op) abort
return self.transport.HasOp(a:op)
endfunction
let s:piggieback = extend(copy(s:repl), s:cljs)
let s:piggieback.user_ns = s:piggieback.UserNs
function! s:piggieback.Piggieback(arg, ...) abort
if a:0 && a:1
if len(self.sessions)
let session = remove(self.sessions, 0)
call session.Message({'op': 'eval', 'code': ':cljs/quit'}, v:t_list)
call session.Close()
endif
return {}
endif
let session = self.clj_session.Clone()
if empty(a:arg)
let arg = get(self, 'default', '')
elseif a:arg =~# '^\d\{1,5}$'
if len(fireplace#findresource('weasel/repl/websocket.clj', self.Path()))
let arg = '(weasel.repl.websocket/repl-env :port ' . a:arg . ')'
else
let arg = '(cljs.repl.browser/repl-env :port ' . a:arg .')'
endif
else
let arg = a:arg
endif
if empty(arg)
throw 'Fireplace: no default ClojureScript REPL'
endif
let replns = matchstr(arg, '^\%((\w\+\.piggieback/cljs-repl \)\=(\=\zs[a-z][a-z0-9-]\+\.[a-z0-9.-]\+\ze/')
if len(replns)
call session.Message({'op': 'eval', 'code': "(require '" . replns . ")"}, v:t_dict)
endif
if arg =~# '^\S*repl-env\>' || arg !~# '('
if len(fireplace#findresource('cemerick/piggieback.clj', self.Path())) && !len(fireplace#findresource('cider/piggieback.clj', self.Path()))
let arg = '(cemerick.piggieback/cljs-repl ' . arg . ')'
else
let arg = '(cider.piggieback/cljs-repl ' . arg . ')'
endif
endif
let response = session.Message({'op': 'eval', 'code': arg}, v:t_dict)
if !has_key(response, 'ex') && get(response, 'ns', 'user') ==# 'cljs.user'
call insert(self.sessions, session)
else
call session.Close()
endif
return response
endfunction
function! s:piggieback.Session() abort
if len(self.sessions)
return self.sessions[0]
endif
let response = self.Piggieback('')
if len(self.sessions)
return self.sessions[0]
endif
call s:output_response(response)
throw 'Fireplace: error starting ClojureScript REPL'
endfunction
function! s:register(session, ...) abort
call insert(s:repls, extend({'session': a:session, 'transport': a:session.transport, 'cljs_sessions': []}, deepcopy(s:repl)))
if a:0 && a:1 !=# ''
let s:repl_paths[a:1] = s:repls[0]
endif
return s:repls[0]
endfunction
function! s:unregister(transport) abort
let transport = get(a:transport, 'transport', a:transport)
let criteria = 'has_key(v:val, "transport") && v:val.transport isnot# transport'
call filter(s:repl_paths, criteria)
call filter(s:repls, criteria)
call filter(s:repl_portfiles, criteria)
endfunction
function! s:unregister_dead() abort
let criteria = 'has_key(v:val, "transport") && v:val.transport.Alive()'
call filter(s:repl_paths, criteria)
call filter(s:repls, criteria)
call filter(s:repl_portfiles, criteria)
endfunction
function! fireplace#register_port_file(portfile, ...) abort
let portfile = fnamemodify(a:portfile, ':p')
let old = get(s:repl_portfiles, portfile, {})
if has_key(old, 'time') && getftime(portfile) !=# old.time
call s:unregister(old)
let old = {}
endif
if empty(old) && getfsize(portfile) > 0
let port = matchstr(readfile(portfile, 'b', 1)[0], '\d\+')
try
let transport = fireplace#transport#connect(port)
let session = transport.Clone()
let s:repl_portfiles[portfile] = {
\ 'time': getftime(portfile),
\ 'session': session,
\ 'transport': transport}
call s:register(session, a:0 ? a:1 : '')
return session
catch /^Fireplace:/
if &verbose
echohl WarningMSG
echomsg v:exception
echohl None
endif
return {}
endtry
else
return get(old, 'transport', {})
endif
endfunction
" Section: :Connect
function! fireplace#ConnectComplete(A, L, P) abort
let proto = matchstr(a:A, '\w\+\ze://')
if proto ==# ''
let options = map(['nrepl'], 'v:val."://"')
else
let rest = matchstr(a:A, '://\zs.*')
let options = ['localhost:']
call map(options, 'proto."://".v:val')
endif
if a:A !=# ''
call filter(options, 'v:val[0 : strlen(a:A)-1] ==# a:A')
endif
return options
endfunction
function! fireplace#ConnectCommand(line1, line2, range, bang, mods, arg, args) abort
let str = get(a:args, 0, '')
if empty(str)
let str = input('Port or URL: ')
if empty(str)
return ''
endif
endif
let str = substitute(str, '^file:[\/]\{' . (has('win32') ? '3' : '2') . '\}', '', '')
if str =~# '^[%#]'
let str = expand(str)
endif
if str !~# '^\d\+$\|:\d\|:[\/][\/]' && filereadable(str)
let path = fnamemodify(str, ':p:h')
let str = readfile(str, '', 1)[0]
elseif str !~# '^\d\+$\|:\d\|:[\/][\/]' && filereadable(str . '/.nrepl-port')
let path = fnamemodify(str, ':p:h')
let str = readfile(str . '/.nrepl-port', '', 1)[0]
else
let path = fnamemodify(exists('b:java_root') ? b:java_root : getcwd(), ':~')
endif
try
let transport = fireplace#transport#connect(str)
catch /.*/
return 'echoerr '.string(v:exception)
endtry
if type(transport) !=# type({}) || empty(transport)
return ''
endif
let client = s:register(transport.Clone())
echo 'Connected to ' . transport.url
let root = len(a:args) > 1 ? expand(a:args[1]) : input('Scope connection to: ', path, 'dir')
if root !=# '' && root !=# '-'
let s:repl_paths[fnamemodify(root, ':p:s?.\zs[\/]$??')] = client
endif
return ''
endfunction
function! s:piggieback(count, arg, remove) abort
try
let response = s:Cljs().Piggieback(a:arg, a:remove)
call s:output_response(response)
return ''
catch /^Fireplace:/
return 'echoerr ' . string(v:exception)
endtry
endfunction
function! s:set_up_connect() abort
command! -buffer -bang -bar -complete=customlist,fireplace#ConnectComplete -nargs=*
\ Connect FireplaceConnect<bang> <args>
command! -buffer -bang -range=-1 -complete=customlist,fireplace#eval_complete -nargs=*
\ Piggieback exe s:piggieback(<count>, <q-args>, <bang>0)
endfunction
" Section: Java runner
if !exists('s:spawns')
let s:spawns = {}
endif
function! s:spawn_interrupt(id) abort
let message = get(s:spawns, a:id, {})
if type(get(message, 'job', '')) == v:t_number
call jobstop(message.job)
elseif type(get(message, 'job', '')) != v:t_string
call job_stop(message.job)
endif
endfunction
function! s:spawn_wait(id, ...) abort
let message = get(s:spawns, a:id, {})
let finished = v:true
if type(get(message, 'job', '')) == v:t_number
let finished = jobwait([message.job], a:0 ? a:1 : -1)[0] == -1 ? v:false : v:true
elseif type(get(message, 'job', '')) != v:t_string
let ms = 0
let max = a:0 ? a:1 : -1
while job_status(message.job) ==# 'run'
if ms == max
let finished = v:false
break
endif
let ms += 1
sleep 1m
endwhile
endif
if has_key(s:spawns, a:id)
throw 'Fireplace: race condition waiting on spawning eval?'
endif
return finished
endfunction
function! s:spawn_complete(id, name, callback) abort
let result = {'id': a:id}
let result.value = join(readfile(a:name . '.pr' , 'b'), "\n")
let result.out = join(readfile(a:name . '.out', 'b'), "\n")
let result.err = join(readfile(a:name . '.err', 'b'), "\n")
let result.ex = join(readfile(a:name . '.ex' , 'b'), "\n")
if empty(result.ex)
let result.status = ['done']
else
let result.status = ['eval-error', 'done']
endif
call filter(result, '!empty(v:val)')
call remove(s:spawns, a:id)
try
call a:callback(result)
catch
endtry
endfunction
function! s:spawn_eval(id, classpath, expr, ns, callback) abort
if a:ns !=# '' && a:ns !=# 'user'
let ns = '(require '.s:qsym(a:ns).') (in-ns '.s:qsym(a:ns).') '
else
let ns = ''
endif
let tempname = tempname()
call writefile([], tempname . '.pr', 'b')
call writefile([], tempname . '.ex', 'b')
call writefile(split('(do '.a:expr.')', "\n"), tempname . '.in', 'b')
call writefile([], tempname . '.out', 'b')
call writefile([], tempname . '.err', 'b')
let java_cmd = split(exists('$JAVA_CMD') ? $JAVA_CMD : 'java', ' ')
let command = java_cmd + ['-cp', a:classpath, 'clojure.main', '-e',
\ ' (try' .
\ ' (require ''clojure.repl ''clojure.java.javadoc) '. ns .
\ ' (spit '.s:str(tempname . '.pr').' (pr-str (eval (read-string (slurp '.s:str(tempname . '.in').')))))' .
\ ' (catch Exception e' .
\ ' (spit *err* (.toString e))' .
\ ' (spit '.s:str(tempname . '.ex').' (class e))))']
let s:spawns[a:id] = {}
if has('job')
let opts = {
\ 'out_io': 'file', 'out_name': tempname . '.out',
\ 'err_io': 'file', 'err_name': tempname . '.err',
\ 'exit_cb': { j, data -> s:spawn_complete(a:id, tempname, a:callback) }}
let s:spawns[a:id].job = job_start(command, opts)
elseif exists('*jobstart')
let opts = {
\ 'on_stdout': { j, data, type -> writefile(data, tempname . '.out', 'ab') },
\ 'on_stderr': { j, data, type -> writefile(data, tempname . '.err', 'ab') },
\ 'on_exit': { j, data, type -> s:spawn_complete(a:id, tempname, a:callback) }}
let s:spawns[a:id].job = jobstart(command, opts)
endif
return {'id': a:id}
endfunction
let s:no_repl = 'Fireplace: no live REPL connection'
let s:oneoff = extend(copy(s:clj), s:common)
let s:oneoff.user_ns = s:repl.UserNs
function! s:oneoff.Client() dict abort
return self
endfunction
function! s:oneoff.Path() dict abort
return self._path
endfunction
let s:oneoff.path = s:oneoff.Path
function! s:oneoff.Eval(...) dict abort
let options = {'op': 'eval', 'code': ''}
for l:Arg in a:000
if type(Arg) == v:t_string
let options.code = Arg
elseif type(Arg) == v:t_dict
call extend(options, Arg)
elseif type(Arg) == v:t_func
let l:Callback = Arg
endif
endfor
if !empty(get(options, 'session', 1))
throw s:no_repl
endif
let id = has_key(options, 'id') ? options.id : fireplace#transport#id()
let path = join(self.Path(), has('win32') ? ';' : ':')
let options = s:NormalizeNs(self, options)
let ns = get(options, 'ns', self.UserNs())
let queue = []
if exists('l:Callback')
return s:spawn_eval(id, path, options.code, ns, l:Callback)
endif
call s:spawn_eval(id, path, options.code, ns, function('add', [queue]))
call s:spawn_wait(id)
return fireplace#transport#combine(queue)
endfunction
let s:oneoff.eval = s:oneoff.Eval
function! s:oneoff.Session(...) abort
throw s:no_repl
endfunction
function! s:oneoff.HasOp(op) abort
return 0
endfunction
let s:oneoff.message = s:oneoff.Session
let s:oneoff.Message = s:oneoff.Session
" Section: Client
function! s:buffer_absolute(...) abort
let buffer = call('s:buf', a:000)
let path = substitute(fnamemodify(bufname(buffer), ':p'), '\C^zipfile:\%([\/][\/]\)\=\(.*\)::', '\1/', '')
let scheme = substitute(matchstr(path, '^\a\a\+\ze:'), '^.', '\u&', '')
if len(scheme) && exists('*' . scheme . 'Real')
let path = {scheme}Real(path)
elseif getbufvar(buffer, '&buftype') !~# '^$\|^acwrite$'
return ''
endif
if path !~# '^/\|^\a\+:\|^$' && isdirectory(matchstr(path, '^[^\/]\+[\/]'))
let path = getcwd() . matchstr(path, '[\/]') . path
endif
return path =~# '^\a:[\/]\|^/' ? simplify(path) : ''
endfunction
function! s:buffer_path(...) abort
let buffer = call('s:buf', a:000)
let path = s:buffer_absolute(buffer)
for dir in fireplace#path(buffer)
if dir !=# '' && path[0 : strlen(dir)-1] ==# dir && path[strlen(dir)] =~# '[\/]'
return path[strlen(dir)+1:-1]
endif
endfor
return ''
endfunction
function! fireplace#ns(...) abort
let buffer = call('s:buf', a:000)
if !empty(getbufvar(buffer, 'fireplace_ns'))
return getbufvar(buffer, 'fireplace_ns')
endif
let head = getbufline(buffer, 1, 500)
let blank = '^\s*\%(\%(;\|#!\).*\)\=$'
call filter(head, 'v:val !~# blank')
let keyword_group = '[A-Za-z0-9_?*!+/=<>.-]'
let lines = join(head[0:49], ' ')
let lines = substitute(lines, '"\%(\\.\|[^"]\)*"\|\\.', '', 'g')
let lines = substitute(lines, '\^\={[^{}]*}', '', '')
let lines = substitute(lines, '\^:'.keyword_group.'\+', '', 'g')
let ns = matchstr(lines, '\C^(\s*\%(in-ns\s*''\|ns\s\+\)\zs'.keyword_group.'\+\ze')
if ns !=# ''
return ns
endif
let path = s:buffer_path(buffer)
return s:to_ns(path ==# '' ? s:user_ns(buffer) : path)
endfunction
function! s:buf(...) abort
if exists('s:input') && !a:0
return s:input
endif
let bufnr = a:0 && a:1 >= 0 && a:1 isnot# v:true ? a:1 : bufnr('')
let fullname = fnamemodify(bufname(bufnr), ':p')
if has_key(s:qffiles, fullname)
return s:qffiles[fullname].buffer
else
return bufnr
endif
endfunction
function! s:bufext(...) abort
return matchstr(bufname(call('s:buf', a:000)), '\.\zs\w\+$')
endfunction
function! s:impl_ns(...) abort
let buf = a:0 ? a:1 : s:buf()
let ext = fnamemodify(bufname(buf), ':e')
if ext ==# 'cljs'
return 'cljs'
elseif ext ==# 'clj'
return 'clojure'
elseif !empty(get(b:, 'fireplace_cljc_platform', ''))
return b:fireplace_cljc_platform is# 'cljs' ? 'cljs' : 'clj'
else
try
if len(get(call('fireplace#native', a:000), 'cljs_sessions', []))
return 'cljs'
endif
catch /^Fireplace: no live REPL connection/
endtry
return 'clojure'
endif
endfunction
function! s:repl_ns(...) abort
return s:impl_ns(a:0 ? a:1 : s:buf()) . '.repl'
endfunction
function! s:user_ns(...) abort
return s:impl_ns(a:0 ? a:1 : s:buf()) ==# 'cljs' ? 'cljs.user' : 'user'
endfunction
function! s:slash() abort
return exists('+shellslash') && !&shellslash ? '\' : '/'
endfunction
function! s:includes_file(file, path) abort
for path in a:path
if len(path) && strpart(a:file, 0, len(path)) ==? path
return 1
endif
endfor
endfunction
function! s:path_extract(path, ...) abort
let path = []
if a:0 || a:path =~# '\.jar'
for elem in split(substitute(a:path, ',$', '', ''), a:0 ? '[=,]' : ',')
if elem ==# ''
let path += ['.']
else
let path += split(glob(substitute(elem, '\\\ze[\\ ,]', '', 'g'), 1), "\n")
endif
endfor
endif
return path
endfunction
function! fireplace#path(...) abort
let buf = a:0 ? a:1 : s:buf()
let absolute = s:buffer_absolute(buf)
for repl in s:repls
if s:includes_file(absolute, repl.Path())
return repl.Path()
endif
endfor
return s:path_extract(getbufvar(buf, '&path'))
endfunction
function! fireplace#native(...) abort
call s:unregister_dead()
for [k, v] in items(s:repl_portfiles)
if getftime(k) != v.time
call s:unregister(v)
endif
endfor
let buf = a:0 ? a:1 : s:buf()
let path = s:buffer_absolute(buf)
let portfile = findfile('.nrepl-port', (a:0 ? fnamemodify(path, ':h') : '.') . ';')
if !empty(portfile) && filereadable(portfile)
call fireplace#register_port_file(portfile, fnamemodify(portfile, ':p:h'))
else
let portfile = findfile('.shadow-cljs/nrepl.port', (a:0 ? fnamemodify(path, ':h') : '') . ';')
if !empty(portfile) && filereadable(portfile)
call fireplace#register_port_file(portfile, fnamemodify(portfile, ':p:h:h'))
endif
endif
if !a:0
silent doautocmd <nomodeline> User FireplacePreConnect
endif
let root = substitute(path, '[\/]$', '', '')
let previous = ""
while root !=# previous
if has_key(s:repl_paths, root)
return s:repl_paths[root]
endif
let previous = root
let root = fnamemodify(root, ':h')
endwhile
for repl in s:repls
if s:includes_file(path, repl.Path())