build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

ext.dbfitVersion = '3.1.0'

task cleanFitnesseroot(type:Exec) {
    def gitArgs = ['clean', '-d', '-x', '-f', 'FitNesseRoot/']
    gitArgs += keepUncommitedTests() ? ['-e', 'FitNesseRoot/DbFit/'] : []

    executable 'git'
    args gitArgs
}

task cleanDist << {
    delete 'dist'
    delete 'zips'
    delete 'docs'
}

task copyLocal(dependsOn: [cleanFitnesseroot, cleanDist, ':dbfit-java:assembleAll', ':dbfit-java:libs']) << {
    copy {
        from 'LICENSE', 'README.md'
        into 'dist'
    }
    copy {
        from 'bin'
        include 'encrypt.*'
        into 'dist'
    }
    copy {
        from 'templates'
        include 'startFitnesse.*'
        into 'dist'
        rename '(.+)\\.tmpl$', '$1'
        filter(ReplaceTokens,
            tokens: ['dbfitVersion': dbfitVersion, 'fitNesseVersion': project(':dbfit-java').fitNesseVersion])
    }
    copy {
        from 'files'
        into 'dist'
    }
    copy {
        from 'dbfit-java'
        include '**/*.jar'
        exclude 'build/**/*.jar'
        exclude proprietaryLibs()
        exclude experimentalItems()
        into 'dist/lib'
        eachFile {details ->
            details.path = flattenPath(details.path)
        }
        includeEmptyDirs = false 
    }
}

task copyExtraLibs(dependsOn: [copyLocal]) << {
    copy {
        from 'dbfit-java'
        include proprietaryLibs()
        into 'dist/lib'
        eachFile {details ->
            details.path = flattenPath(details.path)
        }
        includeEmptyDirs = false
    }
    copy {
        from project(':dbfit-java:derby').configurations.derby
        into 'dist/lib'
    }
}

task copyConnections(dependsOn: [copyLocal]) << {
    copy {
        from 'dbfit-java/oracle/TestDbConnectionDbFitOracle.properties.default'
        into 'dist'
        rename '(.*).default', '$1'
    }

    copy {
        from 'dbfit-java/oracle/TestDbConnectionDbFitOracle.properties.custom'
        into 'dist'
        rename '(.*).custom', '$1'
    }
}

task wikiDocsDir << {
    mkdir('docs/Resources/')
}

task fitnesseUpdateList << {
    copy {
        from zipTree(fitnesseJar()).matching { include 'Resources/updateList' }
        into 'docs'
        rename 'updateList', 'updateList.fitnesse'
    }
}

task dbfitUpdateList(dependsOn: wikiDocsDir) << {
    File f = file('docs/Resources/updateList.dbfit')

    fileTree('FitNesseRoot').each {
        f << "${relativePath(it).toString().replace('\\', '/')}\n"
    }
}

task wikiDocsUpdateList(dependsOn: [fitnesseUpdateList, dbfitUpdateList]) << {
    File f = file('docs/Resources/updateList')

    f << file('docs/Resources/updateList.dbfit').text
    f << file('docs/Resources/updateList.fitnesse').text

    delete 'docs/Resources/updateList.fitnesse'
    delete 'docs/Resources/updateList.dbfit'
}

task wikiDocs(dependsOn: [wikiDocsUpdateList]) << {
    copy {
        from 'FitNesseRoot'
        into 'docs/Resources/FitNesseRoot'
    }

    ant.jar(destfile: 'dist/lib/dbfit-docs-' + dbfitVersion + '.jar', basedir: 'docs', level: 9)
}

def fitnesseJar() {
    fileTree(dir: 'dist/lib', include: 'fitnesse-*.jar').getSingleFile()
}

def flattenPath(def path) {
    path.replaceAll('.*/([^/]*?\\.jar)', {"${it[1]}"})
}

task bundleFitsharp(dependsOn: copyLocal) << {
    mkdir 'dist/fitsharp/'
    ant.get(src: 'http://cloud.github.com/downloads/jediwhale/fitsharp/release.2.2.net.40.zip',
            dest: 'dist/fitsharp/',
            verbose: true)
    copy {
        from zipTree('dist/fitsharp/release.2.2.net.40.zip')
        into 'dist/fitsharp/'
    }
    delete 'dist/fitsharp/release.2.2.net.40.zip'
    file('dist/fitsharp/Runner.exe.config') << '<configuration><runtime><loadFromRemoteSources enabled="true"/></runtime></configuration>'
}


task bundle(type: Zip, dependsOn: [copyLocal, wikiDocs, bundleFitsharp]) {
    description = 'creates the zip file for distributing dbfit'
    from 'dist'
    baseName 'dbfit-complete'
    version dbfitVersion
    destinationDir new File('zips')
}

task start(type: Exec, dependsOn: [copyLocal, copyExtraLibs, copyConnections, wikiDocs, bundleFitsharp]) {
    workingDir './dist'
    description = 'starts fitness with dbfit'
    executable onWindows() ? 'startFitnesse.bat' : './startFitnesse.sh'
}

task starthere(type: Exec, dependsOn: [copyLocal, copyExtraLibs, copyConnections]) {
    workingDir './dist'
    description = 'starts fitness with dbfit on top of real tests sources'
    executable onWindows() ? 'startFitnesse.bat' : './startFitnesse.sh'
    args '-d', '..', '-o', '-f', 'plugins.properties'
}

task fastbuild(dependsOn: [':dbfit-java:core:check', ':dbfit-java:derby:check'])

def onWindows() {
    System.properties['os.name'].toLowerCase().contains('windows')
}

def proprietaryLibs() {
    ['**/ojdbc*.jar', '**/db2jcc4*.jar', '**/terajdbc*.jar', '**/tdgssconfig*.jar', '**/nzjdbc*.jar'] as Set
}

def experimentalItems() {
    [] as Set
}

def keepUncommitedTests() {
    project.hasProperty('keepTests') && keepTests != 'false'
}