build.gradle

// Defines a configuration for the MarkLogic modules; used by the modulesJar task below
configurations {
  modules
}

task sourcesJar(type: Jar) {
  description = "Create a jar of the modules to meet Maven Central's requirements for publishing"
  archiveClassifier = "sources"
  from "src/main/ml-modules"
  destinationDirectory = file("build/libs")
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  archiveClassifier = "javadoc"
  from javadoc
}

task modulesJar(type: Jar) {
  description = "Jar up the marklogic-unit-test MarkLogic modules into a package that can be published"
  from("src/main/ml-modules") {
    into("marklogic-unit-test-modules/ml-modules")
  }
  destinationDirectory = file("build/libs")
  archiveBaseName = "marklogic-unit-test-modules"
}

artifacts {
  archives sourcesJar, javadocJar, modulesJar
}

publishing {
  publications {
    mainJava(MavenPublication) {
      pom {
        name = "${group}:${project.name}"
        description = "Supports testing MarkLogic applications"
        packaging = "jar"
        url = "https://github.com/marklogic-community/${project.name}"
        licenses {
          license {
            name = "The Apache License, Version 2.0"
            url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
          }
        }
        developers {
          developer {
            id = "marklogic"
            name = "MarkLogic Github Contributors"
            email = "general@developer.marklogic.com"
            organization = "MarkLogic"
            organizationUrl = "https://www.marklogic.com"
          }
        }
        scm {
          url = "git@github.com:marklogic-community/${project.name}.git"
          connection = "scm:git@github.com:marklogic-community/${project.name}.git"
          developerConnection = "scm:git@github.com:marklogic-community/${project.name}.git"
        }
      }
      artifact sourcesJar
      artifact javadocJar
      artifact modulesJar
    }
  }
  repositories {
    maven {
      if (project.hasProperty("mavenUser")) {
        credentials {
          username mavenUser
          password mavenPassword
        }
        url publishUrl
        allowInsecureProtocol = true
      } else {
        name = "central"
        url = mavenCentralUrl
        credentials {
          username mavenCentralUsername
          password mavenCentralPassword
        }
      }
    }
  }
}