build.gradle

import org.flywaydb.gradle.task.FlywayMigrateTask

buildscript {
    ext {
        springBootVersion = "2.0.6.RELEASE"
        jaxbVersion = "2.3.0"
    }

    repositories {
        mavenCentral()
    }

    dependencies {
        classpath "org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion"
    }
}

plugins {
    id "java"
    id "org.flywaydb.flyway" version "5.2.4"
    id "com.gorylenko.gradle-git-properties" version "1.5.1"
}


apply plugin: 'org.springframework.boot'

repositories {
    mavenCentral()
}

dependencies {
    compile("org.springframework.boot:spring-boot-starter-web:$springBootVersion")
    testCompile("org.springframework.boot:spring-boot-starter-test:$springBootVersion")
    testCompile("org.mockito:mockito-core:2.23.4")
    compile("org.springframework.boot:spring-boot-starter-jdbc:$springBootVersion")
    compile("mysql:mysql-connector-java:6.0.6")
    compile ("org.springframework.boot:spring-boot-starter-data-jpa:$springBootVersion")
    compile("org.javassist:javassist:3.23.1-GA")    // Required for Java 11

    // JAXB is not present in Java 11
    implementation "javax.xml.bind:jaxb-api:$jaxbVersion"
    implementation "com.sun.xml.bind:jaxb-core:$jaxbVersion"
    implementation "com.sun.xml.bind:jaxb-impl:$jaxbVersion"
    implementation "javax.activation:activation:1.1.1"


    compile("org.springframework.boot:spring-boot-starter-actuator:$springBootVersion")
}
def developmentDbUrl = "jdbc:mysql://localhost:3306/tracker_dev?user=tracker&useSSL=false&useTimezone=true&serverTimezone=UTC&useLegacyDatetimeCode=false"
bootRun.environment([
        "WELCOME_MESSAGE": "hello",
        "SPRING_DATASOURCE_URL": developmentDbUrl,
        "MANAGEMENT_ENDPOINTS_WEB_EXPOSURE_INCLUDE": "*",
        "MANAGEMENT_ENDPOINT_HEALTH_SHOWDETAILS": "always",
        "MANAGEMENT_INFO_GIT_MODE": "full",
])

def testDbUrl = "jdbc:mysql://localhost:3306/tracker_test?user=tracker&useSSL=false&useTimezone=true&serverTimezone=UTC&useLegacyDatetimeCode=false"
test.environment([
        "WELCOME_MESSAGE": "Hello from test",
        "SPRING_DATASOURCE_URL": testDbUrl,
        "MANAGEMENT_ENDPOINTS_WEB_EXPOSURE_INCLUDE": "*",
        "MANAGEMENT_ENDPOINT_HEALTH_SHOWDETAILS": "always",
        "MANAGEMENT_INFO_GIT_MODE": "full",
])

flyway {
    url = developmentDbUrl
    user = "tracker"
    password = ""
    locations = ["filesystem:databases/tracker/migrations"]
}

task testMigrate(type: FlywayMigrateTask) {
    url = testDbUrl
}

springBoot {
    buildInfo()
}