qt: add qt.style option

This allows you to set a theme for Qt applications.
nix-community · Mar 1, 2021 · 56d9a5d · 56d9a5d
1 parent aa479b0
commit 56d9a5d
Show file tree

Hide file tree

Showing 6 changed files with 85 additions and 3 deletions.
diff --git a/modules/misc/qt.nix b/modules/misc/qt.nix
@@ -44,19 +44,63 @@ in {
           </variablelist>
         '';
       };
+
+      style = mkOption {
+        type = types.nullOr types.str;
+        default = null;
+        example = "adwaita";
+        relatedPackages = [ "adwaita-qt" [ "libsForQt5" "qtstyleplugins" ] ];
+        description = ''
+          Selects the style to use for Qt5 applications.</para>
+          <para>The options are
+          <variablelist>
+            <varlistentry>
+              <term><literal>adwaita</literal></term>
+              <term><literal>adwaita-dark</literal></term>
+              <listitem><para>Use Adwaita Qt style with
+                <link xlink:href="https://github.com/FedoraQt/adwaita-qt">adwaita</link>
+              </para></listitem>
+            </varlistentry>
+            <varlistentry>
+              <term><literal>cleanlooks</literal></term>
+              <term><literal>gtk2</literal></term>
+              <term><literal>motif</literal></term>
+              <term><literal>plastique</literal></term>
+              <listitem><para>Use styles from
+                <link xlink:href="https://github.com/qt/qtstyleplugins">qtstyleplugins</link>
+              </para></listitem>
+            </varlistentry>
+          </variablelist>
+        '';
+      };
     };
   };
 
   config = mkIf (cfg.enable && cfg.platformTheme != null) {
-    home.sessionVariables.QT_QPA_PLATFORMTHEME =
-      if cfg.platformTheme == "gnome" then "gnome" else "gtk2";
+    assertions = [{
+      assertion = (cfg.platformTheme == "gnome") -> (cfg.style != null);
+      message = ''
+        `qt.platformTheme` "gnome" must have `qt.style` set to a theme that
+        supports both Qt and Gtk, for example "adwaita" or "adwaita-dark".
+      '';
+    }];
+
+    # Necessary because home.sessionVariables is of types.attrs
+    home.sessionVariables = (filterAttrs (n: v: v != null) {
+      QT_QPA_PLATFORMTHEME =
+        if cfg.platformTheme == "gnome" then "gnome" else "gtk2";
+      QT_STYLE_OVERRIDE = cfg.style;
+    });
 
     home.packages = if cfg.platformTheme == "gnome" then
       [ pkgs.qgnomeplatform ]
+      ++ lib.optionals (builtins.elem cfg.style [ "adwaita" "adwaita-dark" ])
+      [ pkgs.adwaita-qt ]
     else
       [ pkgs.libsForQt5.qtstyleplugins ];
 
-    xsession.importedVariables = [ "QT_QPA_PLATFORMTHEME" ];
+    xsession.importedVariables = [ "QT_QPA_PLATFORMTHEME" ]
+      ++ lib.optionals (cfg.style != null) [ "QT_STYLE_OVERRIDE" ];
 
     # Enable GTK+ style for Qt4 in either case.
     # It doesn’t support the platform theme packages.

diff --git a/tests/default.nix b/tests/default.nix
@@ -84,6 +84,7 @@ import nmt {
     ./modules/misc/debug
     ./modules/misc/numlock
     ./modules/misc/pam
+    ./modules/misc/qt
     ./modules/misc/xdg
     ./modules/misc/xsession
     ./modules/programs/abook

diff --git a/tests/modules/misc/qt/default.nix b/tests/modules/misc/qt/default.nix
@@ -0,0 +1,4 @@
+{
+  qt-platform-theme-gtk = ./qt-platform-theme-gtk.nix;
+  qt-platform-theme-gnome = ./qt-platform-theme-gnome.nix;
+}
diff --git a/tests/modules/misc/qt/qt-platform-theme-expected b/tests/modules/misc/qt/qt-platform-theme-expected
diff --git a/tests/modules/misc/qt/qt-platform-theme-gnome.nix b/tests/modules/misc/qt/qt-platform-theme-gnome.nix
@@ -0,0 +1,18 @@
+{ config, lib, pkgs, ... }:
+
+{
+  config = {
+    qt = {
+      enable = true;
+      platformTheme = "gnome";
+      style = "adwaita";
+    };
+
+    nmt.script = ''
+      assertFileRegex home-path/etc/profile.d/hm-session-vars.sh \
+        'QT_QPA_PLATFORMTHEME="gnome"'
+      assertFileRegex home-path/etc/profile.d/hm-session-vars.sh \
+        'QT_STYLE_OVERRIDE="adwaita"'
+    '';
+  };
+}
diff --git a/tests/modules/misc/qt/qt-platform-theme-gtk.nix b/tests/modules/misc/qt/qt-platform-theme-gtk.nix
@@ -0,0 +1,15 @@
+{ config, lib, pkgs, ... }:
+
+{
+  config = {
+    qt = {
+      enable = true;
+      platformTheme = "gtk";
+    };
+
+    nmt.script = ''
+      assertFileRegex home-path/etc/profile.d/hm-session-vars.sh \
+        'QT_QPA_PLATFORMTHEME="gtk2"'
+    '';
+  };
+}