configure

#!/usr/bin/perl

use strict;
use Cwd qw(abs_path);
use Getopt::Long;

our $VERSION = 2.2;

Getopt::Long::Configure(qw(bundling no_ignore_case require_order));
my %opts = (
    prefix => "/usr/local",
);
my $plver = $^V;
$plver =~ s/v|\.\d+$//g;
$opts{plprefix} = "$opts{prefix}/lib/perl5/site_lib/$plver/";
exit 1 if !GetOptions(\%opts, qw(help|h geodb=s plprefix=s prefix=s));
if ($opts{help}) {
    print "'configure' configures Savors for different environments\n";
    print "\n";
    print "Usage: $0 [OPTION]...\n";
    print "\n";
    print "Defaults for the options are specified in brackets.\n";
    print "\n";
    print "Configuration:\n";
    print "  --help             display this help and exit\n";
    print "  --geodb=PATH       location of IP2Location DB11 database\n";
    print "  --plprefix=DIR     perl installation directory [$opts{plprefix}]\n";
    print "  --prefix=DIR       installation directory [$opts{prefix}]\n";
    print "\n";
    print "Report bugs to <pkolano\@gmail.com>\n";
    exit 0;
}
$opts{geodb} = abs_path($opts{geodb}) if ($opts{geodb});
$opts{prefix} =~ s/\/*$/\//;
$opts{plprefix} =~ s/\/*$/\//;

my $error = 0;
my @pl_mods = qw(
    GD
    Imager
    IO::Pty
    Tk
);
foreach my $mod (@pl_mods) {
    print "checking for perl module $mod...";
    if (!system("perl -M$mod -e '1' 2>/dev/null")) {
        print "yes\n";
    } else {
        print "no\n";
        print "*** ERROR: Can't find perl module $mod\n";
        $error = 1;
    }
}
print "\n";

my @py_mods = qw(
    cython
    numpy
    PIL
);
foreach my $mod (@py_mods) {
    print "checking for python module $mod...";
    if (!system("python -c 'import $mod' 2>/dev/null")) {
        print "yes\n";
    } else {
        print "no\n";
        print "*** ERROR: Can't find python module $mod\n";
        $error = 1;
    }
}
print "\n";

my @cmds = (
    "dot -V",
    "mscgen -l",
);
foreach my $cmd (@cmds) {
    print "checking for command $cmd...";
    if (!system("$cmd >/dev/null 2>/dev/null")) {
        print "yes\n";
    } else {
        print "no\n";
        print "*** ERROR: Can't find command $cmd\n";
        $error = 1;
    }
}
print "\n";

if ($error) {
    print "configuration failed...check output for errors\n";
    exit 1;
} else {
    print "configuration succeeded...creating Makefile.config\n";
    open(FILE, ">Makefile.config");
    while (my ($key, $val) = each %opts) {
        print FILE uc($key) . "=" . $val . "\n";
    }
    close FILE;
}