-
Notifications
You must be signed in to change notification settings - Fork 0
/
automultiring.zig
562 lines (474 loc) · 17.5 KB
/
automultiring.zig
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
// SPDX-FileCopyrightText: Copyright 2023, 2024 OK Ryoko
// SPDX-License-Identifier: MIT
const std = @import("std");
const Allocator = std.mem.Allocator;
const ArrayListUnmanaged = std.ArrayListUnmanaged;
const AutoHashMapUnmanaged = std.AutoHashMapUnmanaged;
const math = std.math;
const MultiRing = @import("multiring").MultiRing;
const MultiRingError = error{
NoMoreRoom,
NoSuchNode,
OverwriteAttempt,
RingIsOpen,
};
/// Minimal example of an append-only, ring-level and data-centric interface to a `MultiRing(T)`
/// with automatic memory management
///
/// Keeps all rings closed
///
/// Mitigates the existence of free (dangling) rings
///
/// Guards against undefined behavior in the underlying multiring's operations by returning an error
///
pub fn AutoMultiRing(comptime T: type) type {
return struct {
const Self = @This();
const M = MultiRing(T);
const Nodes = AutoHashMapUnmanaged(Node, M.Node);
const Rings = AutoHashMapUnmanaged(HeadNode, ArrayListUnmanaged(DataNode));
const Id = u32;
pub const Node = union(M.NodeTag) {
head: HeadNode,
data: DataNode,
};
pub const HeadNode = Id;
pub const DataNode = Id;
comptime root: Id = 0,
inner: M = undefined,
key: Id = 0,
// Storage for all nodes
//
// Always assume that the active tag in every key is equal to the active tag in the
// associated value
//
nodes: Nodes = undefined,
// Map from head nodes to data nodes
//
// Always assume that every key corresponds to exactly one key in `Self.nodes` with active
// tag equal to `.head`
//
rings: Rings = undefined,
alloc: Allocator = undefined,
/// Initialize a multiring containing an empty root ring
///
pub fn init(allocator: Allocator) !Self {
const root_id = 0;
const root_ptr = try allocator.create(M.HeadNode);
errdefer allocator.destroy(root_ptr);
root_ptr.* = M.HeadNode{};
var nodes = Nodes{};
errdefer nodes.deinit(allocator);
try nodes.putNoClobber(allocator, Node{ .head = root_id }, M.Node{ .head = root_ptr });
var rings = Rings{};
errdefer rings.deinit(allocator);
var data_ids = ArrayListUnmanaged(DataNode){};
errdefer data_ids.deinit(allocator);
try rings.putNoClobber(allocator, root_id, data_ids);
return .{
.root = root_id,
.inner = M{ .root = root_ptr },
.key = 1,
.nodes = nodes,
.rings = rings,
.alloc = allocator,
};
}
/// Release all memory allocated for this multiring
///
pub fn deinit(self: *Self) void {
{
var it = self.rings.valueIterator();
while (it.next()) |data_ids| {
data_ids.deinit(self.alloc);
}
}
self.rings.deinit(self.alloc);
{
var it = self.nodes.valueIterator();
while (it.next()) |node| {
switch (node.*) {
inline else => |n| self.alloc.destroy(n),
}
}
}
self.nodes.deinit(self.alloc);
self.* = undefined;
}
/// Determine whether this multiring is empty
///
pub fn isEmpty(self: *Self) bool {
return self.inner.isEmpty();
}
/// Determine whether a ring is empty
///
/// Asserts that the ring is in this multiring
///
pub fn isRingEmpty(self: *Self, head_id: HeadNode) !bool {
if (!self.rings.contains(head_id)) {
return MultiRingError.NoSuchNode;
}
return self.rings.getPtr(head_id).?.items.len == 0;
}
/// Return the number of data nodes in this multiring
///
pub fn len(self: *Self) usize {
var it = self.rings.valueIterator();
var count: usize = 0;
while (it.next()) |data| {
count += data.items.len;
}
return count;
}
/// Return the number of data nodes in a ring
///
/// Asserts that the ring is in this multiring
///
pub fn lenRing(self: *Self, head_id: HeadNode) !usize {
if (!self.rings.contains(head_id)) {
return MultiRingError.NoSuchNode;
}
return self.rings.getPtr(head_id).?.items.len;
}
/// Create a ring from zero or more data items and link it to the data node represented by
/// `data_id`
///
/// Asserts that:
///
/// - there is sufficient storage in this multiring, and
/// - there isn't already a ring linked to the data node
///
pub fn createRing(self: *Self, data_id: DataNode, items: ?[]const T) !HeadNode {
if (self.key + 1 >= math.maxInt(Id)) {
return MultiRingError.NoMoreRoom;
}
if (items != null and self.key + items.?.len + 1 >= math.maxInt(Id)) {
return MultiRingError.NoMoreRoom;
}
const head_ptr = try self.alloc.create(M.HeadNode);
errdefer self.alloc.destroy(head_ptr);
head_ptr.* = M.HeadNode{};
const head_id = try self.incrementGetKey();
try self.nodes.putNoClobber(self.alloc, Node{ .head = head_id }, M.Node{ .head = head_ptr });
errdefer {
_ = self.nodes.remove(Node{ .head = head_id });
}
try self.attachRing(head_id, data_id);
var data_ids = ArrayListUnmanaged(DataNode){};
errdefer data_ids.deinit(self.alloc);
try self.rings.putNoClobber(self.alloc, head_id, data_ids);
if (items) |data| {
try self.extendRing(head_id, data);
}
return head_id;
}
/// Link a (multi)ring to a data node in this multiring
///
/// Asserts that:
///
/// - `head_id` represents a free ring, and
/// - `data_id` represents a data node that is in this multiring and to
/// which no ring is already linked
///
fn attachRing(self: *Self, head_id: HeadNode, data_id: DataNode) !void {
const head_node = Node{ .head = head_id };
if (!self.nodes.contains(head_node)) {
return MultiRingError.NoSuchNode;
}
const head_ptr = switch (self.nodes.get(head_node).?) {
.head => |h| h,
.data => unreachable,
};
if (head_ptr.next_above) |_| {
return MultiRingError.OverwriteAttempt;
}
const data_node = Node{ .data = data_id };
if (!self.nodes.contains(data_node)) {
return MultiRingError.NoSuchNode;
}
const data_ptr = switch (self.nodes.get(data_node).?) {
.head => unreachable,
.data => |d| d,
};
if (data_ptr.next_below) |_| {
return MultiRingError.OverwriteAttempt;
}
data_ptr.attachMultiRing(head_ptr);
}
/// Extend a ring with one or more data items
///
/// Asserts that:
///
/// - the ring is in this multiring, and
/// - there is sufficient storage in this multiring
///
/// Invalidates all iterators into the ring
///
pub fn extendRing(self: *Self, head_id: HeadNode, items: []const T) !void {
if (!self.nodes.contains(Node{ .head = head_id })) {
return MultiRingError.NoSuchNode;
}
if (items.len == 0) {
return;
}
if (self.key + items.len >= math.maxInt(Id)) {
return MultiRingError.NoMoreRoom;
}
const data_ids = self.rings.getPtr(head_id).?;
var last_node = switch (self.nodes.get(Node{ .head = head_id }).?) {
.head => |h| M.Node{ .head = h },
.data => unreachable,
};
if (data_ids.items.len > 0) {
const last_data_id = data_ids.items[data_ids.items.len - 1];
switch (self.nodes.get(Node{ .data = last_data_id }).?) {
.head => unreachable,
.data => |d| {
last_node = M.Node{ .data = d };
},
}
}
for (items) |item| {
const data_ptr = try self.alloc.create(M.DataNode);
errdefer self.alloc.destroy(data_ptr);
data_ptr.* = M.DataNode{ .data = item };
const data_id = try self.incrementGetKey();
try self.nodes.putNoClobber(self.alloc, Node{ .data = data_id }, M.Node{ .data = data_ptr });
errdefer {
_ = self.nodes.remove(Node{ .data = data_id });
}
try data_ids.append(self.alloc, data_id);
switch (last_node) {
inline else => |last_ptr| last_ptr.insertAfter(data_ptr),
}
last_node = M.Node{ .data = data_ptr };
}
}
/// Return a copy of the data items in this multiring that satisfy the predicate, skipping
/// all data items below every noncompliant data node
///
/// Assumes that the root node exists
///
/// Asserts that every ring is closed
///
pub fn filter(self: *Self, allocator: Allocator, predicate: *const fn (T) bool) ![]T {
if (self.isEmpty()) {
return &.{};
}
const root_ptr = switch (self.nodes.get(Node{ .head = self.root }).?) {
.head => |r| r,
.data => unreachable,
};
var result = ArrayListUnmanaged(T){};
var it = root_ptr.step();
while (it) |data_ptr| {
if (data_ptr.next == null) {
return MultiRingError.RingIsOpen;
}
if (predicate(data_ptr.data)) {
try result.append(allocator, data_ptr.data);
it = data_ptr.stepZ();
continue;
}
switch (data_ptr.next.?) {
.head => |h| it = h.stepAbove(),
.data => it = data_ptr.step(),
}
}
return result.toOwnedSlice(allocator);
}
/// Return the result of folding every data item in this multiring into an accumulator using
/// the given function
///
/// Assumes that the root node exists
///
/// Asserts that every ring is closed
///
pub fn fold(self: *Self, accumulator: T, func: *const fn (T, T) T) !T {
if (self.isEmpty()) {
return accumulator;
}
const root_ptr = switch (self.nodes.get(Node{ .head = self.root }).?) {
.head => |h| h,
.data => unreachable,
};
var result = accumulator;
var it = root_ptr.step();
while (it) |data_ptr| {
if (data_ptr.next == null) {
return MultiRingError.RingIsOpen;
}
result = func(result, data_ptr.data);
it = data_ptr.stepZ();
}
return result;
}
/// Update this multiring in place by applying the given function to every data item
///
/// Assumes that the root node exists
///
/// Asserts that every ring is closed
///
pub fn map(self: *Self, func: *const fn (T) T) !void {
if (self.isEmpty()) {
return;
}
const root_ptr = switch (self.nodes.get(Node{ .head = self.root }).?) {
.head => |h| h,
.data => unreachable,
};
var it = root_ptr.step();
while (it) |data_ptr| {
if (data_ptr.next == null) {
return MultiRingError.RingIsOpen;
}
data_ptr.data = func(data_ptr.data);
it = data_ptr.stepZ();
}
}
/// Return a copy of the data item stored in the data node represented by `data_id`
///
/// Asserts that the data node is in this multiring
///
pub fn getData(self: *Self, data_id: DataNode) !T {
const data_node = Node{ .data = data_id };
if (!self.nodes.contains(data_node)) {
return MultiRingError.NoSuchNode;
}
return switch (self.nodes.get(data_node).?) {
.head => unreachable,
.data => |d| d.data,
};
}
/// Return an iterator over the data nodes in a ring
///
/// Asserts that the ring is in this multiring
///
pub fn iterateRing(self: *Self, head_id: HeadNode) !RingIterator {
if (!self.rings.contains(head_id)) {
return MultiRingError.NoSuchNode;
}
const data_ids = self.rings.getPtr(head_id).?;
return if (data_ids.items.len > 0) .{
.items = data_ids.items,
.count = data_ids.items.len,
} else .{
.items = undefined,
.count = 0,
};
}
/// Iterator over the data nodes in a ring
///
pub const RingIterator = struct {
items: []DataNode,
count: usize,
/// Return the next data node in the ring
///
/// If the last data node in the ring has already been returned, then return null
///
pub fn next(self: *RingIterator) ?DataNode {
if (self.count > 0) {
const node = self.items[self.items.len - self.count];
self.count -= 1;
return node;
}
return null;
}
};
/// Increment the storage key
///
/// Asserts that the operation will not result in integer overflow
///
fn incrementGetKey(self: *Self) !Id {
if (self.key == math.maxInt(Id)) {
return MultiRingError.NoMoreRoom;
}
self.key += 1;
return self.key;
}
};
}
test "empty multiring" {
const testing = std.testing;
const a = testing.allocator;
const M = AutoMultiRing(u8);
var m = try M.init(a);
defer m.deinit();
try testing.expect(m.isEmpty());
try testing.expect(try m.isRingEmpty(m.root));
try testing.expectError(MultiRingError.NoSuchNode, m.isRingEmpty(1));
try testing.expectEqual(@as(usize, 0), m.len());
try testing.expectEqual(@as(usize, 0), try m.lenRing(m.root));
try testing.expectError(MultiRingError.NoSuchNode, m.lenRing(1));
var it = try m.iterateRing(m.root);
try testing.expectEqual(@as(?M.DataNode, null), it.next());
{
const sum: u8 = 0;
try testing.expectEqual(sum, try m.fold(sum, add));
}
{
const empty = try m.filter(a, isEven);
defer a.free(empty);
try testing.expectEqual(@as(usize, 0), empty.len);
}
}
test "runtime multiring construction, filter and map" {
const testing = std.testing;
const a = testing.allocator;
var m = try AutoMultiRing(u8).init(a);
defer m.deinit();
const root_data = [_]u8{ 0, 1, 2, 3, 4 };
try m.extendRing(m.root, &root_data);
try testing.expect(!m.isEmpty());
try testing.expect(!(try m.isRingEmpty(m.root)));
try testing.expectEqual(@as(usize, 5), m.len());
try testing.expectEqual(@as(usize, 5), try m.lenRing(m.root));
{
var ring_data = ArrayListUnmanaged(u8){};
defer ring_data.deinit(a);
var it = try m.iterateRing(m.root);
while (it.next()) |data_id| {
const d = try m.getData(data_id);
for (root_data[0..d]) |i| {
try ring_data.append(a, i);
}
const slice = try ring_data.toOwnedSlice(a);
defer a.free(slice);
const head_id = try m.createRing(data_id, slice);
try testing.expectEqual(@as(usize, d), try m.lenRing(head_id));
}
}
try testing.expectEqual(@as(usize, 15), m.len());
{
var it = try m.iterateRing(m.root);
try testing.expectError(MultiRingError.OverwriteAttempt, m.createRing(it.next().?, null));
}
{
const expected = [_]u8{ 0, 2, 0, 4, 0, 2 };
const actual = try m.filter(a, isEven);
defer a.free(actual);
try testing.expectEqualSlices(u8, &expected, actual);
}
try testing.expectEqual(@as(usize, 15), m.len());
{
const sum = try m.fold(@as(u8, 0), add);
try testing.expectEqual(@as(u8, 20), sum);
}
try testing.expectEqual(@as(usize, 15), m.len());
try m.map(double);
{
var sum: u8 = 0;
sum = try m.fold(sum, add);
try testing.expectEqual(@as(u8, 40), sum);
}
try testing.expectEqual(@as(usize, 15), m.len());
}
fn isEven(n: u8) bool {
return n % 2 == 0;
}
fn double(n: u8) u8 {
return 2 * n;
}
fn add(accumulator: u8, item: u8) u8 {
return accumulator + item;
}