build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'com.github.ben-manes.versions'
    id 'io.spring.dependency-management' apply false
}

wrapper {
    gradleVersion = "${gradleVersion}"
}

group = 'org.serialthreads'
archivesBaseName = 'serialhtreads'
version = '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

java {
    // https://docs.gradle.org/current/userguide/toolchains.html
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(21))
        // Use Eclipse Temurin (provided by Adoptium).
        vendor.set(JvmVendorSpec.ADOPTIUM)
    }
}

dependencies {
    implementation "org.slf4j:slf4j-api:${slf4jVersion}"

    implementation "org.ow2.asm:asm:${asmVersion}"
    implementation "org.ow2.asm:asm-analysis:${asmVersion}"
    implementation "org.ow2.asm:asm-tree:${asmVersion}"
    implementation "org.ow2.asm:asm-util:${asmVersion}"

    testImplementation "org.junit.jupiter:junit-jupiter-api:${junitVersion}"
    testImplementation "org.junit.platform:junit-platform-launcher:${junitPlatformVersion}"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${junitVersion}"
    testImplementation "org.assertj:assertj-core:${assertjVersion}"
    testRuntimeOnly "org.apache.logging.log4j:log4j-slf4j2-impl:${log4jVersion}"
    testRuntimeOnly "org.apache.logging.log4j:log4j-core:${log4jVersion}"
}

jar {
    manifest {
        attributes(
                "Implementation-Title": "SerialThreads",
                "Implementation-Version": archiveVersion,
                "Premain-Class": "org.serialthreads.agent.Agent",
                "Agent-Class": "org.serialthreads.agent.Agent",
                "Can-Redefine-Classes": false,
                "Can-Retransform-Classes": false)
    }
}

task testJar(type: Jar) {
    archiveClassifier.set('tests')
    from sourceSets.test.output
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
        }
        maven(MavenPublication) {
            artifact testJar
        }
    }
}
build.dependsOn publishToMavenLocal

test {
    useJUnitPlatform()

    // ignore failing tests
    ignoreFailures = true
}

sourceSets {
    performanceTest {
        java {
            compileClasspath += main.output + test.output
            runtimeClasspath += main.output + test.output
            srcDir file('src/test/performance/java')
        }
    }
}