build.gradle

buildscript {
    ext {
        kotlinVersion = '2.0.21'
        springBootVersion = '3.3.5'
        springKafkaVersion = '3.2.4'
        archunitVersion = '1.3.0'
        tokenSupportVersion = '5.0.11'
        jacksonModuleKotlinVersion = '2.18.1'
    }

    repositories {
        maven {
            url "https://maven.pkg.github.com/navikt/maven-release"
            credentials {
                username = "token"
                password = "$System.env.GITHUB_TOKEN"
            }
        }
    }
}


plugins {
    id "org.springframework.boot" version "$springBootVersion"
    id "io.spring.dependency-management" version "1.1.6"
    id "org.jetbrains.kotlin.jvm" version "$kotlinVersion"
    id "org.jetbrains.kotlin.plugin.spring" version "$kotlinVersion"
    id "org.jetbrains.kotlin.plugin.allopen" version "$kotlinVersion"
}

apply from: "buildSrc/ep-module.gradle"

group = 'no.nav.eessi.pensjon'

dependencies {
    //eessi pensjon libs
    implementation("no.nav.eessi.pensjon:ep-logging:2.1.87")
    implementation("no.nav.eessi.pensjon:ep-eux:2.3.37") {
        exclude module: 'ep-security-sts'
    }
    implementation("no.nav.eessi.pensjon:ep-metrics:2.0.89")

    // Spring-boot BOM-fil spesifiserer versjoner for Spring Boot-avhengigheter
    implementation(platform("org.springframework.boot:spring-boot-dependencies:${springBootVersion}"))
    implementation("org.springframework.boot:spring-boot-starter-web")
    implementation("org.yaml:snakeyaml:2.3") // Pga https://security.snyk.io/package/maven/org.yaml:snakeyaml
    implementation("org.springframework.boot:spring-boot-starter-aop")
    implementation("org.springframework.boot:spring-boot-starter-actuator")
    implementation("org.springframework.boot:spring-boot-actuator")
    implementation "org.springframework.kafka:spring-kafka:$springKafkaVersion"
    implementation("org.springframework.retry:spring-retry:2.0.10")

    // Spring Framework BOM-fil overstyrer så vi får siste patch-versjon av Spring Framework
    implementation(platform("org.springframework:spring-framework-bom:6.2.0"))

    implementation "com.fasterxml.jackson.core:jackson-core:${jacksonModuleKotlinVersion}"

    implementation 'org.jetbrains.kotlin:kotlin-reflect'

    implementation("org.apache.httpcomponents.client5:httpclient5:5.3.1")

    //GCP
    implementation("com.google.cloud:google-cloud-storage:2.45.0")

    // Logging
    implementation("net.logstash.logback:logstash-logback-encoder:8.0")
    configurations { all*.exclude group: 'commons-logging', module: 'commons-logging' }
    implementation("org.slf4j:jcl-over-slf4j:2.0.16")

    //Auth
    implementation("no.nav.security:token-client-spring:${tokenSupportVersion}")
    implementation("no.nav.security:token-validation-spring:${tokenSupportVersion}")
    implementation("no.nav.security:token-validation-jaxrs:${tokenSupportVersion}")
    implementation("no.nav.security:token-validation-test-support:2.0.5")

    //test
    testImplementation('org.springframework.boot:spring-boot-starter-test') {
        exclude module: 'junit'
        exclude module: "mockito-core"
        exclude module: "junit-vintage-engine"
    }
    testImplementation("io.mockk:mockk:1.13.13")
    testImplementation("com.ninja-squad:springmockk:4.0.2")

    testImplementation "org.springframework.kafka:spring-kafka-test:$springKafkaVersion"
    testImplementation("org.junit.jupiter:junit-jupiter:5.11.2")
    testImplementation("org.mock-server:mockserver-netty:5.15.0") {
        exclude module: 'junit'
    }

    // Architecture tests
    testImplementation ("com.tngtech.archunit:archunit:${archunitVersion}")

}

test {
    // set heap size for the test JVM(s)
    minHeapSize = "128m"
    maxHeapSize = "512m"

    // set JVM arguments for the test JVM(s)
    failFast = true
    testLogging {
        exceptionFormat "full"
        events "started", "skipped", "passed", "failed"
        showStandardStreams true
    }
}