build.gradle

buildscript {
    dependencies {
        classpath libs.hilt.android.gradle.plugin
        classpath libs.sqldelight.gradle.plugin
        classpath libs.google.services
        classpath libs.bugsnag.plugin
    }

}
plugins {
    alias(libs.plugins.moduleGraph)
    alias(libs.plugins.sonarqube)
    alias(libs.plugins.analysis)

    alias(libs.plugins.about) apply false
    alias(libs.plugins.android.app) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.google.services) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.ksp) apply false
    alias(libs.plugins.powerassert) apply false
    alias(libs.plugins.redacted) apply false
    alias(libs.plugins.sqldelight) apply false
}

tasks.register('clean', Delete) {
    delete rootProject.layout.buildDirectory
}

sonarqube {
    properties {
        property "sonar.projectKey", "savvasdalkitsis_uhuruphotos-android"
        property "sonar.organization", "savvasdalkitsis"
        property "sonar.host.url", "https://sonarcloud.io"
    }
}

subprojects {
    if (name == "konsist") {
        return
    }

    if (name == "app") {
        apply plugin: libs.plugins.android.app.get().pluginId
    } else {
        apply plugin: libs.plugins.android.library.get().pluginId
    }
    apply plugin: libs.plugins.powerassert.get().pluginId
    apply plugin: libs.plugins.kotlin.android.get().pluginId
    apply plugin: libs.plugins.redacted.get().pluginId
    apply plugin: libs.plugins.ksp.get().pluginId

    android {
        compileSdk 35

        defaultConfig {
            minSdk 24
            targetSdk 35
        }
        compileOptions {
            sourceCompatibility JavaVersion.VERSION_21
            targetCompatibility JavaVersion.VERSION_21
        }
        kotlinOptions {
            kotlinOptions.allWarningsAsErrors = true
        }
    }

    dependencies {
        ksp libs.hilt.dagger.compiler
        ksp libs.androidx.hilt.compiler
    }
}