build.gradle

apply plugin: 'java'
apply plugin: 'eclipse'

sourceCompatibility = 1.7
targetCompatibility = 1.7

version = '1.2.0'

repositories {
    mavenCentral()
    maven { url "http://artifacts.psi.ch/artifactory/libs-releases" }
    maven { url "http://artifacts.psi.ch/artifactory/libs-snapshots" }
}

dependencies {
	compile 'org.zeromq:jeromq:0.3.5'
	compile 'org.glassfish.jersey.containers:jersey-container-grizzly2-http:2.4.1'
	compile 'org.glassfish.jersey.media:jersey-media-sse:2.4.1'
	compile 'org.glassfish.jersey.media:jersey-media-json-jackson:2.4.1'
	compile 'commons-cli:commons-cli:1.2'
	
    testCompile group: 'junit', name: 'junit', version: '4.+'
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

jar {
    manifest {
        attributes("Implementation-Version": version)
    }
}

artifacts {
    archives sourcesJar
    archives javadocJar
}



task distribution(type: Zip){
  def baseDir = { archiveName - ".zip" }
  into(baseDir){
    from(project.file("src/dist"))
    into("lib") {
        from(jar)
        from(project.configurations.runtime)
    }
  }
}


apply plugin: 'maven'

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "http://artifacts.psi.ch/artifactory/libs-snapshots-local"){
            	authentication(userName: "upload", password: "{DESede}eWKHxAtQ2Dc=")
            }
            pom.groupId = 'ch.psi'
            pom.artifactId = 'bsread_1_7'
        }
    }
}