Compile from string

[piever]

libsass allows to compile from string, though that currently doesn't work here. If I try:

context = sass_make_data_context("div { a { color: blue; } }")
compiler = sass_make_data_compiler(context)
sass_compiler_parse(compiler)
sass_compiler_execute(compiler)
sass_delete_compiler(compiler)

It segfaults when deleting the compiler as it also tries to deallocate the Julia string. One can either:

• not delete the compiler and accept some memory leak
• figure out how to "pass ownership of a buffer from Julia to C"

The second option seems better but I have no idea how to do it.

[hhaensel]

A workaround for doing this would be

function compile_sass(io::IOBuffer, args...; kwargs...)
  local css
  mktemp(pwd()) do filepath, fileio
    sass = String(take!(io))
    is_indented = get(kwargs, :is_indented_syntax_src, false)
    write(fileio, sass)
    close(fileio)
    is_indented && mv(filepath, filepath * ".sass")
    css = try
      Sass.compile_file(filepath * (is_indented ? ".sass" : ""), args...; kwargs...)
    catch e
      @warn e
    finally
      is_indented && mv(filepath * ".sass", filepath)
    end
  end
  css
end

compile_sass(s::AbstractString, args...; kwargs...) = compile_sass(IOBuffer(s), args...; kwargs...)

At least for me (OS: Windows, Julia: 1.9), calling with is_indented_syntax_src = true had no effect. File ending seems to have precedence over the option. So I renamed the temp file to end with ".sass"

[hhaensel]

Inspired by https://github.com/sass/libsass/blob/master/docs/api-context-example.md I found the true solution:

function sass_copy_string(s)
    ccall((:sass_copy_c_string, Sass.libsass_so),
        Ptr{Cstring}, (Cstring,), s)
end
  
text = sass_copy_string("div { a { color: blue; } }")
context = sass_make_data_context(text)
compiler = sass_make_data_compiler(context)
sass_compiler_parse(compiler)
sass_compiler_execute(compiler)
output = sass_context_get_output_string(context)
sass_delete_data_context(context)
sass_delete_compiler(compiler)

I'll submit a PR to make that available in the julia api.